src/lib/CMakeLists.txt

0001 add_library(KF5SyntaxHighlighting)
0002
0003 ecm_create_qm_loader(syntax_highlighting_QM_LOADER syntaxhighlighting5_qt)
0004
0005 target_sources(KF5SyntaxHighlighting PRIVATE
0006     abstracthighlighter.cpp
0007     context.cpp
0008     contextswitch.cpp
0009     definitiondownloader.cpp
0010     highlightingdata.cpp
0011     foldingregion.cpp
0012     format.cpp
0013     htmlhighlighter.cpp
0014     ansihighlighter.cpp
0015     keywordlist.cpp
0016     rule.cpp
0017     definition.cpp
0018     repository.cpp
0019     state.cpp
0020     syntaxhighlighter.cpp
0021     theme.cpp
0022     wildcardmatcher.cpp
0023     themedata.cpp
0024     worddelimiters.cpp
0025     ${syntax_highlighting_QM_LOADER}
0026     $<TARGET_OBJECTS:SyntaxHighlightingData>
0027 )
0028 ecm_qt_declare_logging_category(KF5SyntaxHighlighting
0029     HEADER ksyntaxhighlighting_logging.h
0030     IDENTIFIER KSyntaxHighlighting::Log
0031     CATEGORY_NAME kf.syntaxhighlighting
0032     OLD_CATEGORY_NAMES org.kde.ksyntaxhighlighting
0033     DESCRIPTION "Syntax Highlighting"
0034     EXPORT KSYNTAXHIGHLIGHTING
0035 )
0036
0037 ecm_generate_export_header(KF5SyntaxHighlighting
0038     BASE_NAME KSyntaxHighlighting
0039     GROUP_BASE_NAME KF
0040     VERSION ${KF_VERSION}
0041     DEPRECATED_BASE_VERSION 0
0042     DEPRECATION_VERSIONS 5.87
0043     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0044 )
0045 set_target_properties(KF5SyntaxHighlighting PROPERTIES
0046     VERSION ${SyntaxHighlighting_VERSION}
0047     SOVERSION ${SyntaxHighlighting_SOVERSION}
0048     EXPORT_NAME SyntaxHighlighting
0049 )
0050
0051 target_link_libraries(KF5SyntaxHighlighting
0052     PUBLIC
0053         Qt${QT_MAJOR_VERSION}::Gui
0054     PRIVATE
0055         Qt${QT_MAJOR_VERSION}::Network
0056 )
0057
0058 set(Forwarding_Header_Names
0059     AbstractHighlighter
0060     Definition
0061     DefinitionDownloader
0062     FoldingRegion
0063     Format
0064     Repository
0065     State
0066     SyntaxHighlighter
0067     Theme
0068     WildcardMatcher
0069 )
0070
0071 ecm_generate_headers(CamelCase_HEADERS
0072     HEADER_NAMES ${Forwarding_Header_Names}
0073     REQUIRED_HEADERS SyntaxHighlighting_HEADERS
0074     OUTPUT_DIR ${CMAKE_BINARY_DIR}/KSyntaxHighlighting/KSyntaxHighlighting
0075 )
0076
0077 target_include_directories(KF5SyntaxHighlighting
0078     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KSyntaxHighlighting>"
0079     PUBLIC "$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/KSyntaxHighlighting;>"
0080 )
0081
0082 install(TARGETS KF5SyntaxHighlighting EXPORT KF5SyntaxHighlightingTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0083
0084 install(FILES
0085     ${CamelCase_HEADERS}
0086     ${SyntaxHighlighting_HEADERS}
0087     ${CMAKE_CURRENT_BINARY_DIR}/ksyntaxhighlighting_export.h
0088     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KSyntaxHighlighting/KSyntaxHighlighting
0089 )
0090
0091 if(BUILD_QCH)
0092     ecm_add_qch(
0093         KF5SyntaxHighlighting_QCH
0094         NAME KSyntaxHighlighting
0095         BASE_NAME KF5SyntaxHighlighting
0096         VERSION ${KF_VERSION}
0097         ORG_DOMAIN org.kde
0098         SOURCES # using only public headers, to cover only public API
0099             ${SyntaxHighlighting_HEADERS}
0100         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0101         LINK_QCHS
0102             Qt5Core_QCH
0103             Qt5Gui_QCH
0104         INCLUDE_DIRS
0105             ${CMAKE_CURRENT_BINARY_DIR}
0106         BLANK_MACROS
0107             KSYNTAXHIGHLIGHTING_EXPORT
0108             KSYNTAXHIGHLIGHTING_DEPRECATED
0109         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0111         COMPONENT Devel
0112     )
0113 endif()
0114 ecm_generate_pri_file(
0115     BASE_NAME KSyntaxHighlighting LIB_NAME
0116     KF5SyntaxHighlighting
0117     DEPS "gui"
0118     FILENAME_VAR PRI_FILENAME
0119     INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KSyntaxHighlighting
0120 )
0121 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})