src/ui/CMakeLists.txt

0001 ecm_create_qm_loader(sonnet_QM_LOADER sonnet5_qt)
0002
0003 set(sonnetui_SRCS
0004     configdialog.cpp
0005     configview.cpp
0006     configwidget.cpp
0007     dialog.cpp
0008     dictionarycombobox.cpp
0009     highlighter.cpp
0010     spellcheckdecorator.cpp
0011     ${sonnet_QM_LOADER}
0012 )
0013
0014 ecm_qt_declare_logging_category(sonnetui_SRCS
0015     HEADER ui_debug.h
0016     IDENTIFIER SONNET_LOG_UI
0017     CATEGORY_NAME kf.sonnet.ui
0018     OLD_CATEGORY_NAMES sonnet.ui
0019     DESCRIPTION "Sonnet UI"
0020     EXPORT SONNET
0021 )
0022
0023 set(sonnetui_UI
0024     configui.ui
0025     sonnetui.ui
0026 )
0027
0028 ecm_generate_headers(SonnetUi_CamelCase_HEADERS
0029   HEADER_NAMES
0030     Dialog
0031     Highlighter
0032     ConfigDialog
0033     ConfigView
0034     ConfigWidget
0035     DictionaryComboBox
0036     SpellCheckDecorator
0037   PREFIX Sonnet
0038   REQUIRED_HEADERS SonnetUi_HEADERS
0039 )
0040
0041 qt_wrap_ui(sonnetui_SRCS ${sonnetui_UI})
0042
0043 add_library(KF5SonnetUi ${sonnetui_SRCS})
0044 ecm_generate_export_header(KF5SonnetUi
0045     BASE_NAME SonnetUi
0046     GROUP_BASE_NAME KF
0047     VERSION ${KF_VERSION}
0048     DEPRECATED_BASE_VERSION 0
0049     DEPRECATION_VERSIONS 5.65
0050     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0051 )
0052
0053 add_library(KF5::SonnetUi ALIAS KF5SonnetUi)
0054
0055 target_link_libraries(KF5SonnetUi
0056     PUBLIC Qt${QT_MAJOR_VERSION}::Widgets
0057     PRIVATE KF5::SonnetCore
0058 )
0059
0060 set_target_properties(KF5SonnetUi PROPERTIES VERSION ${SONNET_VERSION}
0061                                              SOVERSION ${SONNET_SOVERSION}
0062                                              EXPORT_NAME SonnetUi
0063 )
0064
0065
0066 # CMAKE_CURRENT_BINARY_DIR: for camelcase headers and lowercase forwarders
0067 target_include_directories(KF5SonnetUi INTERFACE
0068     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi>"
0069     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet>"
0070 )
0071 target_include_directories(KF5SonnetUi PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>")
0072
0073 install(TARGETS KF5SonnetUi EXPORT KF5SonnetTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0074
0075 install(FILES ${SonnetUi_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi/Sonnet COMPONENT Devel)
0076
0077 install(FILES
0078    ${SonnetUi_HEADERS}
0079    ${CMAKE_CURRENT_BINARY_DIR}/sonnetui_export.h
0080    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi/sonnet COMPONENT Devel)
0081
0082 if(BUILD_DESIGNERPLUGIN)
0083     add_subdirectory(designer)
0084 endif()
0085
0086 if (BUILD_QCH)
0087     ecm_add_qch(
0088         KF5SonnetUi_QCH
0089         NAME SonnetUi
0090         BASE_NAME KF5SonnetUi
0091         VERSION ${KF_VERSION}
0092         ORG_DOMAIN org.kde
0093         SOURCES # using only public headers, to cover only public API
0094             ${SonnetUi_HEADERS}
0095         LINK_QCHS
0096             Qt5Core_QCH
0097             Qt5Gui_QCH
0098             Qt5Widgets_QCH
0099         INCLUDE_DIRS
0100             ${CMAKE_CURRENT_BINARY_DIR}
0101         BLANK_MACROS
0102             SONNETUI_EXPORT
0103             SONNETUI_DEPRECATED_EXPORT
0104             SONNETUI_DEPRECATED
0105             "SONNETUI_DEPRECATED_VERSION(x, y, t)"
0106         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0107         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0108         COMPONENT Devel
0109     )
0110 endif()
0111
0112 include(ECMGeneratePriFile)
0113 ecm_generate_pri_file(
0114     BASE_NAME SonnetUi
0115     LIB_NAME KF5SonnetUi
0116     DEPS "widgets"
0117     FILENAME_VAR PRI_FILENAME
0118     INCLUDE_INSTALL_DIRS
0119         ${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet
0120         ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi
0121 )
0122 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})