frameworks/ktexteditor/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KTextEditor VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.115.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 # add own modules to search path, too
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0015
0016 include(KDEInstallDirs)
0017 include(KDECMakeSettings)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019 include(KDEGitCommitHooks)
0020
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMGenerateExportHeader)
0024 include(CMakePackageConfigHelpers)
0025 include(CheckFunctionExists)
0026 include(CheckSymbolExists)
0027 include(KDEPackageAppTemplates)
0028 include(GenerateExportHeader)
0029 include(ECMAddQch)
0030 include(ECMQtDeclareLoggingCategory)
0031 include(ECMDeprecationSettings)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 option(ENABLE_PCH "Enable Precompiled Headers support" OFF)
0037
0038 if (NOT WIN32)
0039     set(ENABLE_KAUTH_DEFAULT ON)
0040 else()
0041     set(ENABLE_KAUTH_DEFAULT OFF)
0042 endif()
0043 option(ENABLE_KAUTH "Enable KAuth integration" ${ENABLE_KAUTH_DEFAULT})
0044 add_feature_info(KAUTH ${ENABLE_KAUTH} "KAuth integration for editing system files")
0045
0046 ecm_setup_version(
0047   PROJECT
0048   VARIABLE_PREFIX KTEXTEDITOR
0049   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/ktexteditor_version.h"
0050   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5TextEditorConfigVersion.cmake"
0051   SOVERSION 5
0052 )
0053
0054 # Dependencies
0055 set(REQUIRED_QT_VERSION 5.15.2)
0056
0057 # Required Qt components to build this framework
0058 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Core Widgets Qml
0059   PrintSupport Xml)
0060 if (QT_MAJOR_VERSION STREQUAL "6")
0061     find_package(Qt6Core5Compat)
0062 endif()
0063
0064 find_package(KF5Archive ${KF_DEP_VERSION} REQUIRED)
0065 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0066 find_package(KF5GuiAddons ${KF_DEP_VERSION} REQUIRED)
0067 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0068 find_package(KF5KIO ${KF_DEP_VERSION} REQUIRED)
0069 find_package(KF5Parts ${KF_DEP_VERSION} REQUIRED)
0070 find_package(KF5Sonnet ${KF_DEP_VERSION} REQUIRED)
0071 find_package(KF5SyntaxHighlighting ${KF_DEP_VERSION} REQUIRED)
0072 find_package(KF5WindowSystem ${KF_DEP_VERSION} REQUIRED)
0073
0074 if (ENABLE_KAUTH)
0075     find_package(KF5Auth ${KF_DEP_VERSION} REQUIRED)
0076     set(HAVE_KAUTH ${KF5Auth_FOUND})
0077 else()
0078     set(HAVE_KAUTH FALSE)
0079 endif()
0080
0081 # EditorConfig integration
0082 find_package(EditorConfig)
0083
0084 # forbid some old things
0085 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0086 ecm_set_disabled_deprecation_versions(
0087     QT 5.15.2
0088     KF 5.97.0
0089     KWIDGETSADDONS 5.77 # We need KSelectAction::triggered(QString)
0090 )
0091
0092 # Subdirectories
0093 add_definitions(-DTRANSLATION_DOMAIN=\"ktexteditor5\")
0094 ki18n_install(po)
0095
0096 add_subdirectory(src)
0097 if (BUILD_TESTING)
0098     add_subdirectory(autotests)
0099 endif()
0100 add_subdirectory(templates)
0101
0102 # Create a Config.cmake and a ConfigVersion.cmake file and install them
0103 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5TextEditor")
0104
0105 if (BUILD_QCH)
0106     ecm_install_qch_export(
0107         TARGETS KF5TextEditor_QCH
0108         FILE KF5TextEditorQchTargets.cmake
0109         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0110         COMPONENT Devel
0111     )
0112     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5TextEditorQchTargets.cmake\")")
0113 endif()
0114
0115 configure_package_config_file(
0116   "${CMAKE_CURRENT_SOURCE_DIR}/KF5TextEditorConfig.cmake.in"
0117   "${CMAKE_CURRENT_BINARY_DIR}/KF5TextEditorConfig.cmake"
0118   INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0119 )
0120
0121 install(FILES
0122   "${CMAKE_CURRENT_BINARY_DIR}/KF5TextEditorConfig.cmake"
0123   "${CMAKE_CURRENT_BINARY_DIR}/KF5TextEditorConfigVersion.cmake"
0124   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0125   COMPONENT Devel
0126 )
0127
0128 install(EXPORT
0129   KF5TextEditorTargets
0130   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0131   FILE KF5TextEditorTargets.cmake
0132   NAMESPACE KF5::
0133 )
0134
0135 install(FILES
0136   "${CMAKE_CURRENT_BINARY_DIR}/ktexteditor_version.h"
0137   DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KTextEditor"
0138   COMPONENT Devel
0139 )
0140
0141 # config.h
0142 check_symbol_exists (fdatasync unistd.h HAVE_FDATASYNC)
0143 configure_file (config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
0144
0145 # let our config.h be found first in any case
0146 include_directories (BEFORE ${CMAKE_CURRENT_BINARY_DIR})
0147
0148 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0149
0150 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)