src/backends/CMakeLists.txt

0001 add_library(KF5PeopleBackend)
0002 add_library(KF5::PeopleBackend ALIAS KF5PeopleBackend)
0003
0004 set_target_properties(KF5PeopleBackend PROPERTIES
0005     VERSION     ${KPEOPLE_VERSION}
0006     SOVERSION   ${KPEOPLE_SOVERSION}
0007     EXPORT_NAME PeopleBackend
0008 )
0009
0010 target_sources(KF5PeopleBackend PRIVATE
0011     contactmonitor.cpp
0012     abstractcontact.cpp
0013     basepersonsdatasource.cpp
0014     allcontactsmonitor.cpp
0015     defaultcontactmonitor.cpp
0016     abstractpersonaction.cpp
0017     abstracteditablecontact.cpp
0018 )
0019
0020 target_link_libraries (KF5PeopleBackend
0021                     PUBLIC
0022                         Qt${QT_MAJOR_VERSION}::Widgets #needed for QAction, otherwise QtGui
0023 )
0024
0025 target_include_directories (KF5PeopleBackend PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0026                                     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPeople>"
0027 )
0028
0029 install (TARGETS KF5PeopleBackend
0030          EXPORT KPeopleTargets
0031          ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0032 )
0033
0034 ecm_generate_headers(KPeopleBackend_CamelCase_HEADERS
0035     HEADER_NAMES
0036         AbstractContact
0037         AbstractEditableContact
0038         AbstractPersonAction
0039         AllContactsMonitor
0040         BasePersonsDataSource
0041         ContactMonitor
0042     REQUIRED_HEADERS KPeopleBackend_HEADERS
0043     PREFIX KPeopleBackend
0044 )
0045 install (FILES ${KPeopleBackend_CamelCase_HEADERS}
0046          DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/KPeopleBackend
0047          COMPONENT Devel
0048 )
0049 install(FILES
0050   ${CMAKE_CURRENT_BINARY_DIR}/kpeoplebackend/kpeoplebackend_export.h
0051   ${KPeopleBackend_HEADERS}
0052   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeoplebackend COMPONENT Devel
0053 )
0054
0055 generate_export_header(KF5PeopleBackend EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kpeoplebackend/kpeoplebackend_export.h BASE_NAME KPeopleBackend)
0056
0057 # make available to ecm_add_qch in parent folder
0058 set(KPeopleBackend_QCH_SOURCES ${KPeopleBackend_HEADERS} PARENT_SCOPE)