Warning, /frameworks/kpackage/autotests/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 find_package(Qt6Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0002 set_package_properties(Qt6Test PROPERTIES PURPOSE "Required for tests")
0003 
0004 remove_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_STRICT_ITERATORS -DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_KEYWORDS)
0005 
0006 include(ECMMarkAsTest)
0007 include(ECMAddTests)
0008 
0009 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
0010 
0011 ecm_add_tests(
0012     fallbackpackagetest.cpp
0013     packagestructuretest.cpp
0014     plasmoidpackagetest.cpp
0015     querytest.cpp
0016     LINK_LIBRARIES Qt6::Test KF6::Package KF6::I18n KF6::Archive
0017 )
0018 
0019 
0020 kcoreaddons_add_plugin(plasmoidstructure_plugin STATIC SOURCES packagestructures/plasmoidstructure.cpp INSTALL_NAMESPACE kf6/packagestructure)
0021 target_link_libraries(plasmoidstructure_plugin KF6::Package)
0022 kcoreaddons_target_static_plugins(querytest NAMESPACE kf6/packagestructure)
0023 kcoreaddons_target_static_plugins(plasmoidpackagetest NAMESPACE kf6/packagestructure)
0024 
0025 set_tests_properties(querytest PROPERTIES RUN_SERIAL TRUE) # it wipes out ~/.qttest/share
0026 set_tests_properties(plasmoidpackagetest PROPERTIES RUN_SERIAL TRUE)
0027 
0028 function(kpackagetooltest testname)
0029     add_test(NAME ${testname}-appstream COMMAND cmake -Dkpackagetool=$<TARGET_FILE:kpackagetool6>
0030                                                       -Dgenerated=${CMAKE_CURRENT_BINARY_DIR}/${testname}.appdata.xml
0031                                                       -Dinput=${CMAKE_CURRENT_LIST_DIR}/data/${testname}/
0032                                                       -Doutput=${CMAKE_CURRENT_SOURCE_DIR}/data/${testname}/${testname}.testappdataxml
0033                                                       -P ${CMAKE_CURRENT_SOURCE_DIR}/kpackagetoolappstreamtest.cmake
0034     )
0035     set(XDG_DATA_DIRS "$ENV{XDG_DATA_DIRS}")
0036     if(NOT XDG_DATA_DIRS)
0037         set(XDG_DATA_DIRS "/usr/local/share:/usr/share")
0038     endif()
0039     set_property(TEST ${testname}-appstream PROPERTY ENVIRONMENT "XDG_DATA_DIRS=${CMAKE_SOURCE_DIR}/src/kpackage/data:${XDG_DATA_DIRS}")
0040 endfunction()
0041 
0042 foreach(var "testfallbackpackage" "testpackage" "testpackage-nodisplay" "testpackagesdep" "testpackagesdepinvalid") # "customcontent" "simplecontent"
0043     kpackagetooltest(${var})
0044 endforeach()
0045 
0046 add_subdirectory(mockdepresolver)