3rdparty/ext_sip/CMakeLists.txt

0001 SET(PREFIX_ext_sip "${EXTPREFIX}" )
0002
0003 if(UNIX)
0004     ExternalProject_Add( ext_sip
0005         DOWNLOAD_DIR ${EXTERNALS_DOWNLOAD_DIR}
0006         URL https://pypi.python.org/packages/source/s/sip/sip-6.6.2.tar.gz
0007         URL_HASH SHA256=0e3efac1c5dfd8e525ae57140927df26993e13f58b89d1577c314f4105bfd90d
0008
0009         CONFIGURE_COMMAND ""
0010
0011         BUILD_COMMAND ${CMAKE_COMMAND} -E env
0012             "PYTHONPATH=${KRITA_PYTHONPATH}"
0013             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py build -j ${SUBMAKE_JOBS}
0014
0015         INSTALL_COMMAND ${CMAKE_COMMAND} -E env
0016             "PYTHONPATH=${KRITA_PYTHONPATH}"
0017             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py install --skip-build --prefix=${PREFIX_ext_sip} --optimize=1
0018
0019         BUILD_IN_SOURCE 1
0020
0021         UPDATE_COMMAND ""
0022     )
0023 elseif (WIN32)
0024     if(MINGW)
0025         set(_compiler -c mingw32)
0026     elseif(MSVC)
0027         set(_compiler -c msvc)
0028     endif()
0029
0030     krita_to_native_path("${PREFIX_ext_sip}" _sip_prefix)
0031     krita_to_native_path("${KRITA_PYTHONPATH}" _krita_pythonpath)
0032     string(TOLOWER ${_krita_pythonpath} _krita_pythonpath)
0033     krita_to_native_environment_path_list("${_krita_pythonpath}" _krita_pythonpath)
0034
0035     ExternalProject_Add( ext_sip
0036         DOWNLOAD_DIR ${EXTERNALS_DOWNLOAD_DIR}
0037         URL https://pypi.python.org/packages/source/s/sip/sip-6.6.2.tar.gz
0038         URL_HASH SHA256=0e3efac1c5dfd8e525ae57140927df26993e13f58b89d1577c314f4105bfd90d
0039
0040         CONFIGURE_COMMAND ""
0041
0042         BUILD_COMMAND ${CMAKE_COMMAND} -E env
0043             PYTHONPATH=${_krita_pythonpath}
0044             SETUPTOOLS_USE_DISTUTILS=local
0045             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py build -j ${SUBMAKE_JOBS} ${_compiler}
0046
0047         # HACK: Create lib\site-packages before installing
0048         # See e.g. https://access.redhat.com/errata/RHBA-2020:4437
0049         INSTALL_COMMAND ${CMAKE_COMMAND} -E make_directory ${_sip_prefix}\\lib\\site-packages
0050             COMMAND ${CMAKE_COMMAND} -E env
0051                 PYTHONPATH=${_krita_pythonpath}
0052                 SETUPTOOLS_USE_DISTUTILS=local
0053                 ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py install --skip-build --prefix=${_sip_prefix} --optimize=1 --install-scripts=${_sip_prefix}\\bin
0054
0055         BUILD_IN_SOURCE 1
0056
0057         UPDATE_COMMAND ""
0058     )
0059
0060     if (MINGW)
0061         ExternalProject_Add_Step(ext_sip
0062             wheel_update_setuptools
0063             COMMAND ${CMAKE_COMMAND} -E env
0064             PYTHONPATH=${_krita_pythonpath}
0065             PYTHONUSERBASE=${_sip_prefix}
0066             ${Python_EXECUTABLE} -m pip install -U pip setuptools>==59.8.0
0067                 COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/../ext_python/sitecustomize.py ${_sip_prefix}\\lib\\site-packages
0068
0069             DEPENDERS build
0070         )
0071         message(STATUS "Using mingw, Will deploy workaround for setuptools.")
0072         ExternalProject_Add_Step(ext_sip
0073             distutils_system_mod
0074             COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/../ext_python/_distutils_system_mod.py ${_sip_prefix}\\lib\\site-packages
0075
0076             DEPENDERS build
0077         )
0078     endif()
0079 endif()
0080