frameworks/kwindowsystem/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(KWindowSystem VERSION ${KF_VERSION})
0005
0006 # ECM setup
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEGitCommitHooks)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(CMakePackageConfigHelpers)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(CMakeFindFrameworks)
0024 include(ECMQtDeclareLoggingCategory)
0025 include(ECMDeprecationSettings)
0026 include(ECMAddQch)
0027 include(ECMPoQmTools)
0028 include(ECMGeneratePkgConfigFile)
0029 include(ECMQmlModule)
0030
0031 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 set(kwindowsystem_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kwindowsystem_version.h")
0037 ecm_setup_version(PROJECT VARIABLE_PREFIX KWINDOWSYSTEM
0038                         VERSION_HEADER "${kwindowsystem_version_header}"
0039                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6WindowSystemConfigVersion.cmake"
0040                         SOVERSION 6)
0041
0042 # Dependencies
0043 set(REQUIRED_QT_VERSION 6.5.0)
0044 find_package(Qt6Gui ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0045
0046 option(KWINDOWSYSTEM_QML "Build QML bindings" ON)
0047
0048 if (KWINDOWSYSTEM_QML)
0049     find_package(Qt6Qml ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0050 endif()
0051
0052 option(KWINDOWSYSTEM_X11 "Build X11 support" ON)
0053 option(KWINDOWSYSTEM_WAYLAND "Build Wayland support" ON)
0054
0055 if (WIN32 OR APPLE OR ANDROID)
0056     set(KWINDOWSYSTEM_X11 OFF)
0057     set(KWINDOWSYSTEM_WAYLAND OFF)
0058 endif()
0059
0060 if (KWINDOWSYSTEM_X11)
0061     find_package(X11 REQUIRED)
0062     find_package(XCB COMPONENTS REQUIRED XCB KEYSYMS RES ICCCM)
0063 endif()
0064
0065 if (KWINDOWSYSTEM_WAYLAND)
0066     find_package(Qt6WaylandClient ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0067     find_package(WaylandProtocols 1.21 REQUIRED)
0068     find_package(PlasmaWaylandProtocols REQUIRED)
0069     check_cxx_source_compiles("
0070         #include <fcntl.h>
0071         #include <sys/mman.h>
0072         #include <unistd.h>
0073
0074         int main() {
0075             const int size = 10;
0076             int fd = memfd_create(\"test\", MFD_CLOEXEC | MFD_ALLOW_SEALING);
0077             ftruncate(fd, size);
0078             fcntl(fd, F_ADD_SEALS, F_SEAL_SHRINK | F_SEAL_SEAL);
0079             mmap(nullptr, size, PROT_WRITE, MAP_SHARED, fd, 0);
0080             return 0;
0081         }" HAVE_MEMFD)
0082 endif()
0083
0084 set(KWINDOWSYSTEM_HAVE_X11 ${KWINDOWSYSTEM_X11})
0085
0086 # Subdirectories
0087 ecm_install_po_files_as_qm(poqm)
0088
0089 ecm_set_disabled_deprecation_versions(
0090     QT 6.5
0091 )
0092
0093 add_subdirectory(src)
0094 if (BUILD_TESTING)
0095     add_subdirectory(autotests)
0096     add_subdirectory(tests)
0097 endif()
0098
0099 # create a Config.cmake and a ConfigVersion.cmake file and install them
0100 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6WindowSystem")
0101
0102 if (BUILD_QCH)
0103     ecm_install_qch_export(
0104         TARGETS KF6WindowSystem_QCH
0105         FILE KF6WindowSystemQchTargets.cmake
0106         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0107         COMPONENT Devel
0108     )
0109     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6WindowSystemQchTargets.cmake\")")
0110 endif()
0111
0112 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6WindowSystemConfig.cmake.in"
0113                               "${CMAKE_CURRENT_BINARY_DIR}/KF6WindowSystemConfig.cmake"
0114                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0115                               )
0116
0117 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6WindowSystemConfig.cmake"
0118                "${CMAKE_CURRENT_BINARY_DIR}/KF6WindowSystemConfigVersion.cmake"
0119         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0120         COMPONENT Devel )
0121
0122 install(EXPORT KF6WindowSystemTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6WindowSystemTargets.cmake NAMESPACE KF6:: )
0123
0124
0125 install(FILES ${kwindowsystem_version_header}
0126         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KWindowSystem COMPONENT Devel )
0127
0128 if (NOT WIN32)
0129     ecm_generate_pkgconfig_file(BASE_NAME KF6WindowSystem
0130       INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KWindowSystem
0131       DEPS Qt6Gui
0132     INSTALL)
0133 endif()
0134
0135 include(ECMFeatureSummary)
0136 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0137
0138 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)