games/ktuberling/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "11")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(ktuberling VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(QT_MIN_VERSION "6.5.0")
0012 set(KF_MIN_VERSION "5.240.0")
0013
0014 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0015 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(FeatureSummary)
0022 include(ECMAddAppIcon)
0023 include(ECMInstallIcons)
0024 include(ECMSetupVersion)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMDeprecationSettings)
0027
0028 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0029     Multimedia
0030     PrintSupport
0031     Svg
0032     SvgWidgets
0033     Widgets
0034     Xml
0035 )
0036
0037 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     Config
0039     I18n
0040 )
0041
0042 if(NOT ANDROID)
0043     find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0044         Completion
0045         ConfigWidgets
0046         CoreAddons
0047         Crash
0048         DBusAddons
0049         KIO
0050         DocTools
0051         WidgetsAddons
0052         XmlGui
0053     )
0054
0055     find_package(KDEGames6 7.5.0 REQUIRED)
0056 endif()
0057
0058 ecm_setup_version(${RELEASE_SERVICE_VERSION} VARIABLE_PREFIX KTUBERLING VERSION_HEADER ktuberling_version.h)
0059
0060 # Added by KDE_COMPILERSETTINGS_LEVEL 5.85
0061 remove_definitions(
0062     -DQT_NO_CAST_FROM_ASCII
0063 )
0064
0065 ecm_set_disabled_deprecation_versions(
0066     QT 6.5
0067     KF 5.239
0068 )
0069 if (NOT ANDROID)
0070     ecm_set_disabled_deprecation_versions(
0071         KDEGAMES 7.5
0072     )
0073 endif()
0074
0075 if(KF5DocTools_FOUND)
0076     add_subdirectory(doc)
0077 endif()
0078
0079 ########### next target ###############
0080
0081 set(ktuberling_common_SRCS
0082    action.cpp
0083    playground.cpp
0084    todraw.cpp
0085    soundfactory.cpp
0086    filefactory.cpp
0087 )
0088 ecm_qt_declare_logging_category(ktuberling_common_SRCS HEADER ktuberling_debug.h IDENTIFIER KTUBERLING_LOG CATEGORY_NAME org.kde.kdegames.ktuberling DESCRIPTION "ktuberling (kdegames)" EXPORT KTUBERLING)
0089
0090 if(ANDROID)
0091     set(ktuberling_mobile_SRCS
0092         ${ktuberling_common_SRCS}
0093         main_mobile.cpp
0094         android_data/resources.qrc
0095     )
0096
0097     add_executable(ktuberling_mobile ${ktuberling_mobile_SRCS})
0098
0099     target_link_libraries(ktuberling_mobile
0100         KF6::ConfigCore
0101         Qt6::Gui
0102         Qt6::Svg
0103         Qt6::Multimedia
0104         Qt6::Xml
0105         Qt6::Widgets
0106         Qt6::SvgWidgets
0107     )
0108
0109     install(TARGETS ktuberling_mobile RUNTIME DESTINATION bin)
0110
0111 else()
0112
0113     set(ktuberling_SRCS
0114         ${ktuberling_common_SRCS}
0115         main.cpp
0116         toplevel.cpp
0117         playgrounddelegate.cpp
0118
0119         ktuberling.qrc
0120     )
0121
0122     file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/*-apps-ktuberling.png")
0123     ecm_add_app_icon(ktuberling_SRCS ICONS ${ICONS_SRCS})
0124
0125     add_executable(ktuberling ${ktuberling_SRCS})
0126
0127     target_link_libraries(ktuberling
0128         KDEGames6
0129         KF6::ConfigWidgets
0130         KF6::Completion
0131         KF6::Crash
0132         KF6::DBusAddons
0133         KF6::KIOCore
0134         KF6::XmlGui
0135         Qt6::PrintSupport
0136         Qt6::Svg
0137         Qt6::Multimedia
0138         Qt6::SvgWidgets
0139     )
0140
0141     install(TARGETS ktuberling  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0142
0143     install(PROGRAMS org.kde.ktuberling.desktop  DESTINATION  ${KDE_INSTALL_APPDIR})
0144
0145     ecm_install_icons(ICONS
0146         128-apps-ktuberling.png
0147         16-apps-ktuberling.png
0148         22-apps-ktuberling.png
0149         32-apps-ktuberling.png
0150         48-apps-ktuberling.png
0151         64-apps-ktuberling.png
0152         128-mimetypes-application-x-tuberling.png
0153         16-mimetypes-application-x-tuberling.png
0154         22-mimetypes-application-x-tuberling.png
0155         32-mimetypes-application-x-tuberling.png
0156         48-mimetypes-application-x-tuberling.png
0157         64-mimetypes-application-x-tuberling.png
0158         DESTINATION ${KDE_INSTALL_ICONDIR} THEME hicolor
0159     )
0160
0161     add_subdirectory(sounds)
0162     add_subdirectory(pics)
0163 endif()
0164
0165 install(FILES org.kde.ktuberling.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0166 ecm_qt_install_logging_categories(EXPORT KTUBERLING FILE ktuberling.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0167
0168 ki18n_install(po)
0169 if(KF5DocTools_FOUND)
0170     kdoctools_install(po)
0171 endif()
0172
0173 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)