frameworks/kwidgetsaddons/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(KWidgetsAddons VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMDeprecationSettings)
0020
0021 set(REQUIRED_QT_VERSION 6.5.0)
0022 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0023
0024
0025 include(ECMGenerateExportHeader)
0026 include(CMakePackageConfigHelpers)
0027 include(ECMSetupVersion)
0028 include(ECMGenerateHeaders)
0029 include(ECMAddQch)
0030 include(ECMPoQmTools)
0031 include(ECMQtDeclareLoggingCategory)
0032 include(CMakeDependentOption)
0033
0034 set(kwidgetsaddons_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kwidgetsaddons_version.h")
0035 ecm_setup_version(PROJECT VARIABLE_PREFIX KWIDGETSADDONS
0036                         VERSION_HEADER "${kwidgetsaddons_version_header}"
0037                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6WidgetsAddonsConfigVersion.cmake"
0038                         SOVERSION 6)
0039
0040 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0041
0042 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0043 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0044
0045 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0046 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0047
0048
0049 ecm_install_po_files_as_qm(poqm)
0050
0051 configure_file(test-config.h.in ${CMAKE_CURRENT_BINARY_DIR}/test-config.h)
0052
0053 ecm_set_disabled_deprecation_versions(
0054     QT 6.5
0055 )
0056
0057 add_subdirectory(src)
0058 if (BUILD_TESTING)
0059     add_subdirectory(autotests)
0060     add_subdirectory(tests)
0061     add_subdirectory(examples)
0062 endif()
0063
0064 # create a Config.cmake and a ConfigVersion.cmake file and install them
0065 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6WidgetsAddons")
0066
0067 if (BUILD_QCH)
0068     ecm_install_qch_export(
0069         TARGETS KF6WidgetsAddons_QCH
0070         FILE KF6WidgetsAddonsQchTargets.cmake
0071         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072         COMPONENT Devel
0073     )
0074     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6WidgetsAddonsQchTargets.cmake\")")
0075 endif()
0076
0077 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6WidgetsAddonsConfig.cmake.in"
0078                               "${CMAKE_CURRENT_BINARY_DIR}/KF6WidgetsAddonsConfig.cmake"
0079                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0080                               )
0081
0082 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6WidgetsAddonsConfig.cmake"
0083                "${CMAKE_CURRENT_BINARY_DIR}/KF6WidgetsAddonsConfigVersion.cmake"
0084         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0085         COMPONENT Devel )
0086
0087 install(EXPORT KF6WidgetsAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6WidgetsAddonsTargets.cmake NAMESPACE KF6:: )
0088
0089 install(FILES
0090   ${kwidgetsaddons_version_header}
0091   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KWidgetsAddons COMPONENT Devel
0092 )
0093
0094 include(ECMFeatureSummary)
0095 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0096
0097 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)