frameworks/kpty/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KPty VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0013
0014 # Includes
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018
0019 include(KDEGitCommitHooks)
0020 include(ECMMarkNonGuiExecutable)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMDeprecationSettings)
0025 include(ECMAddQch)
0026 include(ECMGenerateExportHeader)
0027 include(CMakePackageConfigHelpers)
0028
0029 set(REQUIRED_QT_VERSION 6.5.0)
0030 find_package(Qt6 "${REQUIRED_QT_VERSION}" CONFIG REQUIRED Core)
0031
0032 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0033 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0034
0035 if (UNIX)
0036   find_package(UTEMPTER)
0037   set_package_properties(UTEMPTER PROPERTIES
0038       TYPE OPTIONAL
0039       PURPOSE "Required by KPty for managing UTMP entries"
0040 )
0041
0042   set(HAVE_UTEMPTER ${UTEMPTER_FOUND})
0043 endif()
0044
0045 # create a Config.cmake and a ConfigVersion.cmake file and install them
0046 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Pty")
0047
0048 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0049 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0050
0051 set(kpty_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kpty_version.h")
0052 ecm_setup_version(
0053   PROJECT
0054   VARIABLE_PREFIX KPTY
0055   VERSION_HEADER "${kpty_version_header}"
0056   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6PtyConfigVersion.cmake"
0057   SOVERSION 6)
0058
0059 add_definitions(-DTRANSLATION_DOMAIN=\"kpty6\")
0060 ki18n_install(po)
0061
0062 ecm_set_disabled_deprecation_versions(
0063     QT 6.5
0064     KF 5.102
0065 )
0066
0067 add_subdirectory( src )
0068 if (BUILD_TESTING)
0069     add_subdirectory( autotests )
0070 endif()
0071
0072 if (BUILD_QCH)
0073     ecm_install_qch_export(
0074         TARGETS KF6Pty_QCH
0075         FILE KF6PtyQchTargets.cmake
0076         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0077         COMPONENT Devel
0078     )
0079     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6PtyQchTargets.cmake\")")
0080 endif()
0081
0082 configure_package_config_file(
0083   "${CMAKE_CURRENT_SOURCE_DIR}/KF6PtyConfig.cmake.in"
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF6PtyConfig.cmake"
0085   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0086 )
0087
0088 install(FILES
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF6PtyConfig.cmake"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF6PtyConfigVersion.cmake"
0091   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092   COMPONENT Devel
0093 )
0094
0095 install(EXPORT KF6PtyTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6PtyTargets.cmake NAMESPACE KF6:: )
0096
0097 install(
0098     FILES ${kpty_version_header}
0099     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPty
0100     COMPONENT Devel
0101 )
0102
0103 include(ECMFeatureSummary)
0104 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0105
0106 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)