kpeople/src/CMakeLists.txt

0001 include_directories (${CMAKE_CURRENT_BINARY_DIR}
0002                      ${CMAKE_CURRENT_SOURCE_DIR}
0003 )
0004
0005 add_subdirectory(declarative)
0006 add_subdirectory(widgets)
0007 add_subdirectory(backends)
0008
0009 add_library(KF5People)
0010 add_library(KF5::People ALIAS KF5People)
0011
0012 set_target_properties (KF5People PROPERTIES
0013     VERSION     ${KPEOPLE_VERSION}
0014     SOVERSION   ${KPEOPLE_SOVERSION}
0015     EXPORT_NAME People
0016 )
0017
0018 ecm_qt_declare_logging_category(KF5People
0019     HEADER kpeople_debug.h
0020     IDENTIFIER KPEOPLE_LOG
0021     CATEGORY_NAME kf.people.core
0022     OLD_CATEGORY_NAMES kf5.kpeople
0023     DESCRIPTION "kpeople lib"
0024     EXPORT KPEOPLE
0025 )
0026
0027 target_sources(KF5People PRIVATE
0028     global.cpp
0029     metacontact.cpp
0030     persondata.cpp
0031     matchessolver.cpp
0032     match.cpp
0033     duplicatesfinder.cpp
0034     personsmodel.cpp
0035     personpluginmanager.cpp
0036     personmanager.cpp
0037     personssortfilterproxymodel.cpp
0038     resources.qrc
0039 )
0040
0041 target_link_libraries (KF5People
0042                     PUBLIC
0043                         Qt${QT_MAJOR_VERSION}::Gui
0044                     PRIVATE
0045                         Qt${QT_MAJOR_VERSION}::Sql
0046                         KF5::I18n
0047                         KF5::CoreAddons
0048                         KF5::PeopleBackend
0049 )
0050
0051 if(TARGET Qt${QT_MAJOR_VERSION}::DBus)
0052     target_link_libraries(KF5People PRIVATE Qt${QT_MAJOR_VERSION}::DBus)
0053 endif()
0054
0055 target_include_directories (KF5People PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/kpeople>"
0056                                     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPeople>"
0057 )
0058
0059 if (MSVC)
0060     set_target_properties (KF5People PROPERTIES
0061                            OUTPUT_NAME libkpeople
0062     )
0063 endif (MSVC)
0064
0065 # Install:
0066 install (TARGETS KF5People
0067          EXPORT KPeopleTargets
0068          ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0069 )
0070
0071 ecm_generate_headers(KPeople_CamelCase_HEADERS
0072     HEADER_NAMES
0073         PersonData
0074         PersonPluginManager
0075         PersonsModel
0076         PersonsSortFilterProxyModel
0077         Global
0078     REQUIRED_HEADERS KPeople_HEADERS
0079     PREFIX KPeople
0080 )
0081 install (FILES ${KPeople_CamelCase_HEADERS}
0082          DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/KPeople
0083          COMPONENT Devel
0084 )
0085 install(FILES
0086   ${CMAKE_CURRENT_BINARY_DIR}/kpeople/kpeople_export.h
0087   ${KPeople_HEADERS}
0088   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeople COMPONENT Devel
0089 )
0090
0091 install(FILES personmanager_p.h DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeopleprivate)
0092
0093 generate_export_header(KF5People EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kpeople/kpeople_export.h BASE_NAME KPeople)
0094
0095
0096 if(BUILD_QCH)
0097     ecm_add_qch(
0098         KF5People_QCH
0099         NAME KPeople
0100         BASE_NAME KF5People
0101         VERSION ${KF_VERSION}
0102         ORG_DOMAIN org.kde
0103         SOURCES # using only public headers, to cover only public API
0104             ${KPeople_HEADERS}
0105             ${KPeopleWidgets_QCH_SOURCES}
0106             ${KPeopleBackend_QCH_SOURCES}
0107         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0108         LINK_QCHS
0109             Qt5Gui_QCH
0110             Qt5Widgets_QCH
0111         BLANK_MACROS
0112             KPEOPLE_EXPORT
0113             KPEOPLE_DEPRECATED
0114             KPEOPLE_DEPRECATED_EXPORT
0115             KPEOPLEWIDGETS_EXPORT
0116             KPEOPLEWIDGETS_DEPRECATED
0117             KPEOPLEWIDGETS_DEPRECATED_EXPORT
0118             KPEOPLEBACKEND_EXPORT
0119             KPEOPLEBACKEND_DEPRECATED
0120             KPEOPLEBACKEND_DEPRECATED_EXPORT
0121         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0122         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0123         COMPONENT Devel
0124     )
0125 endif()
0126
0127 ecm_qt_install_logging_categories(
0128     EXPORT KPEOPLE
0129     FILE kpeople.categories
0130     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0131 )
0132
0133 ecm_generate_pri_file(BASE_NAME KPeople LIB_NAME KF5People DEPS "gui" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople)
0134 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0135
0136 if (ANDROID)
0137     install(FILES KF5People-android-dependencies.xml DESTINATION ${KDE_INSTALL_LIBDIR})
0138 endif()