ktextwidgets/src/CMakeLists.txt

0001 add_library(KF5TextWidgets)
0002 add_library(KF5::TextWidgets ALIAS KF5TextWidgets)
0003
0004 target_sources(KF5TextWidgets PRIVATE
0005     dialogs/klinkdialog.cpp
0006     dialogs/klinkdialog_p.h
0007     findreplace/kfind.cpp
0008     findreplace/kfinddialog.cpp
0009     findreplace/kfinddialog.h
0010     findreplace/kfinddialog_p.h
0011     findreplace/kfind.h
0012     findreplace/kfind_p.h
0013     findreplace/kreplace.cpp
0014     findreplace/kreplacedialog.cpp
0015     findreplace/kreplacedialog.h
0016     findreplace/kreplace.h
0017     kregexpeditor/kregexpeditorinterface.h
0018     widgets/kpluralhandlingspinbox.cpp
0019     widgets/kpluralhandlingspinbox.h
0020     widgets/krichtextedit.cpp
0021     widgets/krichtextedit.h
0022     widgets/krichtextedit_p.h
0023     widgets/krichtextwidget.cpp
0024     widgets/krichtextwidget.h
0025     widgets/ktextedit.cpp
0026     widgets/ktextedit.h
0027     widgets/ktextedit_p.h
0028     widgets/nestedlisthelper.cpp
0029     widgets/nestedlisthelper_p.h
0030
0031 )
0032
0033 ecm_generate_export_header(KF5TextWidgets
0034     BASE_NAME KTextWidgets
0035     GROUP_BASE_NAME KF
0036     VERSION ${KF_VERSION}
0037     DEPRECATED_BASE_VERSION 0
0038     DEPRECATION_VERSIONS 5.0 5.65 5.70 5.71 5.81 5.83 5.101
0039     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0040 )
0041
0042 set(ktextwidgets_INCLUDES
0043   ${CMAKE_CURRENT_SOURCE_DIR}/dialogs
0044   ${CMAKE_CURRENT_SOURCE_DIR}/findreplace
0045   ${CMAKE_CURRENT_SOURCE_DIR}/kregexpeditor
0046   ${CMAKE_CURRENT_SOURCE_DIR}/widgets
0047 )
0048 target_include_directories(KF5TextWidgets PUBLIC "$<BUILD_INTERFACE:${ktextwidgets_INCLUDES}>"
0049 )
0050
0051 target_include_directories(KF5TextWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets>")
0052
0053 target_link_libraries(KF5TextWidgets
0054 PUBLIC
0055   Qt${QT_MAJOR_VERSION}::Widgets
0056   KF5::SonnetUi
0057   KF5::I18n
0058 PRIVATE
0059   KF5::SonnetCore
0060   KF5::ConfigWidgets
0061   KF5::Completion
0062 )
0063
0064 if (Qt5TextToSpeech_FOUND)
0065     target_link_libraries(KF5TextWidgets
0066 PRIVATE
0067         Qt5::TextToSpeech)
0068 endif()
0069
0070
0071 set_target_properties(KF5TextWidgets PROPERTIES VERSION ${KTEXTWIDGETS_VERSION}
0072                                                 SOVERSION ${KTEXTWIDGETS_SOVERSION}
0073                                                 EXPORT_NAME TextWidgets
0074 )
0075
0076 ecm_generate_headers(KTextWidgets_HEADERS
0077   HEADER_NAMES
0078   KRichTextEdit
0079   KRichTextWidget
0080   KTextEdit
0081   KPluralHandlingSpinBox
0082
0083   RELATIVE widgets
0084   REQUIRED_HEADERS KTextWidgets_HEADERS
0085 )
0086 ecm_generate_headers(KTextWidgets_HEADERS
0087   HEADER_NAMES
0088   KFind
0089   KFindDialog
0090   KReplace
0091   KReplaceDialog
0092
0093   RELATIVE findreplace
0094   REQUIRED_HEADERS KTextWidgets_HEADERS
0095 )
0096
0097 ecm_generate_headers(KTextWidgets_HEADERS
0098   HEADER_NAMES
0099   KRegExpEditorInterface
0100
0101   RELATIVE kregexpeditor
0102   REQUIRED_HEADERS KTextWidgets_HEADERS
0103 )
0104
0105 install(TARGETS KF5TextWidgets EXPORT KF5TextWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0106
0107 install(FILES
0108   ${CMAKE_CURRENT_BINARY_DIR}/ktextwidgets_export.h
0109   ${KTextWidgets_HEADERS}
0110   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets COMPONENT Devel
0111 )
0112
0113 if (BUILD_DESIGNERPLUGIN)
0114     add_subdirectory(designer)
0115 endif()
0116
0117 if (BUILD_QCH)
0118     ecm_add_qch(
0119         KF5TextWidgets_QCH
0120         NAME KTextWidgets
0121         BASE_NAME KF5TextWidgets
0122         VERSION ${KF_VERSION}
0123         ORG_DOMAIN org.kde
0124         SOURCES # using only public headers, to cover only public API
0125             ${KTextWidgets_HEADERS}
0126         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0127         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0128         LINK_QCHS
0129             Qt5Widgets_QCH
0130             KF5SonnetUi_QCH
0131             KF5I18n_QCH
0132         INCLUDE_DIRS
0133             ${CMAKE_CURRENT_BINARY_DIR}
0134             ${ktextwidgets_INCLUDES}
0135         BLANK_MACROS
0136             KTEXTWIDGETS_EXPORT
0137             KTEXTWIDGETS_DEPRECATED_EXPORT
0138             KTEXTWIDGETS_DEPRECATED
0139             "KTEXTWIDGETS_DEPRECATED_VERSION(x, y, t)"
0140             "KTEXTWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0141         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0142         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0143         COMPONENT Devel
0144     )
0145 endif()
0146
0147 include(ECMGeneratePriFile)
0148 ecm_generate_pri_file(BASE_NAME KTextWidgets LIB_NAME KF5TextWidgets DEPS "widgets SonnetUi KI18n" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KTextWidgets)
0149 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})