src/core/CMakeLists.txt

0001 add_library(KF6SonnetCore)
0002 add_library(KF6::SonnetCore ALIAS KF6SonnetCore)
0003
0004 qt_extract_metatypes(KF6SonnetCore)
0005
0006 set_target_properties(KF6SonnetCore PROPERTIES
0007     VERSION     ${SONNET_VERSION}
0008     SOVERSION   ${SONNET_SOVERSION}
0009     EXPORT_NAME SonnetCore
0010 )
0011
0012 target_sources(KF6SonnetCore PRIVATE
0013     backgroundchecker.cpp
0014     backgroundchecker.h
0015     backgroundchecker_p.h
0016     client.cpp
0017     client_p.h
0018     guesslanguage.cpp
0019     guesslanguage.h
0020     languagefilter.cpp
0021     languagefilter_p.h
0022     loader.cpp
0023     loader_p.h
0024     settings.cpp
0025     settings.h
0026     settingsimpl.cpp
0027     settingsimpl_p.h
0028     speller.cpp
0029     speller.h
0030     spellerplugin.cpp
0031     spellerplugin_p.h
0032     textbreaks.cpp
0033     textbreaks_p.h
0034     tokenizer.cpp
0035     tokenizer_p.h
0036 )
0037
0038 # create trigrams file + add trigrams resource
0039 if (TARGET KF6::parsetrigrams)
0040     add_custom_command(OUTPUT "${PROJECT_BINARY_DIR}/data/trigrams.map"
0041                        COMMAND KF6::parsetrigrams "${PROJECT_SOURCE_DIR}/data/trigrams" > "${PROJECT_BINARY_DIR}/data/trigrams.map")
0042     configure_file(${PROJECT_SOURCE_DIR}/data/trigrams.qrc.in "${PROJECT_BINARY_DIR}/data/trigrams.qrc" @ONLY)
0043     target_sources(KF6SonnetCore PRIVATE "${PROJECT_BINARY_DIR}/data/trigrams.qrc")
0044 endif()
0045
0046 ecm_qt_declare_logging_category(KF6SonnetCore
0047     HEADER core_debug.h
0048     IDENTIFIER SONNET_LOG_CORE
0049     CATEGORY_NAME kf.sonnet.core
0050     OLD_CATEGORY_NAMES sonnet.core
0051     DESCRIPTION "Sonnet Core"
0052     EXPORT SONNET
0053 )
0054
0055 # Dear packagers, this is just used as an extra search paths for plugins. Don't get your panties in a twist.
0056 add_definitions(-DINSTALLATION_PLUGIN_PATH="${CMAKE_INSTALL_PREFIX}/${KDE_INSTALL_PLUGINDIR}")
0057
0058 ecm_generate_export_header(KF6SonnetCore
0059     BASE_NAME SonnetCore
0060     GROUP_BASE_NAME KF
0061     VERSION ${KF_VERSION}
0062     USE_VERSION_HEADER
0063     VERSION_BASE_NAME Sonnet
0064     DEPRECATED_BASE_VERSION 0
0065     DEPRECATION_VERSIONS
0066     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0067 )
0068
0069 ecm_generate_headers(SonnetCore_CamelCase_HEADERS
0070   HEADER_NAMES
0071     BackgroundChecker
0072     Speller
0073     GuessLanguage
0074     Settings
0075   PREFIX Sonnet
0076   REQUIRED_HEADERS SonnetCore_HEADERS
0077 )
0078
0079 target_link_libraries(KF6SonnetCore PUBLIC Qt6::Core)
0080
0081 target_include_directories(KF6SonnetCore
0082     INTERFACE
0083         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore>"
0084         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet>"
0085     PUBLIC
0086         "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}>" # version header
0087 )
0088
0089 install(TARGETS KF6SonnetCore EXPORT KF6SonnetTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0090
0091 install(FILES ${SonnetCore_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore/Sonnet COMPONENT Devel)
0092
0093 install(FILES
0094    ${SonnetCore_HEADERS}
0095    ${CMAKE_CURRENT_BINARY_DIR}/sonnetcore_export.h
0096    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/SonnetCore/sonnet COMPONENT Devel)
0097
0098 if (BUILD_QCH)
0099     ecm_add_qch(
0100         KF6SonnetCore_QCH
0101         NAME SonnetCore
0102         BASE_NAME KF6SonnetCore
0103         VERSION ${KF_VERSION}
0104         ORG_DOMAIN org.kde
0105         SOURCES # using only public headers, to cover only public API
0106             ${SonnetCore_HEADERS}
0107         LINK_QCHS
0108             Qt6Core_QCH
0109         INCLUDE_DIRS
0110             ${CMAKE_CURRENT_BINARY_DIR}
0111         BLANK_MACROS
0112             SONNETCORE_EXPORT
0113             SONNETCORE_DEPRECATED_EXPORT
0114             SONNETCORE_DEPRECATED
0115             "SONNETCORE_DEPRECATED_VERSION(x, y, t)"
0116         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0117         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0118         COMPONENT Devel
0119     )
0120 endif()
0121