Warning, /frameworks/kpeople/src/backends/CMakeLists.txt is written in an unsupported language. File is not indexed. 

0001 add_library(KF6PeopleBackend)
0002 add_library(KF6::PeopleBackend ALIAS KF6PeopleBackend)
0003 
0004 set_target_properties(KF6PeopleBackend PROPERTIES
0005     VERSION     ${KPEOPLE_VERSION}
0006     SOVERSION   ${KPEOPLE_SOVERSION}
0007     EXPORT_NAME PeopleBackend
0008 )
0009 
0010 target_sources(KF6PeopleBackend PRIVATE
0011     contactmonitor.cpp
0012     abstractcontact.cpp
0013     basepersonsdatasource.cpp
0014     allcontactsmonitor.cpp
0015     defaultcontactmonitor.cpp
0016     abstractpersonaction.cpp
0017     abstracteditablecontact.cpp
0018 )
0019 
0020 ecm_generate_export_header(KF6PeopleBackend
0021     EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kpeoplebackend/kpeoplebackend_export.h
0022     BASE_NAME KPeopleBackend
0023     GROUP_BASE_NAME KF
0024     VERSION ${KF_VERSION}
0025     USE_VERSION_HEADER
0026     VERSION_BASE_NAME KPeople
0027     DEPRECATED_BASE_VERSION 0
0028 )
0029 
0030 target_link_libraries (KF6PeopleBackend
0031                     PUBLIC
0032                         Qt6::Gui
0033 )
0034 
0035 target_include_directories (KF6PeopleBackend PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0036                                     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPeople>"
0037 )
0038 
0039 add_subdirectory(vcard)
0040 
0041 install (TARGETS KF6PeopleBackend
0042          EXPORT KPeopleTargets
0043          ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0044 )
0045 
0046 ecm_generate_headers(KPeopleBackend_CamelCase_HEADERS
0047     HEADER_NAMES
0048         AbstractContact
0049         AbstractEditableContact
0050         AbstractPersonAction
0051         AllContactsMonitor
0052         BasePersonsDataSource
0053         ContactMonitor
0054     REQUIRED_HEADERS KPeopleBackend_HEADERS
0055     PREFIX KPeopleBackend
0056 )
0057 install (FILES ${KPeopleBackend_CamelCase_HEADERS}
0058          DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/KPeopleBackend
0059          COMPONENT Devel
0060 )
0061 install(FILES
0062   ${CMAKE_CURRENT_BINARY_DIR}/kpeoplebackend/kpeoplebackend_export.h
0063   ${KPeopleBackend_HEADERS}
0064   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeoplebackend COMPONENT Devel
0065 )
0066 
0067 # make available to ecm_add_qch in parent folder
0068 set(KPeopleBackend_QCH_SOURCES ${KPeopleBackend_HEADERS} PARENT_SCOPE)