modemmanager-qt/src/CMakeLists.txt

0001 #add_subdirectory(dbus)
0002
0003 include_directories(
0004     ${MODEMMANAGER_INCLUDE_DIRS}
0005 )
0006
0007 set(ModemManagerQt_SRCS
0008     bearer.cpp
0009     generictypes.cpp
0010     interface.cpp
0011     manager.cpp
0012     modem.cpp
0013     modemsimple.cpp
0014     modem3gpp.cpp
0015     modem3gppussd.cpp
0016     modemcdma.cpp
0017     modemdevice.cpp
0018     modemfirmware.cpp
0019     modemlocation.cpp
0020     modemmessaging.cpp
0021     modemtime.cpp
0022     sim.cpp
0023     sms.cpp
0024 )
0025
0026 set(DBUS_INTERFACES_FILES
0027    dbus/bearerinterface.cpp
0028    dbus/dbus_manager.cpp
0029    dbus/firmwareinterface.cpp
0030    dbus/locationinterface.cpp
0031    dbus/messaginginterface.cpp
0032    dbus/modem3gppinterface.cpp
0033    dbus/modemcdmainterface.cpp
0034    dbus/modeminterface.cpp
0035    dbus/modemmanager1interface.cpp
0036    dbus/siminterface.cpp
0037    dbus/simpleinterface.cpp
0038    dbus/smsinterface.cpp
0039    dbus/timeinterface.cpp
0040    dbus/ussdinterface.cpp
0041 )
0042
0043 if (${MODEMMANAGER_VERSION} VERSION_EQUAL 1.2.0 OR ${MODEMMANAGER_VERSION} VERSION_GREATER 1.2.0)
0044     set(ModemManagerQt_SRCS
0045         ${ModemManagerQt_SRCS}
0046         modemoma.cpp
0047         modemsignal.cpp
0048         )
0049
0050     set(DBUS_INTERFACES_FILES
0051         ${DBUS_INTERFACES_FILES}
0052         dbus/omainterface.cpp
0053         dbus/signalinterface.cpp
0054         )
0055 endif()
0056
0057 if (${MODEMMANAGER_VERSION} VERSION_EQUAL 1.6.0 OR ${MODEMMANAGER_VERSION} VERSION_GREATER 1.6.0)
0058     set(ModemManagerQt_SRCS
0059         ${ModemManagerQt_SRCS}
0060         modemvoice.cpp
0061         call.cpp
0062         )
0063
0064     set(DBUS_INTERFACES_FILES
0065         ${DBUS_INTERFACES_FILES}
0066         dbus/callinterface.cpp
0067         dbus/voiceinterface.cpp
0068         )
0069 endif()
0070
0071 ecm_qt_export_logging_category(
0072     IDENTIFIER MMQT
0073     CATEGORY_NAME kf.modemmanagerqt
0074     OLD_CATEGORY_NAMES modemmanager-qt
0075     DEFAULT_SEVERITY Warning
0076     DESCRIPTION "ModemManagerQt"
0077     EXPORT MODEMMANAGERQT
0078 )
0079
0080 add_library(KF5ModemManagerQt SHARED ${ModemManagerQt_SRCS} ${DBUS_INTERFACES_FILES})
0081 generate_export_header(KF5ModemManagerQt BASE_NAME ModemManagerQt)
0082 add_library(KF5::ModemManagerQt ALIAS KF5ModemManagerQt)
0083
0084 target_include_directories(KF5ModemManagerQt INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt>")
0085
0086 target_link_libraries(KF5ModemManagerQt PUBLIC Qt${QT_MAJOR_VERSION}::Core Qt${QT_MAJOR_VERSION}::DBus PRIVATE Qt${QT_MAJOR_VERSION}::Xml)
0087
0088 set_target_properties(KF5ModemManagerQt PROPERTIES VERSION ${MODEMMANAGERQT_VERSION}
0089                                                    SOVERSION ${MODEMMANAGERQT_SOVERSION}
0090                                                    EXPORT_NAME ModemManagerQt
0091 )
0092
0093 target_include_directories(KF5ModemManagerQt PUBLIC ${MODEMMANAGER_INCLUDE_DIRS})
0094
0095 ########### static lib for tests  ###############
0096 add_library(KF5ModemManagerQt_static STATIC ${ModemManagerQt_SRCS} ${DBUS_INTERFACES_FILES})
0097 set_target_properties(KF5ModemManagerQt_static PROPERTIES COMPILE_FLAGS -DMMQT_STATIC=1)
0098
0099 target_link_libraries(KF5ModemManagerQt_static PUBLIC Qt${QT_MAJOR_VERSION}::Core Qt${QT_MAJOR_VERSION}::DBus Qt${QT_MAJOR_VERSION}::Xml)
0100 target_include_directories(KF5ModemManagerQt_static PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/..;${CMAKE_CURRENT_BINARY_DIR}/..>")
0101 if (QT_MAJOR_VERSION STREQUAL "5")
0102     ecm_generate_headers(ModemManagerQt_CamelCaseHEADERS
0103         HEADER_NAMES
0104         Call
0105         Bearer
0106         GenericTypes
0107         Interface
0108         Manager
0109         Modem
0110         Modem3Gpp
0111         Modem3GppUssd
0112         ModemCdma
0113         ModemDevice
0114         ModemFirmware
0115         ModemLocation
0116         ModemMessaging
0117         ModemSignal
0118         ModemSimple
0119         ModemTime
0120         ModemOma
0121         ModemVoice
0122         Sim
0123         Sms
0124         OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/ModemManagerQt"
0125         REQUIRED_HEADERS ModemManagerQt_HEADERS
0126     )
0127 else()
0128     ecm_generate_headers(ModemManagerQt_CamelCaseHEADERS
0129       HEADER_NAMES
0130       Call
0131       Bearer
0132       GenericTypes
0133       Interface
0134       Manager
0135       Modem
0136       Modem3Gpp
0137       Modem3GppUssd
0138       ModemCdma
0139       ModemDevice
0140       ModemFirmware
0141       ModemLocation
0142       ModemMessaging
0143       ModemSignal
0144       ModemSimple
0145       ModemTime
0146       ModemOma
0147       ModemVoice
0148       Sim
0149       Sms
0150       PREFIX ModemManagerQt
0151       REQUIRED_HEADERS ModemManagerQt_HEADERS
0152     )
0153 endif()
0154
0155 install(TARGETS KF5ModemManagerQt EXPORT KF5ModemManagerQtTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0156
0157
0158 # To keep backwards compatibility we stick with this layout for KF5,
0159 # and use the ModemManagerQt/ModemManagerQt and ModemManagerQt/modemmanagerqt layout for KF6
0160 if (QT_MAJOR_VERSION STREQUAL "5")
0161     install(FILES
0162         ${CMAKE_CURRENT_BINARY_DIR}/modemmanagerqt_export.h
0163         ${ModemManagerQt_HEADERS}
0164         ${ModemManagerQt_CamelCaseHEADERS}
0165         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt COMPONENT Devel
0166     )
0167 else()
0168     install(FILES
0169         ${ModemManagerQt_CamelCaseHEADERS}
0170         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt/ModemManagerQt COMPONENT Devel
0171     )
0172
0173     install(FILES
0174         ${CMAKE_CURRENT_BINARY_DIR}/modemmanagerqt_export.h
0175         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt
0176         COMPONENT Devel
0177     )
0178
0179     install(FILES
0180         ${ModemManagerQt_HEADERS}
0181         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ModemManagerQt/modemmanagerqt COMPONENT Devel
0182     )
0183 endif()
0184
0185 ecm_qt_install_logging_categories(
0186     EXPORT MODEMMANAGERQT
0187     FILE modemmanagerqt.categories
0188     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0189 )
0190
0191 if(BUILD_QCH)
0192     ecm_add_qch(
0193         KF5ModemManagerQt_QCH
0194         NAME ModemManagerQt
0195         BASE_NAME KF5ModemManagerQt
0196         VERSION ${KF_VERSION}
0197         ORG_DOMAIN org.kde
0198         SOURCES # using only public headers, to cover only public API
0199             ${ModemManagerQt_HEADERS}
0200         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0201         LINK_QCHS
0202             Qt5Core_QCH
0203             Qt5DBus_QCH
0204             Qt5Xml_QCH
0205         BLANK_MACROS
0206             MODEMMANAGERQT_EXPORT
0207             MODEMMANAGERQT_DEPRECATED
0208             MODEMMANAGERQT_DEPRECATED_EXPORT
0209         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0210         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0211         COMPONENT Devel
0212     )
0213 endif()