frameworks/ktexteditor/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KTextEditor VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.249.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 # add own modules to search path, too
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0015
0016 include(KDEInstallDirs)
0017 include(KDECMakeSettings)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019 include(KDEGitCommitHooks)
0020
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMGenerateExportHeader)
0024 include(CMakePackageConfigHelpers)
0025 include(CheckFunctionExists)
0026 include(CheckSymbolExists)
0027 include(KDEPackageAppTemplates)
0028 include(GenerateExportHeader)
0029 include(ECMAddQch)
0030 include(ECMQtDeclareLoggingCategory)
0031 include(ECMDeprecationSettings)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 option(ENABLE_PCH "Enable Precompiled Headers support" ON)
0037
0038 if (NOT WIN32)
0039     set(ENABLE_KAUTH_DEFAULT ON)
0040 else()
0041     set(ENABLE_KAUTH_DEFAULT OFF)
0042 endif()
0043 option(ENABLE_KAUTH "Enable KAuth integration" ${ENABLE_KAUTH_DEFAULT})
0044 add_feature_info(KAUTH ${ENABLE_KAUTH} "KAuth integration for editing system files")
0045
0046 set(ktexteditor_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/ktexteditor_version.h")
0047 ecm_setup_version(
0048   PROJECT
0049   VARIABLE_PREFIX KTEXTEDITOR
0050   VERSION_HEADER "${ktexteditor_version_header}"
0051   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6TextEditorConfigVersion.cmake"
0052   SOVERSION 6
0053 )
0054
0055 # Dependencies
0056 set(REQUIRED_QT_VERSION 6.5.0)
0057
0058 # Required Qt components to build this framework
0059 find_package(Qt6 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Core Widgets Qml PrintSupport TextToSpeech)
0060
0061 # Required Frameworks
0062 find_package(KF6Archive ${KF_DEP_VERSION} REQUIRED)
0063 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0064 find_package(KF6GuiAddons ${KF_DEP_VERSION} REQUIRED)
0065 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0066 find_package(KF6KIO ${KF_DEP_VERSION} REQUIRED)
0067 find_package(KF6Parts ${KF_DEP_VERSION} REQUIRED)
0068 find_package(KF6Sonnet ${KF_DEP_VERSION} REQUIRED)
0069 find_package(KF6SyntaxHighlighting ${KF_DEP_VERSION} REQUIRED)
0070 find_package(KF6TextWidgets ${KF_DEP_VERSION} REQUIRED)
0071
0072 if (ENABLE_KAUTH)
0073     find_package(KF6Auth ${KF_DEP_VERSION} REQUIRED)
0074     set(HAVE_KAUTH ${KF6Auth_FOUND})
0075 else()
0076     set(HAVE_KAUTH FALSE)
0077 endif()
0078
0079 # EditorConfig integration
0080 find_package(EditorConfig)
0081
0082 # forbid some old things
0083 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0084 ecm_set_disabled_deprecation_versions(
0085     QT 6.3
0086 )
0087
0088 # define which offscreen platform plugin to use for tests
0089 # windows has issues with offscreen tests in the CI
0090 set(OFFSCREEN_QPA)
0091 if(NOT WIN32)
0092     set(OFFSCREEN_QPA "-platform" "offscreen")
0093 endif()
0094
0095 # Subdirectories
0096 add_definitions(-DTRANSLATION_DOMAIN=\"ktexteditor6\")
0097 ki18n_install(po)
0098
0099 add_subdirectory(src)
0100 if (BUILD_TESTING)
0101     add_subdirectory(autotests)
0102 endif()
0103 add_subdirectory(templates)
0104
0105 # Create a Config.cmake and a ConfigVersion.cmake file and install them
0106 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6TextEditor")
0107
0108 if (BUILD_QCH)
0109     ecm_install_qch_export(
0110         TARGETS KF6TextEditor_QCH
0111         FILE KF6TextEditorQchTargets.cmake
0112         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0113         COMPONENT Devel
0114     )
0115     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6TextEditorQchTargets.cmake\")")
0116 endif()
0117
0118 configure_package_config_file(
0119   "${CMAKE_CURRENT_SOURCE_DIR}/KF6TextEditorConfig.cmake.in"
0120   "${CMAKE_CURRENT_BINARY_DIR}/KF6TextEditorConfig.cmake"
0121   INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0122 )
0123
0124 install(FILES
0125   "${CMAKE_CURRENT_BINARY_DIR}/KF6TextEditorConfig.cmake"
0126   "${CMAKE_CURRENT_BINARY_DIR}/KF6TextEditorConfigVersion.cmake"
0127   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0128   COMPONENT Devel
0129 )
0130
0131 install(EXPORT
0132   KF6TextEditorTargets
0133   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0134   FILE KF6TextEditorTargets.cmake
0135   NAMESPACE KF6::
0136 )
0137
0138 install(FILES
0139   "${ktexteditor_version_header}"
0140   DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KTextEditor"
0141   COMPONENT Devel
0142 )
0143
0144 # config.h
0145 check_symbol_exists (fdatasync unistd.h HAVE_FDATASYNC)
0146 configure_file (config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
0147
0148 # let our config.h be found first in any case
0149 include_directories (BEFORE ${CMAKE_CURRENT_BINARY_DIR})
0150
0151 include(ECMFeatureSummary)
0152 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0153
0154 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)