src/widgets/CMakeLists.txt

0001 set(PURPOSEWIDGETS_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR_KF}/PurposeWidgets")
0002
0003 add_library(KF6PurposeWidgets)
0004 add_library(KF6::PurposeWidgets ALIAS KF6PurposeWidgets)
0005
0006 set_target_properties(KF6PurposeWidgets PROPERTIES
0007     VERSION     ${PURPOSE_VERSION}
0008     SOVERSION   ${PURPOSE_SOVERSION}
0009     EXPORT_NAME PurposeWidgets
0010 )
0011
0012 qt_add_resources(qmlfiles_SRCS purposewidgets-resources.qrc)
0013
0014 target_sources(KF6PurposeWidgets PRIVATE
0015     menu.cpp
0016     ${qmlfiles_SRCS}
0017 )
0018
0019 ecm_generate_export_header(KF6PurposeWidgets
0020     BASE_NAME PurposeWidgets
0021     GROUP_BASE_NAME KF
0022     VERSION ${KF_VERSION}
0023     USE_VERSION_HEADER
0024     VERSION_BASE_NAME Purpose
0025     DEPRECATED_BASE_VERSION 0
0026 )
0027
0028 target_link_libraries(KF6PurposeWidgets
0029     PUBLIC
0030         KF6::Purpose
0031         Qt6::Widgets
0032     PRIVATE
0033         Qt6::Qml
0034         KF6::I18n
0035 )
0036
0037 target_include_directories(KF6PurposeWidgets
0038     PUBLIC
0039         "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0040         "$<BUILD_INTERFACE:${Purpose_BINARY_DIR}>"
0041     INTERFACE
0042         "$<INSTALL_INTERFACE:${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}>"
0043 )
0044
0045 install(TARGETS KF6PurposeWidgets EXPORT KF6PurposeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0046
0047 ecm_generate_headers(PurposeWidgets_CamelCase_HEADERS
0048     HEADER_NAMES
0049         Menu
0050     REQUIRED_HEADERS PurposeWidgets_HEADERS
0051     PREFIX Purpose
0052 )
0053 install(
0054     FILES
0055         ${PurposeWidgets_CamelCase_HEADERS}
0056     DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/Purpose # C++ namespace
0057     COMPONENT Devel
0058 )
0059 install(
0060     FILES
0061         ${Purpose_BINARY_DIR}/src/widgets/purposewidgets_export.h
0062         ${PurposeWidgets_HEADERS}
0063     DESTINATION ${PURPOSEWIDGETS_INSTALL_INCLUDEDIR}/purpose # C++ namespace
0064     COMPONENT Devel
0065 )