modemmanager-qt/src/CMakeLists.txt

0001 #add_subdirectory(dbus)
0002
0003 include_directories(
0004     ${MODEMMANAGER_INCLUDE_DIRS}
0005 )
0006
0007 set(ModemManagerQt_SRCS
0008     bearer.cpp
0009     generictypes.cpp
0010     interface.cpp
0011     manager.cpp
0012     modem.cpp
0013     modemsimple.cpp
0014     modem3gpp.cpp
0015     modem3gppussd.cpp
0016     modemcdma.cpp
0017     modemdevice.cpp
0018     modemfirmware.cpp
0019     modemlocation.cpp
0020     modemmessaging.cpp
0021     modemtime.cpp
0022     sim.cpp
0023     sms.cpp
0024 )
0025
0026 set(DBUS_INTERFACES_FILES
0027    dbus/bearerinterface.cpp
0028    dbus/dbus_manager.cpp
0029    dbus/firmwareinterface.cpp
0030    dbus/locationinterface.cpp
0031    dbus/messaginginterface.cpp
0032    dbus/modem3gppinterface.cpp
0033    dbus/modemcdmainterface.cpp
0034    dbus/modeminterface.cpp
0035    dbus/modemmanager1interface.cpp
0036    dbus/siminterface.cpp
0037    dbus/simpleinterface.cpp
0038    dbus/smsinterface.cpp
0039    dbus/timeinterface.cpp
0040    dbus/ussdinterface.cpp
0041 )
0042
0043 if (${MODEMMANAGER_VERSION} VERSION_EQUAL 1.2.0 OR ${MODEMMANAGER_VERSION} VERSION_GREATER 1.2.0)
0044     set(ModemManagerQt_SRCS
0045         ${ModemManagerQt_SRCS}
0046         modemoma.cpp
0047         modemsignal.cpp
0048         )
0049
0050     set(DBUS_INTERFACES_FILES
0051         ${DBUS_INTERFACES_FILES}
0052         dbus/omainterface.cpp
0053         dbus/signalinterface.cpp
0054         )
0055 endif()
0056
0057 if (${MODEMMANAGER_VERSION} VERSION_EQUAL 1.6.0 OR ${MODEMMANAGER_VERSION} VERSION_GREATER 1.6.0)
0058     set(ModemManagerQt_SRCS
0059         ${ModemManagerQt_SRCS}
0060         modemvoice.cpp
0061         call.cpp
0062         )
0063
0064     set(DBUS_INTERFACES_FILES
0065         ${DBUS_INTERFACES_FILES}
0066         dbus/callinterface.cpp
0067         dbus/voiceinterface.cpp
0068         )
0069 endif()
0070
0071 ecm_qt_export_logging_category(
0072     IDENTIFIER MMQT
0073     CATEGORY_NAME kf.modemmanagerqt
0074     OLD_CATEGORY_NAMES modemmanager-qt
0075     DEFAULT_SEVERITY Warning
0076     DESCRIPTION "ModemManagerQt"
0077     EXPORT MODEMMANAGERQT
0078 )
0079
0080 add_library(KF6ModemManagerQt SHARED ${ModemManagerQt_SRCS} ${DBUS_INTERFACES_FILES})
0081 add_library(KF6::ModemManagerQt ALIAS KF6ModemManagerQt)
0082
0083 ecm_generate_export_header(KF6ModemManagerQt
0084     BASE_NAME ModemManagerQt
0085     GROUP_BASE_NAME KF
0086     VERSION ${KF_VERSION}
0087     USE_VERSION_HEADER
0088     DEPRECATED_BASE_VERSION 0
0089 )
0090
0091 target_include_directories(KF6ModemManagerQt INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt>")
0092
0093 target_link_libraries(KF6ModemManagerQt PUBLIC Qt6::Core Qt6::DBus PRIVATE Qt6::Xml)
0094
0095 set_target_properties(KF6ModemManagerQt PROPERTIES VERSION ${MODEMMANAGERQT_VERSION}
0096                                                    SOVERSION ${MODEMMANAGERQT_SOVERSION}
0097                                                    EXPORT_NAME ModemManagerQt
0098 )
0099
0100 target_include_directories(KF6ModemManagerQt PUBLIC ${MODEMMANAGER_INCLUDE_DIRS})
0101
0102 ########### static lib for tests  ###############
0103 add_library(KF6ModemManagerQt_static STATIC ${ModemManagerQt_SRCS} ${DBUS_INTERFACES_FILES})
0104 set_target_properties(KF6ModemManagerQt_static PROPERTIES COMPILE_FLAGS -DMMQT_STATIC=1)
0105
0106 target_link_libraries(KF6ModemManagerQt_static PUBLIC Qt6::Core Qt6::DBus Qt6::Xml)
0107 target_include_directories(KF6ModemManagerQt_static PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/..;${CMAKE_CURRENT_BINARY_DIR}/..>")
0108 ecm_generate_headers(ModemManagerQt_CamelCaseHEADERS
0109     HEADER_NAMES
0110     Call
0111     Bearer
0112     GenericTypes
0113     Interface
0114     Manager
0115     Modem
0116     Modem3Gpp
0117     Modem3GppUssd
0118     ModemCdma
0119     ModemDevice
0120     ModemFirmware
0121     ModemLocation
0122     ModemMessaging
0123     ModemSignal
0124     ModemSimple
0125     ModemTime
0126     ModemOma
0127     ModemVoice
0128     Sim
0129     Sms
0130     PREFIX ModemManagerQt
0131     REQUIRED_HEADERS ModemManagerQt_HEADERS
0132 )
0133
0134 install(TARGETS KF6ModemManagerQt EXPORT KF6ModemManagerQtTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0135
0136 install(FILES
0137     ${ModemManagerQt_CamelCaseHEADERS}
0138     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt/ModemManagerQt COMPONENT Devel
0139 )
0140
0141 install(FILES
0142     ${CMAKE_CURRENT_BINARY_DIR}/modemmanagerqt_export.h
0143     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt
0144     COMPONENT Devel
0145 )
0146
0147 install(FILES
0148     ${ModemManagerQt_HEADERS}
0149     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt/modemmanagerqt COMPONENT Devel
0150 )
0151
0152 ecm_qt_install_logging_categories(
0153     EXPORT MODEMMANAGERQT
0154     FILE modemmanagerqt.categories
0155     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0156 )
0157
0158 if(BUILD_QCH)
0159     ecm_add_qch(
0160         KF6ModemManagerQt_QCH
0161         NAME ModemManagerQt
0162         BASE_NAME KF6ModemManagerQt
0163         VERSION ${KF_VERSION}
0164         ORG_DOMAIN org.kde
0165         SOURCES # using only public headers, to cover only public API
0166             ${ModemManagerQt_HEADERS}
0167         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0168         LINK_QCHS
0169             Qt6Core_QCH
0170             Qt6DBus_QCH
0171             Qt6Xml_QCH
0172         BLANK_MACROS
0173             MODEMMANAGERQT_EXPORT
0174             MODEMMANAGERQT_DEPRECATED
0175             MODEMMANAGERQT_DEPRECATED_EXPORT
0176         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0177         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0178         COMPONENT Devel
0179     )
0180 endif()