kpeople/src/CMakeLists.txt

0001 include_directories (${CMAKE_CURRENT_BINARY_DIR}
0002                      ${CMAKE_CURRENT_SOURCE_DIR}
0003 )
0004
0005 add_subdirectory(declarative)
0006 add_subdirectory(widgets)
0007 add_subdirectory(backends)
0008
0009 add_library(KF6People)
0010 add_library(KF6::People ALIAS KF6People)
0011
0012 set_target_properties (KF6People PROPERTIES
0013     VERSION     ${KPEOPLE_VERSION}
0014     SOVERSION   ${KPEOPLE_SOVERSION}
0015     EXPORT_NAME People
0016 )
0017
0018 ecm_generate_export_header(KF6People
0019     EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kpeople/kpeople_export.h
0020     BASE_NAME KPeople
0021     GROUP_BASE_NAME KF
0022     VERSION ${KF_VERSION}
0023     USE_VERSION_HEADER
0024     DEPRECATED_BASE_VERSION 0
0025 )
0026
0027 ecm_qt_declare_logging_category(KF6People
0028     HEADER kpeople_debug.h
0029     IDENTIFIER KPEOPLE_LOG
0030     CATEGORY_NAME kf.people.core
0031     OLD_CATEGORY_NAMES kf5.kpeople
0032     DESCRIPTION "kpeople lib"
0033     EXPORT KPEOPLE
0034 )
0035
0036 target_sources(KF6People PRIVATE
0037     actions.cpp
0038     global.cpp
0039     metacontact.cpp
0040     persondata.cpp
0041     matchessolver.cpp
0042     match.cpp
0043     duplicatesfinder.cpp
0044     personsmodel.cpp
0045     personpluginmanager.cpp
0046     personmanager.cpp
0047     personssortfilterproxymodel.cpp
0048     resources.qrc
0049 )
0050
0051 target_link_libraries (KF6People
0052                     PUBLIC
0053                         Qt6::Gui
0054                     PRIVATE
0055                         Qt6::Sql
0056                         KF6::I18n
0057                         KF6::CoreAddons
0058                         KF6::PeopleBackend
0059 )
0060
0061 if(TARGET Qt6::DBus)
0062     target_link_libraries(KF6People PRIVATE Qt6::DBus)
0063 endif()
0064
0065 target_include_directories (KF6People PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/kpeople>"
0066                                     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPeople>"
0067 )
0068
0069 if (MSVC)
0070     set_target_properties (KF6People PROPERTIES
0071                            OUTPUT_NAME libkpeople
0072     )
0073 endif (MSVC)
0074
0075 # Install:
0076 install (TARGETS KF6People
0077          EXPORT KPeopleTargets
0078          ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0079 )
0080
0081 ecm_generate_headers(KPeople_CamelCase_HEADERS
0082     HEADER_NAMES
0083         Actions
0084         PersonData
0085         PersonPluginManager
0086         PersonsModel
0087         PersonsSortFilterProxyModel
0088         Global
0089     REQUIRED_HEADERS KPeople_HEADERS
0090     PREFIX KPeople
0091 )
0092 install (FILES ${KPeople_CamelCase_HEADERS}
0093          DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/KPeople
0094          COMPONENT Devel
0095 )
0096 install(FILES
0097   ${CMAKE_CURRENT_BINARY_DIR}/kpeople/kpeople_export.h
0098   ${KPeople_HEADERS}
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeople COMPONENT Devel
0100 )
0101
0102 install(FILES personmanager_p.h DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPeople/kpeopleprivate)
0103
0104 if(BUILD_QCH)
0105     ecm_add_qch(
0106         KF6People_QCH
0107         NAME KPeople
0108         BASE_NAME KF6People
0109         VERSION ${KF_VERSION}
0110         ORG_DOMAIN org.kde
0111         SOURCES # using only public headers, to cover only public API
0112             ${KPeople_HEADERS}
0113             ${KPeopleWidgets_QCH_SOURCES}
0114             ${KPeopleBackend_QCH_SOURCES}
0115         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0116         LINK_QCHS
0117             Qt6Gui_QCH
0118             Qt6Widgets_QCH
0119         BLANK_MACROS
0120             KPEOPLE_EXPORT
0121             KPEOPLE_DEPRECATED
0122             KPEOPLE_DEPRECATED_EXPORT
0123             KPEOPLEWIDGETS_EXPORT
0124             KPEOPLEWIDGETS_DEPRECATED
0125             KPEOPLEWIDGETS_DEPRECATED_EXPORT
0126             KPEOPLEBACKEND_EXPORT
0127             KPEOPLEBACKEND_DEPRECATED
0128             KPEOPLEBACKEND_DEPRECATED_EXPORT
0129         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0130         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0131         COMPONENT Devel
0132     )
0133 endif()
0134
0135 ecm_qt_install_logging_categories(
0136     EXPORT KPEOPLE
0137     FILE kpeople.categories
0138     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0139 )
0140
0141 if (ANDROID)
0142     install(FILES KF6People-android-dependencies.xml DESTINATION ${KDE_INSTALL_LIBDIR})
0143 endif()