src/kpackage/CMakeLists.txt

0001 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-package.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-package.h)
0002
0003 add_library(KF6Package)
0004 add_library(KF6::Package ALIAS KF6Package)
0005
0006 set_target_properties(KF6Package PROPERTIES
0007     VERSION     ${PACKAGE_VERSION}
0008     SOVERSION   ${PACKAGE_SOVERSION}
0009     EXPORT_NAME Package
0010 )
0011
0012 target_sources(KF6Package PRIVATE
0013     package.cpp
0014     packagestructure.cpp
0015     packageloader.cpp
0016     packagejob.cpp
0017     private/packages.cpp
0018     private/packagejobthread.cpp
0019 )
0020
0021 ecm_qt_declare_logging_category(KF6Package
0022     HEADER kpackage_debug.h
0023     IDENTIFIER KPACKAGE_LOG
0024     CATEGORY_NAME kf.package
0025     OLD_CATEGORY_NAMES kf5.kpackage
0026     DESCRIPTION "kpackage (lib)"
0027     EXPORT KPACKAGE
0028 )
0029
0030 ecm_generate_export_header(KF6Package
0031     EXPORT_FILE_NAME kpackage/package_export.h
0032     BASE_NAME KPackage
0033     GROUP_BASE_NAME KF
0034     VERSION ${KF_VERSION}
0035     USE_VERSION_HEADER
0036     DEPRECATED_BASE_VERSION 0
0037     DEPRECATION_VERSIONS
0038     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0039 )
0040
0041 target_link_libraries(KF6Package
0042 PUBLIC
0043      KF6::CoreAddons
0044 PRIVATE
0045      Qt6::DBus
0046      KF6::Archive
0047      KF6::I18n
0048 )
0049
0050 target_include_directories(KF6Package PUBLIC
0051   "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/..;${CMAKE_CURRENT_BINARY_DIR};${CMAKE_CURRENT_BINARY_DIR}/KPackage>"
0052 )
0053 target_include_directories(KF6Package INTERFACE
0054   "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KPackage>"
0055 )
0056
0057 ########### install files ###############
0058 ecm_generate_headers(Package_CamelCase_HEADERS
0059     HEADER_NAMES
0060         Package
0061         PackageStructure
0062         PackageLoader
0063         PackageJob
0064         packagestructure_compat_p
0065     REQUIRED_HEADERS Package_HEADERS
0066     PREFIX KPackage
0067 )
0068
0069 install(FILES
0070         ${Package_HEADERS}
0071         ${CMAKE_CURRENT_BINARY_DIR}/kpackage/package_export.h
0072         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPackage/kpackage COMPONENT Devel)
0073
0074 install(FILES
0075         ${Package_CamelCase_HEADERS}
0076         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPackage/KPackage COMPONENT Devel)
0077
0078 install(TARGETS KF6Package EXPORT KF6PackageTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0079 if (NOT BUILD_SHARED_LIBS)
0080     install(TARGETS kpackage_common_STATIC EXPORT KF6PackageTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0081 endif()
0082
0083 if(BUILD_QCH)
0084     ecm_add_qch(
0085         KF6Package_QCH
0086         NAME KPackage
0087         BASE_NAME KF6Package
0088         VERSION ${KF_VERSION}
0089         ORG_DOMAIN org.kde
0090         SOURCES # using only public headers, to cover only public API
0091             ${Package_HEADERS}
0092         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0093         LINK_QCHS
0094             KF6CoreAddons_QCH
0095         BLANK_MACROS
0096             KPACKAGE_EXPORT
0097             "KPACKAGE_DEPRECATED_VERSION(x, y, t)"
0098         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0099         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0100         COMPONENT Devel
0101     )
0102 endif()