Warning, /frameworks/sonnet/src/ui/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 add_library(KF6SonnetUi)
0002 add_library(KF6::SonnetUi ALIAS KF6SonnetUi)
0003 
0004 set_target_properties(KF6SonnetUi PROPERTIES
0005     VERSION     ${SONNET_VERSION}
0006     SOVERSION   ${SONNET_SOVERSION}
0007     EXPORT_NAME SonnetUi
0008 )
0009 
0010 ecm_create_qm_loader(KF6SonnetUi sonnet6_qt)
0011 
0012 qt_wrap_ui(sonnetui_ui_SRCS
0013     configui.ui
0014     sonnetui.ui
0015 )
0016 
0017 target_sources(KF6SonnetUi PRIVATE
0018     ${sonnetui_ui_SRCS}
0019     configdialog.cpp
0020     configview.cpp
0021     configwidget.cpp
0022     dialog.cpp
0023     dictionarycombobox.cpp
0024     highlighter.cpp
0025     spellcheckdecorator.cpp
0026 )
0027 
0028 ecm_qt_declare_logging_category(KF6SonnetUi
0029     HEADER ui_debug.h
0030     IDENTIFIER SONNET_LOG_UI
0031     CATEGORY_NAME kf.sonnet.ui
0032     OLD_CATEGORY_NAMES sonnet.ui
0033     DESCRIPTION "Sonnet UI"
0034     EXPORT SONNET
0035 )
0036 
0037 ecm_generate_headers(SonnetUi_CamelCase_HEADERS
0038   HEADER_NAMES
0039     Dialog
0040     Highlighter
0041     ConfigDialog
0042     ConfigView
0043     ConfigWidget
0044     DictionaryComboBox
0045     SpellCheckDecorator
0046   PREFIX Sonnet
0047   REQUIRED_HEADERS SonnetUi_HEADERS
0048 )
0049 
0050 ecm_generate_export_header(KF6SonnetUi
0051     BASE_NAME SonnetUi
0052     GROUP_BASE_NAME KF
0053     VERSION ${KF_VERSION}
0054     USE_VERSION_HEADER
0055     VERSION_BASE_NAME Sonnet
0056     DEPRECATED_BASE_VERSION 0
0057     DEPRECATION_VERSIONS
0058     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0059 )
0060 
0061 target_link_libraries(KF6SonnetUi
0062     PUBLIC Qt6::Widgets
0063     PRIVATE KF6::SonnetCore
0064 )
0065 
0066 target_include_directories(KF6SonnetUi
0067     INTERFACE
0068         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi>"
0069         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet>"
0070     PUBLIC
0071         "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}>" # version header
0072 )
0073 
0074 install(TARGETS KF6SonnetUi EXPORT KF6SonnetTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0075 
0076 install(FILES ${SonnetUi_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi/Sonnet COMPONENT Devel)
0077 
0078 install(FILES
0079    ${SonnetUi_HEADERS}
0080    ${CMAKE_CURRENT_BINARY_DIR}/sonnetui_export.h
0081    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetUi/sonnet COMPONENT Devel)
0082 
0083 if(BUILD_DESIGNERPLUGIN)
0084     add_subdirectory(designer)
0085 endif()
0086 
0087 if (BUILD_QCH)
0088     ecm_add_qch(
0089         KF6SonnetUi_QCH
0090         NAME SonnetUi
0091         BASE_NAME KF6SonnetUi
0092         VERSION ${KF_VERSION}
0093         ORG_DOMAIN org.kde
0094         SOURCES # using only public headers, to cover only public API
0095             ${SonnetUi_HEADERS}
0096         LINK_QCHS
0097             Qt6Core_QCH
0098             Qt6Gui_QCH
0099             Qt6Widgets_QCH
0100         INCLUDE_DIRS
0101             ${CMAKE_CURRENT_BINARY_DIR}
0102         BLANK_MACROS
0103             SONNETUI_EXPORT
0104             SONNETUI_DEPRECATED_EXPORT
0105             SONNETUI_DEPRECATED
0106             "SONNETUI_DEPRECATED_VERSION(x, y, t)"
0107         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0108         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0109         COMPONENT Devel
0110     )
0111 endif()
0112