src/lib/CMakeLists.txt

0001 add_library(KF6SyntaxHighlighting)
0002
0003 set_target_properties(KF6SyntaxHighlighting PROPERTIES
0004     VERSION     ${KSYNTAXHIGHLIGHTING_VERSION}
0005     SOVERSION   ${KSYNTAXHIGHLIGHTING_SOVERSION}
0006     EXPORT_NAME SyntaxHighlighting
0007 )
0008
0009 ecm_create_qm_loader(syntax_highlighting_QM_LOADER syntaxhighlighting6_qt)
0010
0011 target_sources(KF6SyntaxHighlighting PRIVATE
0012     abstracthighlighter.cpp
0013     context.cpp
0014     contextswitch.cpp
0015     definitiondownloader.cpp
0016     highlightingdata.cpp
0017     foldingregion.cpp
0018     format.cpp
0019     htmlhighlighter.cpp
0020     ansihighlighter.cpp
0021     keywordlist.cpp
0022     rule.cpp
0023     definition.cpp
0024     repository.cpp
0025     state.cpp
0026     syntaxhighlighter.cpp
0027     theme.cpp
0028     wildcardmatcher.cpp
0029     themedata.cpp
0030     worddelimiters.cpp
0031     ${syntax_highlighting_QM_LOADER}
0032     $<TARGET_OBJECTS:SyntaxHighlightingData>
0033 )
0034 ecm_qt_declare_logging_category(KF6SyntaxHighlighting
0035     HEADER ksyntaxhighlighting_logging.h
0036     IDENTIFIER KSyntaxHighlighting::Log
0037     CATEGORY_NAME kf.syntaxhighlighting
0038     OLD_CATEGORY_NAMES org.kde.ksyntaxhighlighting
0039     DESCRIPTION "Syntax Highlighting"
0040     EXPORT KSYNTAXHIGHLIGHTING
0041 )
0042
0043 ecm_generate_export_header(KF6SyntaxHighlighting
0044     BASE_NAME KSyntaxHighlighting
0045     GROUP_BASE_NAME KF
0046     VERSION ${KF_VERSION}
0047     USE_VERSION_HEADER
0048     DEPRECATED_BASE_VERSION 0
0049     DEPRECATION_VERSIONS
0050     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0051 )
0052
0053 target_link_libraries(KF6SyntaxHighlighting
0054     PUBLIC
0055         Qt6::Gui
0056     PRIVATE
0057         Qt6::Network
0058 )
0059
0060 set(Forwarding_Header_Names
0061     AbstractHighlighter
0062     Definition
0063     DefinitionDownloader
0064     FoldingRegion
0065     Format
0066     Repository
0067     State
0068     SyntaxHighlighter
0069     Theme
0070     WildcardMatcher
0071 )
0072
0073 ecm_generate_headers(CamelCase_HEADERS
0074     HEADER_NAMES ${Forwarding_Header_Names}
0075     REQUIRED_HEADERS SyntaxHighlighting_HEADERS
0076     OUTPUT_DIR ${CMAKE_BINARY_DIR}/KSyntaxHighlighting/KSyntaxHighlighting
0077 )
0078
0079 target_include_directories(KF6SyntaxHighlighting
0080     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KSyntaxHighlighting>"
0081     PUBLIC "$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/KSyntaxHighlighting;>"
0082 )
0083
0084 install(TARGETS KF6SyntaxHighlighting EXPORT KF6SyntaxHighlightingTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0085
0086 install(FILES
0087     ${CamelCase_HEADERS}
0088     ${SyntaxHighlighting_HEADERS}
0089     ${CMAKE_CURRENT_BINARY_DIR}/ksyntaxhighlighting_export.h
0090     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KSyntaxHighlighting/KSyntaxHighlighting
0091 )
0092
0093 if(BUILD_QCH)
0094     ecm_add_qch(
0095         KF6SyntaxHighlighting_QCH
0096         NAME KSyntaxHighlighting
0097         BASE_NAME KF6SyntaxHighlighting
0098         VERSION ${KF_VERSION}
0099         ORG_DOMAIN org.kde
0100         SOURCES # using only public headers, to cover only public API
0101             ${SyntaxHighlighting_HEADERS}
0102         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0103         LINK_QCHS
0104             Qt6Core_QCH
0105             Qt6Gui_QCH
0106         INCLUDE_DIRS
0107             ${CMAKE_CURRENT_BINARY_DIR}
0108         BLANK_MACROS
0109             KSYNTAXHIGHLIGHTING_EXPORT
0110             KSYNTAXHIGHLIGHTING_DEPRECATED
0111         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0112         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0113         COMPONENT Devel
0114     )
0115 endif()