frameworks/sonnet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 project(Sonnet VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 include(CMakeDependentOption)
0008 find_package(ECM 5.106.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake )
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMGenerateExportHeader)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMGenerateQmlTypes)
0024 include(ECMFindQmlModule)
0025 include(ECMQmlModule)
0026 include(ECMDeprecationSettings)
0027 include(ECMAddQch)
0028 include(ECMPoQmTools)
0029 include(CMakeDependentOption)
0030
0031 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0032
0033 set(REQUIRED_QT_VERSION 5.15.2)
0034 option(SONNET_USE_WIDGETS "Build components using Qt${QT_MAJOR_VERSION}Widgets" ON)
0035 option(SONNET_USE_QML "Build components using Qt${QT_MAJOR_VERSION}Quick" ON)
0036
0037 if(SONNET_USE_WIDGETS)
0038     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0039 endif()
0040
0041 if(SONNET_USE_QML)
0042     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Quick)
0043 endif()
0044
0045 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core)
0046
0047 if (QT_MAJOR_VERSION STREQUAL "6")
0048     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core5Compat) # QTextCodec
0049 endif()
0050
0051 ecm_setup_version(PROJECT VARIABLE_PREFIX SONNET
0052                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/sonnet_version.h"
0053                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5SonnetConfigVersion.cmake"
0054                         SOVERSION 5)
0055
0056 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0057 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0058
0059 if(SONNET_USE_WIDGETS)
0060     cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0061     add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0062 endif()
0063
0064 ecm_install_po_files_as_qm(poqm)
0065
0066 ecm_set_disabled_deprecation_versions(
0067     QT 5.15.2
0068 )
0069
0070 add_subdirectory(data)
0071 add_subdirectory(src)
0072 if (BUILD_TESTING)
0073      add_subdirectory(autotests)
0074 endif()
0075
0076 cmake_dependent_option(BUILD_EXAMPLES "Whether to build the examples" OFF "SONNET_USE_WIDGETS" OFF)
0077 if (BUILD_EXAMPLES)
0078     add_subdirectory(examples)
0079 endif()
0080
0081 # create a Config.cmake and a ConfigVersion.cmake file and install them
0082 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Sonnet")
0083
0084 if (BUILD_QCH)
0085     ecm_install_qch_export(
0086         TARGETS KF5SonnetCore_QCH KF5SonnetUi_QCH
0087         FILE KF5SonnetQchTargets.cmake
0088         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089         COMPONENT Devel
0090     )
0091     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5SonnetQchTargets.cmake\")")
0092 endif()
0093
0094 include(CMakePackageConfigHelpers)
0095
0096 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5SonnetConfig.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/KF5SonnetConfig.cmake"
0097                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0098                               )
0099
0100 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/KF5SonnetConfig.cmake"
0101               "${CMAKE_CURRENT_BINARY_DIR}/KF5SonnetConfigVersion.cmake"
0102         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"  COMPONENT Devel )
0103
0104 install(EXPORT KF5SonnetTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5SonnetTargets.cmake NAMESPACE KF5:: )
0105
0106 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/sonnet_version.h
0107         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Sonnet COMPONENT Devel)
0108
0109 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0110
0111 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)