frameworks/kwindowsystem/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KWindowSystem VERSION ${KF_VERSION})
0005
0006 # ECM setup
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEGitCommitHooks)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(CMakePackageConfigHelpers)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(CMakeFindFrameworks)
0024 include(ECMQtDeclareLoggingCategory)
0025 include(ECMDeprecationSettings)
0026 include(ECMAddQch)
0027 include(ECMPoQmTools)
0028
0029 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0030
0031 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0032 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0033
0034 # TODO KF6: remove
0035 option(KWINDOWSYSTEM_NO_WIDGETS "Disable deprecated API including QWidget usage, so that KWindowSystem does not link to QtWidgets. Warning: this is binary and source incompatible.")
0036 if (KWINDOWSYSTEM_NO_WIDGETS)
0037     # ensure EXCLUDE_DEPRECATED_BEFORE_AND_AT is at least at the version where all QWidgets API is deprecated
0038     if (NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0039         EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS "5.62.0")
0040         set(EXCLUDE_DEPRECATED_BEFORE_AND_AT "5.62.0")
0041     endif()
0042 endif()
0043
0044 ecm_setup_version(PROJECT VARIABLE_PREFIX KWINDOWSYSTEM
0045                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kwindowsystem_version.h"
0046                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5WindowSystemConfigVersion.cmake"
0047                         SOVERSION 5)
0048
0049 # Dependencies
0050 set(REQUIRED_QT_VERSION 5.15.2)
0051 find_package(Qt${QT_MAJOR_VERSION}Gui ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0052 if(NOT KWINDOWSYSTEM_NO_WIDGETS)
0053     find_package(Qt${QT_MAJOR_VERSION}Widgets ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0054 endif()
0055
0056 if (APPLE)
0057     cmake_find_frameworks(Carbon)
0058     cmake_find_frameworks(CoreFoundation)
0059 endif()
0060
0061 if(WIN32 AND QT_MAJOR_VERSION EQUAL "5")
0062    find_package(Qt5WinExtras REQUIRED)
0063 endif()
0064
0065 if (NOT APPLE)
0066     find_package(X11)
0067 endif()
0068
0069 set(KWINDOWSYSTEM_HAVE_X11 ${X11_FOUND})
0070
0071 if(X11_FOUND)
0072     find_package(XCB COMPONENTS REQUIRED XCB KEYSYMS RES)
0073     set(KWINDOWSYSTEM_HAVE_XFIXES ${X11_Xfixes_FOUND})
0074
0075     if (QT_MAJOR_VERSION STREQUAL "5")
0076         find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED X11Extras)
0077     elseif (QT_MAJOR_VERSION STREQUAL "6")
0078         find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Gui) # qtx11extras_p.h
0079     endif()
0080 endif()
0081
0082 # Subdirectories
0083 ecm_install_po_files_as_qm(poqm)
0084
0085 ecm_set_disabled_deprecation_versions(
0086     QT 5.15.2
0087 )
0088
0089 add_subdirectory(src)
0090 if (BUILD_TESTING)
0091     add_subdirectory(autotests)
0092     add_subdirectory(tests)
0093 endif()
0094
0095 # create a Config.cmake and a ConfigVersion.cmake file and install them
0096 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5WindowSystem")
0097
0098 if (BUILD_QCH)
0099     ecm_install_qch_export(
0100         TARGETS KF5WindowSystem_QCH
0101         FILE KF5WindowSystemQchTargets.cmake
0102         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0103         COMPONENT Devel
0104     )
0105     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5WindowSystemQchTargets.cmake\")")
0106 endif()
0107
0108 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5WindowSystemConfig.cmake.in"
0109                               "${CMAKE_CURRENT_BINARY_DIR}/KF5WindowSystemConfig.cmake"
0110                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0111                               )
0112
0113 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5WindowSystemConfig.cmake"
0114                "${CMAKE_CURRENT_BINARY_DIR}/KF5WindowSystemConfigVersion.cmake"
0115         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0116         COMPONENT Devel )
0117
0118 install(EXPORT KF5WindowSystemTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5WindowSystemTargets.cmake NAMESPACE KF5:: )
0119
0120
0121 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kwindowsystem_version.h
0122         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KWindowSystem COMPONENT Devel )
0123
0124 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0125
0126 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)