graphics/kimagemapeditor/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "11")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(kimagemapeditor VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set (QT_MIN_VERSION "5.15.2")
0012 set (KF_MIN_VERSION "5.86.0")
0013 set (KDE_COMPILERSETTINGS_LEVEL "5.83.0")
0014
0015 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0017
0018 add_definitions(-DQURL_NO_CAST_FROM_STRING)
0019
0020 include(FeatureSummary)
0021 include(ECMInstallIcons)
0022 include(KDEInstallDirs)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024 include(KDECMakeSettings)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMSetupVersion)
0027
0028 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS
0029     Gui
0030     Widgets
0031     WebEngineWidgets
0032 )
0033 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0034     Config
0035     ConfigWidgets
0036     CoreAddons
0037     Crash
0038     DBusAddons
0039     DocTools
0040     GuiAddons
0041     Parts
0042     I18n
0043     WidgetsAddons
0044     XmlGui
0045 )
0046
0047 ecm_setup_version(${RELEASE_SERVICE_VERSION} VARIABLE_PREFIX KIMAGEMAPEDITOR VERSION_HEADER kimagemapeditor_version.h)
0048
0049 include_directories (${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} )
0050
0051 add_subdirectory( pics )
0052 add_subdirectory( doc )
0053
0054 ecm_qt_declare_logging_category(kimagemapeditor_LOG_SRC
0055     HEADER kimagemapeditor_debug.h
0056     IDENTIFIER KIMAGEMAPEDITOR_LOG
0057     CATEGORY_NAME org.kde.kimagemapeditor
0058     DEFAULT_SEVERITY Warning
0059     DESCRIPTION "KImageMapEditor"
0060     EXPORT KIMAGEMAPEDITOR
0061 )
0062
0063 ########### next target ###############
0064
0065 add_executable(kimagemapeditor_bin)
0066
0067 set_target_properties(kimagemapeditor_bin PROPERTIES OUTPUT_NAME kimagemapeditor)
0068
0069 target_sources(kimagemapeditor_bin PRIVATE
0070     main.cpp
0071     kimeshell.cpp
0072     ${kimagemapeditor_LOG_SRC}
0073
0074     kimagemapeditor.qrc
0075 )
0076
0077 target_link_libraries(kimagemapeditor_bin
0078     KF${QT_MAJOR_VERSION}::CoreAddons
0079     KF${QT_MAJOR_VERSION}::I18n
0080     KF${QT_MAJOR_VERSION}::ConfigCore
0081     KF${QT_MAJOR_VERSION}::Parts
0082     Qt::WebEngineWidgets
0083 )
0084
0085 install(TARGETS kimagemapeditor_bin  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0086
0087
0088 ########### next target ###############
0089
0090 configure_file(kimagemapeditorpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.json)
0091
0092 if (QT_MAJOR_VERSION STREQUAL "5")
0093     configure_file(kimagemapeditorpart.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.desktop)
0094 endif()
0095
0096 add_library(kimagemapeditorpart MODULE)
0097
0098 target_sources(kimagemapeditorpart PRIVATE
0099     areacreator.cpp
0100     kimearea.cpp
0101     kimecommands.cpp
0102     kimedialogs.cpp
0103     kimagemapeditor.cpp
0104     drawzone.cpp
0105     arealistview.cpp
0106     imageslistview.cpp
0107     mapslistview.cpp
0108     imagemapchoosedialog.cpp
0109     ${kimagemapeditor_LOG_SRC}
0110
0111     kimagemapeditorpart.qrc
0112 )
0113
0114 target_link_libraries(kimagemapeditorpart
0115     KF${QT_MAJOR_VERSION}::CoreAddons
0116     KF${QT_MAJOR_VERSION}::I18n
0117     KF${QT_MAJOR_VERSION}::ConfigCore
0118     KF${QT_MAJOR_VERSION}::Parts
0119     Qt::WebEngineWidgets
0120 )
0121
0122 install(TARGETS kimagemapeditorpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/parts)
0123
0124 ########### install files ###############
0125
0126 install( FILES  org.kde.kimagemapeditor.desktop  DESTINATION ${KDE_INSTALL_APPDIR})
0127 install( FILES  org.kde.kimagemapeditor.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0128
0129 if (QT_MAJOR_VERSION STREQUAL "5")
0130     install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/kimagemapeditorpart.desktop  DESTINATION ${KDE_INSTALL_KSERVICESDIR})
0131 endif()
0132
0133 ki18n_install(po)
0134 kdoctools_install(po)
0135
0136 ecm_qt_install_logging_categories(
0137     EXPORT KIMAGEMAPEDITOR
0138     FILE kimagemapeditor.categories
0139     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0140 )
0141
0142 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)