graphics/kimagemapeditor/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "1")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(kimagemapeditor VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set (QT_MIN_VERSION "5.15.2")
0012 set (KF5_MIN_VERSION "5.86.0")
0013 set (KDE_COMPILERSETTINGS_LEVEL "5.83.0")
0014
0015 find_package(ECM ${KF5_MIN_VERSION} REQUIRED CONFIG)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0017
0018 add_definitions(-DQURL_NO_CAST_FROM_STRING)
0019
0020 include(FeatureSummary)
0021 include(ECMInstallIcons)
0022 include(KDEInstallDirs)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024 include(KDECMakeSettings)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMSetupVersion)
0027
0028 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS
0029     Gui
0030     Widgets
0031     WebEngineWidgets
0032 )
0033 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0034     Config
0035     ConfigWidgets
0036     CoreAddons
0037     Crash
0038     DBusAddons
0039     DocTools
0040     GuiAddons
0041     Parts
0042     I18n
0043     WidgetsAddons
0044     XmlGui
0045 )
0046
0047 ecm_setup_version(${RELEASE_SERVICE_VERSION} VARIABLE_PREFIX KIMAGEMAPEDITOR VERSION_HEADER kimagemapeditor_version.h)
0048
0049 include_directories (${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} )
0050
0051 add_subdirectory( pics )
0052 add_subdirectory( doc )
0053
0054 ecm_qt_declare_logging_category(kimagemapeditor_LOG_SRC
0055     HEADER kimagemapeditor_debug.h
0056     IDENTIFIER KIMAGEMAPEDITOR_LOG
0057     CATEGORY_NAME org.kde.kimagemapeditor
0058     DEFAULT_SEVERITY Warning
0059     DESCRIPTION "KImageMapEditor"
0060     EXPORT KIMAGEMAPEDITOR
0061 )
0062
0063 ########### next target ###############
0064
0065 add_executable(kimagemapeditor_bin)
0066
0067 set_target_properties(kimagemapeditor_bin PROPERTIES OUTPUT_NAME kimagemapeditor)
0068
0069 target_sources(kimagemapeditor_bin PRIVATE
0070     main.cpp
0071     kimeshell.cpp
0072     ${kimagemapeditor_LOG_SRC}
0073
0074     kimagemapeditor.qrc
0075 )
0076
0077 target_link_libraries(kimagemapeditor_bin
0078     KF5::CoreAddons
0079     KF5::I18n
0080     KF5::ConfigCore
0081     KF5::Parts
0082     Qt::WebEngineWidgets
0083 )
0084
0085 install(TARGETS kimagemapeditor_bin  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0086
0087
0088 ########### next target ###############
0089
0090 configure_file(kimagemapeditorpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.desktop)
0091
0092 add_library(kimagemapeditorpart MODULE)
0093
0094 target_sources(kimagemapeditorpart PRIVATE
0095     areacreator.cpp
0096     kimearea.cpp
0097     kimecommands.cpp
0098     kimedialogs.cpp
0099     kimagemapeditor.cpp
0100     drawzone.cpp
0101     arealistview.cpp
0102     imageslistview.cpp
0103     mapslistview.cpp
0104     imagemapchoosedialog.cpp
0105     ${kimagemapeditor_LOG_SRC}
0106
0107     kimagemapeditorpart.qrc
0108 )
0109
0110 kcoreaddons_desktop_to_json(kimagemapeditorpart ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.desktop)
0111
0112 target_link_libraries(kimagemapeditorpart
0113     KF5::CoreAddons
0114     KF5::I18n
0115     KF5::ConfigCore
0116     KF5::Parts
0117     Qt::WebEngineWidgets
0118 )
0119
0120 install(TARGETS kimagemapeditorpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf5/parts)
0121
0122 ########### install files ###############
0123
0124 install( FILES  org.kde.kimagemapeditor.desktop  DESTINATION ${KDE_INSTALL_APPDIR})
0125 install( FILES  org.kde.kimagemapeditor.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0126 install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.desktop  DESTINATION ${KDE_INSTALL_KSERVICESDIR})
0127
0128 ki18n_install(po)
0129 kdoctools_install(po)
0130
0131 ecm_qt_install_logging_categories(
0132     EXPORT KIMAGEMAPEDITOR
0133     FILE kimagemapeditor.categories
0134     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0135 )
0136
0137 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)