src/core/CMakeLists.txt

0001 set(sonnetcore_SRCS
0002     backgroundchecker.cpp
0003     backgroundchecker.h
0004     backgroundchecker_p.h
0005     client.cpp
0006     client_p.h
0007     guesslanguage.cpp
0008     guesslanguage.h
0009     languagefilter.cpp
0010     languagefilter_p.h
0011     loader.cpp
0012     loader_p.h
0013     settings.cpp
0014     settings.h
0015     settingsimpl.cpp
0016     settingsimpl_p.h
0017     speller.cpp
0018     speller.h
0019     spellerplugin.cpp
0020     spellerplugin_p.h
0021     textbreaks.cpp
0022     textbreaks_p.h
0023     tokenizer.cpp
0024     tokenizer_p.h
0025 )
0026
0027 # create trigrams file + add trigrams resource
0028 if (TARGET KF5::parsetrigrams)
0029     add_custom_command(OUTPUT "${CMAKE_BINARY_DIR}/data/trigrams.map"
0030                        COMMAND KF5::parsetrigrams "${CMAKE_SOURCE_DIR}/data/trigrams" > "${CMAKE_BINARY_DIR}/data/trigrams.map")
0031     configure_file(${CMAKE_SOURCE_DIR}/data/trigrams.qrc.in ${CMAKE_BINARY_DIR}/data/trigrams.qrc @ONLY)
0032     qt_add_resources(sonnetcore_SRCS "${CMAKE_BINARY_DIR}/data/trigrams.qrc")
0033 endif()
0034
0035 ecm_qt_declare_logging_category(sonnetcore_SRCS
0036     HEADER core_debug.h
0037     IDENTIFIER SONNET_LOG_CORE
0038     CATEGORY_NAME kf.sonnet.core
0039     OLD_CATEGORY_NAMES sonnet.core
0040     DESCRIPTION "Sonnet Core"
0041     EXPORT SONNET
0042 )
0043
0044 # Dear packagers, this is just used as an extra search paths for plugins. Don't get your panties in a twist.
0045 add_definitions(-DINSTALLATION_PLUGIN_PATH="${CMAKE_INSTALL_PREFIX}/${KDE_INSTALL_PLUGINDIR}")
0046
0047
0048 add_library(KF5SonnetCore ${sonnetcore_SRCS})
0049 ecm_generate_export_header(KF5SonnetCore
0050     BASE_NAME SonnetCore
0051     GROUP_BASE_NAME KF
0052     VERSION ${KF_VERSION}
0053     DEPRECATED_BASE_VERSION 0
0054     #DEPRECATION_VERSIONS 5.65
0055     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0056 )
0057
0058
0059 add_library(KF5::SonnetCore ALIAS KF5SonnetCore)
0060
0061 ecm_generate_headers(SonnetCore_CamelCase_HEADERS
0062   HEADER_NAMES
0063     BackgroundChecker
0064     Speller
0065     GuessLanguage
0066     Settings
0067   PREFIX Sonnet
0068   REQUIRED_HEADERS SonnetCore_HEADERS
0069 )
0070
0071 target_link_libraries(KF5SonnetCore PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0072
0073 set_target_properties(KF5SonnetCore PROPERTIES VERSION ${SONNET_VERSION}
0074                                                SOVERSION ${SONNET_SOVERSION}
0075                                                EXPORT_NAME SonnetCore
0076 )
0077
0078 # CMAKE_CURRENT_BINARY_DIR: for camelcase headers and lowercase forwarders
0079 target_include_directories(KF5SonnetCore INTERFACE
0080     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore>"
0081     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet>"
0082 )
0083 target_include_directories(KF5SonnetCore PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>")
0084
0085 install(TARGETS KF5SonnetCore EXPORT KF5SonnetTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0086
0087 install(FILES ${SonnetCore_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore/Sonnet COMPONENT Devel)
0088
0089 install(FILES
0090    ${SonnetCore_HEADERS}
0091    ${CMAKE_CURRENT_BINARY_DIR}/sonnetcore_export.h
0092    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore/sonnet COMPONENT Devel)
0093
0094 if (BUILD_QCH)
0095     ecm_add_qch(
0096         KF5SonnetCore_QCH
0097         NAME SonnetCore
0098         BASE_NAME KF5SonnetCore
0099         VERSION ${KF_VERSION}
0100         ORG_DOMAIN org.kde
0101         SOURCES # using only public headers, to cover only public API
0102             ${SonnetCore_HEADERS}
0103         LINK_QCHS
0104             Qt5Core_QCH
0105         INCLUDE_DIRS
0106             ${CMAKE_CURRENT_BINARY_DIR}
0107         BLANK_MACROS
0108             SONNETCORE_EXPORT
0109             SONNETCORE_DEPRECATED_EXPORT
0110             SONNETCORE_DEPRECATED
0111             "SONNETCORE_DEPRECATED_VERSION(x, y, t)"
0112         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0113         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0114         COMPONENT Devel
0115     )
0116 endif()
0117
0118 include(ECMGeneratePriFile)
0119 ecm_generate_pri_file(
0120     BASE_NAME SonnetCore
0121     LIB_NAME KF5SonnetCore
0122     DEPS "core"
0123     FILENAME_VAR PRI_FILENAME
0124     INCLUDE_INSTALL_DIRS
0125         ${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet
0126         ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore
0127 )
0128 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})