frameworks/kplotting/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(KPlotting VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMDeprecationSettings)
0022 include(ECMAddQch)
0023 include(ECMGenerateExportHeader)
0024 include(CMakePackageConfigHelpers)
0025 include(CMakeDependentOption)
0026
0027 set(REQUIRED_QT_VERSION 6.5.0)
0028 find_package(Qt6Widgets ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0029
0030 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0031 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0032
0033 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0034 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0035
0036 set(kplotting_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kplotting_version.h")
0037 ecm_setup_version(PROJECT VARIABLE_PREFIX KPLOTTING
0038                         VERSION_HEADER "${kplotting_version_header}"
0039                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6PlottingConfigVersion.cmake"
0040                         SOVERSION 6)
0041 ecm_set_disabled_deprecation_versions(
0042     QT 6.5
0043 )
0044
0045 add_subdirectory(src)
0046 add_subdirectory(examples)
0047 if (BUILD_TESTING)
0048     add_subdirectory(autotests)
0049 endif()
0050
0051 # create a Config.cmake and a ConfigVersion.cmake file and install them
0052 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Plotting")
0053
0054 if (BUILD_QCH)
0055     ecm_install_qch_export(
0056         TARGETS KF6Plotting_QCH
0057         FILE KF6PlottingQchTargets.cmake
0058         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0059         COMPONENT Devel
0060     )
0061     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6PlottingQchTargets.cmake\")")
0062 endif()
0063
0064 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6PlottingConfig.cmake.in"
0065                               "${CMAKE_CURRENT_BINARY_DIR}/KF6PlottingConfig.cmake"
0066                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0067                               )
0068
0069 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6PlottingConfig.cmake"
0070                "${CMAKE_CURRENT_BINARY_DIR}/KF6PlottingConfigVersion.cmake"
0071         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072         COMPONENT Devel )
0073
0074 install(EXPORT KF6PlottingTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6PlottingTargets.cmake NAMESPACE KF6:: )
0075
0076 install(FILES ${kplotting_version_header}
0077         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPlotting COMPONENT Devel )
0078
0079 include(ECMFeatureSummary)
0080 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0081
0082 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)