games/ktuberling/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "1")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(ktuberling VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(QT_MIN_VERSION "5.15.2")
0012 set(KF_MIN_VERSION "5.91.0")
0013
0014 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0015 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(FeatureSummary)
0022 include(ECMAddAppIcon)
0023 include(ECMInstallIcons)
0024 include(ECMSetupVersion)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMDeprecationSettings)
0027 if (QT_MAJOR_VERSION STREQUAL "6")
0028     set(QT_REQUIRED_VERSION "6.4.0")
0029     set(KF_MIN_VERSION "5.240.0")
0030     set(KF_MAJOR_VERSION "6")
0031 else()
0032     set(KF_MAJOR_VERSION "5")
0033 endif()
0034
0035 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS PrintSupport Svg Widgets Xml Multimedia)
0036 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS Config I18n)
0037
0038 if (QT_MAJOR_VERSION EQUAL "6")
0039     find_package(Qt6 ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS SvgWidgets)
0040 endif()
0041
0042 if(NOT ANDROID)
0043     find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0044         Completion
0045         ConfigWidgets
0046         CoreAddons
0047         Crash
0048         DBusAddons
0049         KIO
0050         DocTools
0051         WidgetsAddons
0052         XmlGui
0053     )
0054
0055     find_package(KF5KDEGames 7.3.0 REQUIRED)
0056 endif()
0057
0058 ecm_setup_version(${RELEASE_SERVICE_VERSION} VARIABLE_PREFIX KTUBERLING VERSION_HEADER ktuberling_version.h)
0059
0060 # Added by KDE_COMPILERSETTINGS_LEVEL 5.85
0061 remove_definitions(
0062     -DQT_NO_CAST_FROM_ASCII
0063 )
0064
0065 ecm_set_disabled_deprecation_versions(
0066     QT 6.4
0067     KF 5.103
0068 )
0069
0070 if(KF5DocTools_FOUND)
0071     add_subdirectory(doc)
0072 endif()
0073
0074 ########### next target ###############
0075
0076 set(ktuberling_common_SRCS
0077    action.cpp
0078    playground.cpp
0079    todraw.cpp
0080    soundfactory.cpp
0081    filefactory.cpp
0082 )
0083 ecm_qt_declare_logging_category(ktuberling_common_SRCS HEADER ktuberling_debug.h IDENTIFIER KTUBERLING_LOG CATEGORY_NAME org.kde.kdegames.ktuberling DESCRIPTION "ktuberling (kdegames)" EXPORT KTUBERLING)
0084
0085 if(ANDROID)
0086     set(ktuberling_mobile_SRCS
0087         ${ktuberling_common_SRCS}
0088         main_mobile.cpp
0089         android_data/resources.qrc
0090     )
0091
0092     add_executable(ktuberling_mobile ${ktuberling_mobile_SRCS})
0093
0094     target_link_libraries(ktuberling_mobile
0095         Qt${QT_MAJOR_VERSION}::Gui
0096         Qt${QT_MAJOR_VERSION}::Svg
0097         Qt${QT_MAJOR_VERSION}::Multimedia
0098         Qt${QT_MAJOR_VERSION}::Xml
0099         Qt${QT_MAJOR_VERSION}::Widgets
0100         KF${KF_MAJOR_VERSION}::ConfigCore )
0101
0102     if (QT_MAJOR_VERSION EQUAL "6")
0103         target_link_libraries(ktuberling_mobile Qt6::SvgWidgets)
0104     endif()
0105
0106     install(TARGETS ktuberling_mobile RUNTIME DESTINATION bin)
0107
0108 else()
0109
0110     set(ktuberling_SRCS
0111         ${ktuberling_common_SRCS}
0112         main.cpp
0113         toplevel.cpp
0114         playgrounddelegate.cpp
0115
0116         ktuberling.qrc
0117     )
0118
0119     file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/*-apps-ktuberling.png")
0120     ecm_add_app_icon(ktuberling_SRCS ICONS ${ICONS_SRCS})
0121
0122     add_executable(ktuberling ${ktuberling_SRCS})
0123
0124     target_link_libraries(ktuberling
0125         Qt${QT_MAJOR_VERSION}::PrintSupport
0126         Qt${QT_MAJOR_VERSION}::Svg
0127         Qt${QT_MAJOR_VERSION}::Multimedia
0128         KF${KF_MAJOR_VERSION}::ConfigWidgets
0129         KF${KF_MAJOR_VERSION}::Completion
0130         KF${KF_MAJOR_VERSION}::Crash
0131         KF${KF_MAJOR_VERSION}::DBusAddons
0132         KF${KF_MAJOR_VERSION}::KIOCore
0133         KF${KF_MAJOR_VERSION}::XmlGui
0134         KF5KDEGames
0135     )
0136
0137     if (QT_MAJOR_VERSION EQUAL "6")
0138         target_link_libraries(ktuberling Qt6::SvgWidgets)
0139     endif()
0140
0141     install(TARGETS ktuberling  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0142
0143     install(PROGRAMS org.kde.ktuberling.desktop  DESTINATION  ${KDE_INSTALL_APPDIR})
0144
0145     ecm_install_icons(ICONS
0146         128-apps-ktuberling.png
0147         16-apps-ktuberling.png
0148         22-apps-ktuberling.png
0149         32-apps-ktuberling.png
0150         48-apps-ktuberling.png
0151         64-apps-ktuberling.png
0152         128-mimetypes-application-x-tuberling.png
0153         16-mimetypes-application-x-tuberling.png
0154         22-mimetypes-application-x-tuberling.png
0155         32-mimetypes-application-x-tuberling.png
0156         48-mimetypes-application-x-tuberling.png
0157         64-mimetypes-application-x-tuberling.png
0158         DESTINATION ${KDE_INSTALL_ICONDIR} THEME hicolor
0159     )
0160
0161     add_subdirectory(sounds)
0162     add_subdirectory(pics)
0163 endif()
0164
0165 install(FILES org.kde.ktuberling.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0166 ecm_qt_install_logging_categories(EXPORT KTUBERLING FILE ktuberling.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0167
0168 ki18n_install(po)
0169 if(KF5DocTools_FOUND)
0170     kdoctools_install(po)
0171 endif()
0172
0173 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)