src/widgets/CMakeLists.txt

0001 set(PURPOSEWIDGETS_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR_KF}/purposewidgets")
0002
0003 qt_add_resources(qmlfiles_SRCS purposewidgets-resources.qrc)
0004 add_library(KF5PurposeWidgets menu.cpp ${qmlfiles_SRCS})
0005
0006 ecm_generate_export_header(KF5PurposeWidgets
0007     EXPORT_FILE_NAME purposewidgets_export.h
0008     BASE_NAME PurposeWidgets
0009     GROUP_BASE_NAME KF
0010     VERSION ${KF_VERSION}
0011     DEPRECATED_BASE_VERSION 0
0012     DEPRECATION_VERSIONS 5.104
0013     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0014 )
0015
0016 target_link_libraries(KF5PurposeWidgets
0017     PUBLIC
0018         KF5::Purpose
0019         Qt${QT_MAJOR_VERSION}::Widgets
0020     PRIVATE
0021         Qt${QT_MAJOR_VERSION}::Qml
0022         KF5::I18n
0023 )
0024 set_target_properties(KF5PurposeWidgets PROPERTIES VERSION ${PURPOSE_VERSION}
0025                                           SOVERSION ${PURPOSE_SOVERSION}
0026                                           EXPORT_NAME PurposeWidgets
0027 )
0028 target_include_directories(KF5PurposeWidgets
0029     PUBLIC
0030         "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0031         "$<BUILD_INTERFACE:${Purpose_BINARY_DIR}>"
0032     INTERFACE
0033         "$<INSTALL_INTERFACE:${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}>"
0034 )
0035
0036 install(TARGETS KF5PurposeWidgets EXPORT KF5PurposeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0037 add_library(KF5::PurposeWidgets ALIAS KF5PurposeWidgets)
0038
0039 ecm_generate_headers(PurposeWidgets_CamelCase_HEADERS
0040     HEADER_NAMES
0041         Menu
0042     REQUIRED_HEADERS PurposeWidgets_HEADERS
0043     PREFIX Purpose
0044 )
0045 install(
0046     FILES
0047         ${PurposeWidgets_CamelCase_HEADERS}
0048     DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/Purpose
0049     COMPONENT Devel
0050 )
0051 install(
0052     FILES
0053         ${Purpose_BINARY_DIR}/src/widgets/purposewidgets_export.h
0054         ${PurposeWidgets_HEADERS}
0055     DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/purpose
0056     COMPONENT Devel
0057 )
0058
0059 # provide compat headers for old C++ namespace-part-of-filename includes
0060 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0061    EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.104.0)
0062     install(
0063         FILES compatheaders/Menu
0064         DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/PurposeWidgets
0065         COMPONENT Devel
0066     )
0067     install(
0068         FILES compatheaders/menu.h
0069         DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/purposewidgets
0070         COMPONENT Devel
0071     )
0072 endif()