frameworks/kwidgetsaddons/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KWidgetsAddons VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMDeprecationSettings)
0020
0021 set(REQUIRED_QT_VERSION 5.15.2)
0022 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0023
0024
0025 include(ECMGenerateExportHeader)
0026 include(CMakePackageConfigHelpers)
0027 include(ECMSetupVersion)
0028 include(ECMGenerateHeaders)
0029 include(ECMAddQch)
0030 include(ECMPoQmTools)
0031 include(ECMQtDeclareLoggingCategory)
0032 include(CMakeDependentOption)
0033
0034 ecm_setup_version(PROJECT VARIABLE_PREFIX KWIDGETSADDONS
0035                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kwidgetsaddons_version.h"
0036                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5WidgetsAddonsConfigVersion.cmake"
0037                         SOVERSION 5)
0038
0039 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0040
0041 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0042 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0043
0044 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0045 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0046
0047
0048 ecm_install_po_files_as_qm(poqm)
0049
0050 configure_file(test-config.h.in ${CMAKE_CURRENT_BINARY_DIR}/test-config.h)
0051
0052 ecm_set_disabled_deprecation_versions(
0053     QT 5.14 # QLabel::pixmap(), cannot be ported, but in a deprecated method
0054 )
0055
0056 add_subdirectory(src)
0057 if (BUILD_TESTING)
0058     add_subdirectory(autotests)
0059     add_subdirectory(tests)
0060     add_subdirectory(examples)
0061 endif()
0062
0063 # create a Config.cmake and a ConfigVersion.cmake file and install them
0064 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5WidgetsAddons")
0065
0066 if (BUILD_QCH)
0067     ecm_install_qch_export(
0068         TARGETS KF5WidgetsAddons_QCH
0069         FILE KF5WidgetsAddonsQchTargets.cmake
0070         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0071         COMPONENT Devel
0072     )
0073     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5WidgetsAddonsQchTargets.cmake\")")
0074 endif()
0075
0076 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5WidgetsAddonsConfig.cmake.in"
0077                               "${CMAKE_CURRENT_BINARY_DIR}/KF5WidgetsAddonsConfig.cmake"
0078                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0079                               )
0080
0081 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5WidgetsAddonsConfig.cmake"
0082                "${CMAKE_CURRENT_BINARY_DIR}/KF5WidgetsAddonsConfigVersion.cmake"
0083         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0084         COMPONENT Devel )
0085
0086 install(EXPORT KF5WidgetsAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5WidgetsAddonsTargets.cmake NAMESPACE KF5:: )
0087
0088 install(FILES
0089   ${CMAKE_CURRENT_BINARY_DIR}/kwidgetsaddons_version.h
0090   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KWidgetsAddons COMPONENT Devel
0091 )
0092
0093 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0094
0095 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)