ktextwidgets/src/CMakeLists.txt

0001 add_library(KF6TextWidgets)
0002 add_library(KF6::TextWidgets ALIAS KF6TextWidgets)
0003
0004 set_target_properties(KF6TextWidgets PROPERTIES
0005     VERSION     ${KTEXTWIDGETS_VERSION}
0006     SOVERSION   ${KTEXTWIDGETS_SOVERSION}
0007     EXPORT_NAME TextWidgets
0008 )
0009
0010 target_sources(KF6TextWidgets PRIVATE
0011     dialogs/klinkdialog.cpp
0012     dialogs/klinkdialog_p.h
0013     findreplace/kfind.cpp
0014     findreplace/kfinddialog.cpp
0015     findreplace/kfinddialog.h
0016     findreplace/kfinddialog_p.h
0017     findreplace/kfind.h
0018     findreplace/kfind_p.h
0019     findreplace/kreplace.cpp
0020     findreplace/kreplacedialog.cpp
0021     findreplace/kreplacedialog.h
0022     findreplace/kreplace.h
0023     widgets/kpluralhandlingspinbox.cpp
0024     widgets/kpluralhandlingspinbox.h
0025     widgets/krichtextedit.cpp
0026     widgets/krichtextedit.h
0027     widgets/krichtextedit_p.h
0028     widgets/krichtextwidget.cpp
0029     widgets/krichtextwidget.h
0030     widgets/ktextedit.cpp
0031     widgets/ktextedit.h
0032     widgets/ktextedit_p.h
0033     widgets/nestedlisthelper.cpp
0034     widgets/nestedlisthelper_p.h
0035
0036 )
0037
0038 ecm_generate_export_header(KF6TextWidgets
0039     BASE_NAME KTextWidgets
0040     GROUP_BASE_NAME KF
0041     VERSION ${KF_VERSION}
0042     USE_VERSION_HEADER
0043     DEPRECATED_BASE_VERSION 0
0044     DEPRECATION_VERSIONS
0045     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0046 )
0047
0048 set(ktextwidgets_INCLUDES
0049   ${CMAKE_CURRENT_SOURCE_DIR}/dialogs
0050   ${CMAKE_CURRENT_SOURCE_DIR}/findreplace
0051   ${CMAKE_CURRENT_SOURCE_DIR}/widgets
0052 )
0053 target_include_directories(KF6TextWidgets PUBLIC "$<BUILD_INTERFACE:${ktextwidgets_INCLUDES}>"
0054 )
0055
0056 target_include_directories(KF6TextWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets>")
0057
0058 target_link_libraries(KF6TextWidgets
0059 PUBLIC
0060   Qt6::Widgets
0061   KF6::SonnetUi
0062   KF6::I18n
0063 PRIVATE
0064   KF6::SonnetCore
0065   KF6::ConfigWidgets
0066   KF6::Completion
0067 )
0068
0069 if (Qt6TextToSpeech_FOUND)
0070     target_link_libraries(KF6TextWidgets
0071       PRIVATE
0072         Qt6::TextToSpeech)
0073 endif()
0074
0075 ecm_generate_headers(KTextWidgets_HEADERS
0076   HEADER_NAMES
0077   KRichTextEdit
0078   KRichTextWidget
0079   KTextEdit
0080   KPluralHandlingSpinBox
0081
0082   RELATIVE widgets
0083   REQUIRED_HEADERS KTextWidgets_HEADERS
0084 )
0085 ecm_generate_headers(KTextWidgets_HEADERS
0086   HEADER_NAMES
0087   KFind
0088   KFindDialog
0089   KReplace
0090   KReplaceDialog
0091
0092   RELATIVE findreplace
0093   REQUIRED_HEADERS KTextWidgets_HEADERS
0094 )
0095
0096 install(TARGETS KF6TextWidgets EXPORT KF6TextWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0097
0098 install(FILES
0099   ${CMAKE_CURRENT_BINARY_DIR}/ktextwidgets_export.h
0100   ${KTextWidgets_HEADERS}
0101   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets COMPONENT Devel
0102 )
0103
0104 if (BUILD_DESIGNERPLUGIN)
0105     add_subdirectory(designer)
0106 endif()
0107
0108 if (BUILD_QCH)
0109     ecm_add_qch(
0110         KF6TextWidgets_QCH
0111         NAME KTextWidgets
0112         BASE_NAME KF6TextWidgets
0113         VERSION ${KF_VERSION}
0114         ORG_DOMAIN org.kde
0115         SOURCES # using only public headers, to cover only public API
0116             ${KTextWidgets_HEADERS}
0117         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0118         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0119         LINK_QCHS
0120             Qt6Widgets_QCH
0121             KF6SonnetUi_QCH
0122             KF6I18n_QCH
0123         INCLUDE_DIRS
0124             ${CMAKE_CURRENT_BINARY_DIR}
0125             ${ktextwidgets_INCLUDES}
0126         BLANK_MACROS
0127             KTEXTWIDGETS_EXPORT
0128             KTEXTWIDGETS_DEPRECATED_EXPORT
0129             KTEXTWIDGETS_DEPRECATED
0130             "KTEXTWIDGETS_DEPRECATED_VERSION(x, y, t)"
0131             "KTEXTWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0132         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0133         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0134         COMPONENT Devel
0135     )
0136 endif()
0137