Warning, /games/ktuberling/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "08")
0006 set(RELEASE_SERVICE_VERSION_MICRO "1")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(ktuberling VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(QT_MIN_VERSION "5.15.2")
0012 set(KF_MIN_VERSION "5.91.0")
0013
0014 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0015 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(FeatureSummary)
0022 include(ECMAddAppIcon)
0023 include(ECMInstallIcons)
0024 include(ECMSetupVersion)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMDeprecationSettings)
0027 if (QT_MAJOR_VERSION STREQUAL "6")
0028 set(QT_REQUIRED_VERSION "6.4.0")
0029 set(KF_MIN_VERSION "5.240.0")
0030 set(KF_MAJOR_VERSION "6")
0031 else()
0032 set(KF_MAJOR_VERSION "5")
0033 endif()
0034
0035 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS PrintSupport Svg Widgets Xml Multimedia)
0036 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS Config I18n)
0037
0038 if (QT_MAJOR_VERSION EQUAL "6")
0039 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS SvgWidgets)
0040 endif()
0041
0042 if(NOT ANDROID)
0043 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0044 Completion
0045 ConfigWidgets
0046 CoreAddons
0047 Crash
0048 DBusAddons
0049 KIO
0050 DocTools
0051 WidgetsAddons
0052 XmlGui
0053 )
0054
0055 if (QT_MAJOR_VERSION STREQUAL "6")
0056 find_package(KDEGames6 7.5.0 REQUIRED)
0057 else()
0058 find_package(KF5KDEGames 7.3.0 REQUIRED)
0059 endif()
0060 endif()
0061
0062 ecm_setup_version(${RELEASE_SERVICE_VERSION} VARIABLE_PREFIX KTUBERLING VERSION_HEADER ktuberling_version.h)
0063
0064 # Added by KDE_COMPILERSETTINGS_LEVEL 5.85
0065 remove_definitions(
0066 -DQT_NO_CAST_FROM_ASCII
0067 )
0068
0069 ecm_set_disabled_deprecation_versions(
0070 QT 6.4
0071 KF 5.103
0072 )
0073
0074 if(KF5DocTools_FOUND)
0075 add_subdirectory(doc)
0076 endif()
0077
0078 ########### next target ###############
0079
0080 set(ktuberling_common_SRCS
0081 action.cpp
0082 playground.cpp
0083 todraw.cpp
0084 soundfactory.cpp
0085 filefactory.cpp
0086 )
0087 ecm_qt_declare_logging_category(ktuberling_common_SRCS HEADER ktuberling_debug.h IDENTIFIER KTUBERLING_LOG CATEGORY_NAME org.kde.kdegames.ktuberling DESCRIPTION "ktuberling (kdegames)" EXPORT KTUBERLING)
0088
0089 if(ANDROID)
0090 set(ktuberling_mobile_SRCS
0091 ${ktuberling_common_SRCS}
0092 main_mobile.cpp
0093 android_data/resources.qrc
0094 )
0095
0096 add_executable(ktuberling_mobile ${ktuberling_mobile_SRCS})
0097
0098 target_link_libraries(ktuberling_mobile
0099 Qt${QT_MAJOR_VERSION}::Gui
0100 Qt${QT_MAJOR_VERSION}::Svg
0101 Qt${QT_MAJOR_VERSION}::Multimedia
0102 Qt${QT_MAJOR_VERSION}::Xml
0103 Qt${QT_MAJOR_VERSION}::Widgets
0104 KF${KF_MAJOR_VERSION}::ConfigCore )
0105
0106 if (QT_MAJOR_VERSION EQUAL "6")
0107 target_link_libraries(ktuberling_mobile Qt6::SvgWidgets)
0108 endif()
0109
0110 install(TARGETS ktuberling_mobile RUNTIME DESTINATION bin)
0111
0112 else()
0113
0114 set(ktuberling_SRCS
0115 ${ktuberling_common_SRCS}
0116 main.cpp
0117 toplevel.cpp
0118 playgrounddelegate.cpp
0119
0120 ktuberling.qrc
0121 )
0122
0123 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/*-apps-ktuberling.png")
0124 ecm_add_app_icon(ktuberling_SRCS ICONS ${ICONS_SRCS})
0125
0126 add_executable(ktuberling ${ktuberling_SRCS})
0127
0128 if (QT_MAJOR_VERSION STREQUAL "6")
0129 target_link_libraries(ktuberling KDEGames6)
0130 else()
0131 target_link_libraries(ktuberling KF5KDEGames)
0132 endif()
0133
0134 target_link_libraries(ktuberling
0135 Qt${QT_MAJOR_VERSION}::PrintSupport
0136 Qt${QT_MAJOR_VERSION}::Svg
0137 Qt${QT_MAJOR_VERSION}::Multimedia
0138 KF${KF_MAJOR_VERSION}::ConfigWidgets
0139 KF${KF_MAJOR_VERSION}::Completion
0140 KF${KF_MAJOR_VERSION}::Crash
0141 KF${KF_MAJOR_VERSION}::DBusAddons
0142 KF${KF_MAJOR_VERSION}::KIOCore
0143 KF${KF_MAJOR_VERSION}::XmlGui
0144 )
0145
0146 if (QT_MAJOR_VERSION EQUAL "6")
0147 target_link_libraries(ktuberling Qt6::SvgWidgets)
0148 endif()
0149
0150 install(TARGETS ktuberling ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0151
0152 install(PROGRAMS org.kde.ktuberling.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0153
0154 ecm_install_icons(ICONS
0155 128-apps-ktuberling.png
0156 16-apps-ktuberling.png
0157 22-apps-ktuberling.png
0158 32-apps-ktuberling.png
0159 48-apps-ktuberling.png
0160 64-apps-ktuberling.png
0161 128-mimetypes-application-x-tuberling.png
0162 16-mimetypes-application-x-tuberling.png
0163 22-mimetypes-application-x-tuberling.png
0164 32-mimetypes-application-x-tuberling.png
0165 48-mimetypes-application-x-tuberling.png
0166 64-mimetypes-application-x-tuberling.png
0167 DESTINATION ${KDE_INSTALL_ICONDIR} THEME hicolor
0168 )
0169
0170 add_subdirectory(sounds)
0171 add_subdirectory(pics)
0172 endif()
0173
0174 install(FILES org.kde.ktuberling.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0175 ecm_qt_install_logging_categories(EXPORT KTUBERLING FILE ktuberling.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0176
0177 ki18n_install(po)
0178 if(KF5DocTools_FOUND)
0179 kdoctools_install(po)
0180 endif()
0181
0182 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)