frameworks/kplotting/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KPlotting VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(KDEGitCommitHooks)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMDeprecationSettings)
0022 include(ECMAddQch)
0023 include(GenerateExportHeader)
0024 include(CMakePackageConfigHelpers)
0025 include(CMakeDependentOption)
0026
0027 set(REQUIRED_QT_VERSION 5.15.2)
0028 find_package(Qt${QT_MAJOR_VERSION}Widgets ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0029
0030 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0031 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0032
0033 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0034 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0035
0036 ecm_setup_version(PROJECT VARIABLE_PREFIX KPLOTTING
0037                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kplotting_version.h"
0038                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5PlottingConfigVersion.cmake"
0039                         SOVERSION 5)
0040 ecm_set_disabled_deprecation_versions(
0041     QT 5.15.2
0042 )
0043
0044 add_subdirectory(src)
0045 add_subdirectory(examples)
0046 if (BUILD_TESTING)
0047     add_subdirectory(autotests)
0048 endif()
0049
0050 # create a Config.cmake and a ConfigVersion.cmake file and install them
0051 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Plotting")
0052
0053 if (BUILD_QCH)
0054     ecm_install_qch_export(
0055         TARGETS KF5Plotting_QCH
0056         FILE KF5PlottingQchTargets.cmake
0057         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0058         COMPONENT Devel
0059     )
0060     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5PlottingQchTargets.cmake\")")
0061 endif()
0062
0063 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5PlottingConfig.cmake.in"
0064                               "${CMAKE_CURRENT_BINARY_DIR}/KF5PlottingConfig.cmake"
0065                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0066                               )
0067
0068 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5PlottingConfig.cmake"
0069                "${CMAKE_CURRENT_BINARY_DIR}/KF5PlottingConfigVersion.cmake"
0070         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0071         COMPONENT Devel )
0072
0073 install(EXPORT KF5PlottingTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5PlottingTargets.cmake NAMESPACE KF5:: )
0074
0075 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kplotting_version.h
0076         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPlotting COMPONENT Devel )
0077
0078 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0079
0080 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)