src/kpackage/CMakeLists.txt

0001 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-package.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-package.h)
0002
0003 add_library(KF5Package)
0004 add_library(KF5::Package ALIAS KF5Package)
0005
0006 set_target_properties(KF5Package PROPERTIES
0007     VERSION     ${PACKAGE_VERSION}
0008     SOVERSION   ${PACKAGE_SOVERSION}
0009     EXPORT_NAME Package
0010 )
0011
0012 target_sources(KF5Package PRIVATE
0013     package.cpp
0014     packagestructure.cpp
0015     packageloader.cpp
0016     private/packages.cpp
0017     private/packagejob.cpp
0018     version.cpp
0019     kpackage.qrc
0020 )
0021
0022 ecm_qt_declare_logging_category(KF5Package
0023     HEADER kpackage_debug.h
0024     IDENTIFIER KPACKAGE_LOG
0025     CATEGORY_NAME kf.package
0026     OLD_CATEGORY_NAMES kf5.kpackage
0027     DESCRIPTION "kpackage (lib)"
0028     EXPORT KPACKAGE
0029 )
0030
0031
0032
0033 ecm_generate_export_header(KF5Package
0034     EXPORT_FILE_NAME kpackage/package_export.h
0035     BASE_NAME KPackage
0036     GROUP_BASE_NAME KF
0037     VERSION ${KF_VERSION}
0038     DEPRECATED_BASE_VERSION 0
0039     DEPRECATION_VERSIONS 5.21 5.84 5.85 5.86 5.106
0040     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0041 )
0042
0043 add_library(kpackage_common_STATIC STATIC private/packagejobthread.cpp private/versionparser.cpp)
0044 target_link_libraries(kpackage_common_STATIC PRIVATE Qt${QT_VERSION_MAJOR}::Core KF5::CoreAddons KF5::Archive KF5::I18n)
0045 set_property(TARGET kpackage_common_STATIC PROPERTY POSITION_INDEPENDENT_CODE ON)
0046
0047 target_link_libraries(KF5Package
0048 PUBLIC
0049      KF5::CoreAddons
0050 PRIVATE
0051      Qt${QT_MAJOR_VERSION}::DBus
0052      KF5::Archive
0053      KF5::I18n
0054      kpackage_common_STATIC
0055 )
0056
0057 target_include_directories(KF5Package PUBLIC
0058   "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/..;${CMAKE_CURRENT_BINARY_DIR};${CMAKE_CURRENT_BINARY_DIR}/KPackage>"
0059 )
0060 target_include_directories(KF5Package INTERFACE
0061   "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF};${KDE_INSTALL_INCLUDEDIR_KF}/KPackage>"
0062 )
0063
0064 ########### install files ###############
0065 ecm_generate_headers(Package_CamelCase_HEADERS
0066     HEADER_NAMES
0067         Package
0068         PackageStructure
0069         PackageLoader
0070     REQUIRED_HEADERS Package_HEADERS
0071     PREFIX KPackage
0072 )
0073
0074 set(Package_HEADERS
0075     ${Package_HEADERS}
0076     version.h
0077 )
0078
0079 install(FILES
0080         ${Package_HEADERS}
0081         ${CMAKE_CURRENT_BINARY_DIR}/kpackage/package_export.h
0082         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPackage/kpackage COMPONENT Devel)
0083
0084 install(FILES
0085         ${Package_CamelCase_HEADERS}
0086         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KPackage/KPackage COMPONENT Devel)
0087
0088 install(FILES
0089    data/kservicetypes5/kpackage-packagestructure.desktop
0090    data/kservicetypes5/kpackage-generic.desktop
0091    data/kservicetypes5/kpackage-genericqml.desktop
0092    DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
0093
0094
0095 install(TARGETS KF5Package EXPORT KF5PackageTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0096 if (NOT BUILD_SHARED_LIBS)
0097     install(TARGETS kpackage_common_STATIC EXPORT KF5PackageTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0098 endif()
0099
0100 if(BUILD_QCH)
0101     ecm_add_qch(
0102         KF5Package_QCH
0103         NAME KPackage
0104         BASE_NAME KF5Package
0105         VERSION ${KF_VERSION}
0106         ORG_DOMAIN org.kde
0107         SOURCES # using only public headers, to cover only public API
0108             ${Package_HEADERS}
0109         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0110         LINK_QCHS
0111             KF5CoreAddons_QCH
0112         BLANK_MACROS
0113             KPACKAGE_EXPORT
0114             "KPACKAGE_DEPRECATED_VERSION(x, y, t)"
0115         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0116         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0117         COMPONENT Devel
0118     )
0119 endif()