kpackage/autotests/CMakeLists.txt

0001 find_package(Qt${QT_MAJOR_VERSION}Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0002 set_package_properties(Qt${QT_MAJOR_VERSION}Test PROPERTIES PURPOSE "Required for tests")
0003
0004 remove_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_STRICT_ITERATORS -DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_KEYWORDS)
0005
0006 include(ECMMarkAsTest)
0007 include(ECMAddTests)
0008
0009 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
0010
0011 add_library(kpackage_test_static STATIC packagestructures/plasmoidstructure.cpp)
0012 set_property(TARGET kpackage_test_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0013 target_link_libraries(kpackage_test_static KF5::Package KF5::Archive KF5::CoreAddons KF5::I18n )
0014
0015 MACRO(PLASMA_UNIT_TESTS)
0016        FOREACH(_testname ${ARGN})
0017                ecm_add_test(
0018                        ${_testname}.cpp
0019                        LINK_LIBRARIES Qt${QT_MAJOR_VERSION}::Test kpackage_test_static
0020                        TEST_NAME ${_testname}
0021                        NAME_PREFIX "plasma-")
0022        ENDFOREACH(_testname)
0023 ENDMACRO(PLASMA_UNIT_TESTS)
0024
0025 PLASMA_UNIT_TESTS(
0026     fallbackpackagetest
0027     packagestructuretest
0028     plasmoidpackagetest
0029     rccpackagetest
0030     querytest
0031 )
0032
0033
0034 kcoreaddons_add_plugin(plasmoidstructure_plugin STATIC SOURCES packagestructures/plugin.cpp INSTALL_NAMESPACE kpackage/packagestructure)
0035 target_link_libraries(plasmoidstructure_plugin kpackage_test_static)
0036 kcoreaddons_target_static_plugins(querytest kpackage/packagestructure)
0037
0038 set_tests_properties(plasma-querytest PROPERTIES RUN_SERIAL TRUE) # it wipes out ~/.qttest/share
0039 set_tests_properties(plasma-plasmoidpackagetest PROPERTIES RUN_SERIAL TRUE)
0040
0041 function(kpackagetool5test testname)
0042     add_test(NAME ${testname}-appstream COMMAND cmake -Dkpackagetool=$<TARGET_FILE:kpackagetool5>
0043                                                       -Dgenerated=${CMAKE_CURRENT_BINARY_DIR}/${testname}.appdata.xml
0044                                                       -Dinput=${CMAKE_CURRENT_LIST_DIR}/data/${testname}/
0045                                                       -Doutput=${CMAKE_CURRENT_SOURCE_DIR}/data/${testname}/${testname}.testappdataxml
0046                                                       -P ${CMAKE_CURRENT_SOURCE_DIR}/kpackagetoolappstreamtest.cmake
0047     )
0048     set(XDG_DATA_DIRS "$ENV{XDG_DATA_DIRS}")
0049     if(NOT XDG_DATA_DIRS)
0050         set(XDG_DATA_DIRS "/usr/local/share:/usr/share")
0051     endif()
0052     set_property(TEST ${testname}-appstream PROPERTY ENVIRONMENT "XDG_DATA_DIRS=${CMAKE_SOURCE_DIR}/src/kpackage/data:${XDG_DATA_DIRS}")
0053 endfunction()
0054
0055 foreach(var "testfallbackpackage" "testpackage" "testpackage-nodisplay" "testjsonmetadatapackage" "testpackagesdep" "testpackagesdepinvalid") # "customcontent" "simplecontent"
0056     kpackagetool5test(${var})
0057 endforeach()
0058
0059 file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/testpackage-rcc")
0060 set(kpkgqrc "${CMAKE_CURRENT_SOURCE_DIR}/data/testpackage-rcc/resources.qrc")
0061 set(kpkgrcc "${CMAKE_CURRENT_BINARY_DIR}/testpackage-rcc/contents.rcc")
0062 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/data/testpackage-rcc/metadata.json"  ${CMAKE_CURRENT_BINARY_DIR}/testpackage-rcc COPYONLY)
0063 add_custom_command(OUTPUT ${kpkgrcc}
0064                     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
0065         COMMAND Qt${QT_MAJOR_VERSION}::rcc ${kpkgqrc} --binary -o ${kpkgrcc})
0066 add_custom_target(testpackage-rcc ALL DEPENDS ${kpkgrcc})
0067
0068
0069 add_subdirectory(mockdepresolver)