frameworks/sonnet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.240.0") # handled by release scripts
0004 project(Sonnet VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 include(CMakeDependentOption)
0008 find_package(ECM 5.240.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake )
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMGenerateExportHeader)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMGenerateQmlTypes)
0024 include(ECMFindQmlModule)
0025 include(ECMQmlModule)
0026 include(ECMDeprecationSettings)
0027 include(ECMAddQch)
0028 include(ECMPoQmTools)
0029 include(CMakeDependentOption)
0030
0031 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0032
0033 set(REQUIRED_QT_VERSION 6.5.0)
0034 option(SONNET_USE_WIDGETS "Build components using Qt6Widgets" ON)
0035 option(SONNET_USE_QML "Build components using Qt6Quick" ON)
0036
0037 if(SONNET_USE_WIDGETS)
0038     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0039 endif()
0040
0041 if(SONNET_USE_QML)
0042     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Quick)
0043 endif()
0044
0045 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core)
0046
0047 ecm_setup_version(PROJECT VARIABLE_PREFIX SONNET
0048                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/sonnet_version.h"
0049                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6SonnetConfigVersion.cmake"
0050                         SOVERSION 6)
0051
0052 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0053 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0054
0055 if(SONNET_USE_WIDGETS)
0056     cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0057     add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0058 endif()
0059
0060 ecm_install_po_files_as_qm(poqm)
0061
0062 ecm_set_disabled_deprecation_versions(
0063     QT 6.4
0064 )
0065
0066 add_subdirectory(data)
0067 add_subdirectory(src)
0068 if (BUILD_TESTING)
0069      add_subdirectory(autotests)
0070 endif()
0071
0072 cmake_dependent_option(BUILD_EXAMPLES "Whether to build the examples" OFF "SONNET_USE_WIDGETS" OFF)
0073 if (BUILD_EXAMPLES)
0074     add_subdirectory(examples)
0075 endif()
0076
0077 # create a Config.cmake and a ConfigVersion.cmake file and install them
0078 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Sonnet")
0079
0080 if (BUILD_QCH)
0081     ecm_install_qch_export(
0082         TARGETS KF6SonnetCore_QCH KF6SonnetUi_QCH
0083         FILE KF6SonnetQchTargets.cmake
0084         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0085         COMPONENT Devel
0086     )
0087     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6SonnetQchTargets.cmake\")")
0088 endif()
0089
0090 include(CMakePackageConfigHelpers)
0091
0092 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6SonnetConfig.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/KF6SonnetConfig.cmake"
0093                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0094                               )
0095
0096 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/KF6SonnetConfig.cmake"
0097               "${CMAKE_CURRENT_BINARY_DIR}/KF6SonnetConfigVersion.cmake"
0098         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"  COMPONENT Devel )
0099
0100 install(EXPORT KF6SonnetTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6SonnetTargets.cmake NAMESPACE KF6:: )
0101
0102 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/sonnet_version.h
0103         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet COMPONENT Devel)
0104
0105 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0106
0107 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)