frameworks/kpty/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KPty VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0013
0014 # Includes
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018
0019 include(KDEGitCommitHooks)
0020 include(ECMMarkNonGuiExecutable)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMDeprecationSettings)
0025 include(ECMAddQch)
0026 include(CMakePackageConfigHelpers)
0027 include(GenerateExportHeader)
0028
0029 set(REQUIRED_QT_VERSION 5.15.2)
0030 find_package(Qt${QT_MAJOR_VERSION} "${REQUIRED_QT_VERSION}" CONFIG REQUIRED Core)
0031
0032 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0033 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0034
0035 if (UNIX)
0036   find_package(UTEMPTER)
0037   set_package_properties(UTEMPTER PROPERTIES
0038       TYPE OPTIONAL
0039       PURPOSE "Required by KPty for managing UTMP entries"
0040 )
0041
0042   set(HAVE_UTEMPTER ${UTEMPTER_FOUND})
0043 endif()
0044
0045 # create a Config.cmake and a ConfigVersion.cmake file and install them
0046 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Pty")
0047
0048 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0049 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0050
0051 ecm_setup_version(
0052   PROJECT
0053   VARIABLE_PREFIX KPTY
0054   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kpty_version.h"
0055   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5PtyConfigVersion.cmake"
0056   SOVERSION 5)
0057
0058 add_definitions(-DTRANSLATION_DOMAIN=\"kpty5\")
0059 ki18n_install(po)
0060
0061 ecm_set_disabled_deprecation_versions(
0062     QT 5.15.2
0063     KF 5.97
0064 )
0065
0066 add_subdirectory( src )
0067 if (BUILD_TESTING)
0068     add_subdirectory( autotests )
0069 endif()
0070
0071 if (BUILD_QCH)
0072     ecm_install_qch_export(
0073         TARGETS KF5Pty_QCH
0074         FILE KF5PtyQchTargets.cmake
0075         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0076         COMPONENT Devel
0077     )
0078     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5PtyQchTargets.cmake\")")
0079 endif()
0080
0081 configure_package_config_file(
0082   "${CMAKE_CURRENT_SOURCE_DIR}/KF5PtyConfig.cmake.in"
0083   "${CMAKE_CURRENT_BINARY_DIR}/KF5PtyConfig.cmake"
0084   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0085 )
0086
0087 install(FILES
0088   "${CMAKE_CURRENT_BINARY_DIR}/KF5PtyConfig.cmake"
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF5PtyConfigVersion.cmake"
0090   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0091   COMPONENT Devel
0092 )
0093
0094 install(EXPORT KF5PtyTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5PtyTargets.cmake NAMESPACE KF5:: )
0095
0096 install(FILES
0097    ${CMAKE_CURRENT_BINARY_DIR}/kpty_version.h
0098   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPty COMPONENT Devel
0099 )
0100
0101 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0102
0103 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)