kjobwidgets/src/CMakeLists.txt

0001 configure_file(config-kjobwidgets.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kjobwidgets.h )
0002
0003 add_library(KF5JobWidgets)
0004 add_library(KF5::JobWidgets ALIAS KF5JobWidgets)
0005
0006 set_target_properties(KF5JobWidgets PROPERTIES
0007     VERSION     ${KJOBWIDGETS_VERSION}
0008     SOVERSION   ${KJOBWIDGETS_SOVERSION}
0009     EXPORT_NAME JobWidgets
0010 )
0011
0012 ecm_create_qm_loader(KF5JobWidgets kjobwidgets5_qt)
0013
0014 set(kjobwidgets_dbus_SRCS)
0015 if (TARGET Qt${QT_MAJOR_VERSION}::DBus)
0016     qt_add_dbus_interfaces(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewServer.xml )
0017     qt_add_dbus_interface(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobView.xml jobviewiface )
0018
0019     qt_add_dbus_interfaces(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewServerV2.xml )
0020     qt_add_dbus_interface(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewV3.xml jobviewv3iface )
0021 endif()
0022
0023 target_sources(KF5JobWidgets PRIVATE
0024     kabstractwidgetjobtracker.cpp
0025     kabstractwidgetjobtracker.h
0026     kabstractwidgetjobtracker_p.h
0027     kdialogjobuidelegate.cpp
0028     kdialogjobuidelegate.h
0029     kjobtrackerformatters.cpp
0030     kjobtrackerformatters_p.h
0031     kjobwidgets.cpp
0032     kjobwidgets.h
0033     kstatusbarjobtracker.cpp
0034     kstatusbarjobtracker.h
0035     kstatusbarjobtracker_p.h
0036     kwidgetjobtracker.cpp
0037     kwidgetjobtracker.h
0038     kwidgetjobtracker_p.h
0039
0040     ${kjobwidgets_dbus_SRCS}
0041 )
0042 if (TARGET Qt${QT_MAJOR_VERSION}::DBus)
0043     target_sources(KF5JobWidgets PRIVATE
0044         kuiserverjobtracker.cpp
0045         kuiserverjobtracker.h
0046         kuiserverjobtracker_p.h
0047         kuiserverv2jobtracker.cpp
0048         kuiserverv2jobtracker.h
0049         kuiserverv2jobtracker_p.h
0050     )
0051 endif()
0052
0053 ecm_qt_declare_logging_category(KF5JobWidgets
0054     HEADER debug.h
0055     IDENTIFIER KJOBWIDGETS
0056     CATEGORY_NAME kf.jobwidgets
0057     OLD_CATEGORY_NAMES kf5.kjobwidgets
0058     DESCRIPTION "KJobWidgets"
0059     EXPORT KJOBWIDGETS
0060 )
0061
0062 ecm_generate_export_header(KF5JobWidgets
0063     BASE_NAME KJobWidgets
0064     GROUP_BASE_NAME KF
0065     VERSION ${KF_VERSION}
0066     DEPRECATED_BASE_VERSION 0
0067     DEPRECATION_VERSIONS 5.79
0068     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0069 )
0070
0071 target_include_directories(KF5JobWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets>")
0072
0073 target_link_libraries(KF5JobWidgets
0074    PUBLIC
0075       Qt${QT_MAJOR_VERSION}::Widgets
0076       KF5::CoreAddons    # KJob
0077    PRIVATE
0078       KF5::WidgetsAddons # KSqueezedTextLabel
0079 )
0080 if (TARGET Qt${QT_MAJOR_VERSION}::DBus)
0081     target_link_libraries(KF5JobWidgets PRIVATE Qt${QT_MAJOR_VERSION}::DBus)
0082 endif()
0083
0084 if (HAVE_X11)
0085     if (TARGET Qt5::X11Extras)
0086         target_link_libraries(KF5JobWidgets PRIVATE Qt5::X11Extras)
0087     elseif (TARGET Qt6::Gui)
0088         target_link_libraries(KF5JobWidgets PRIVATE Qt6::GuiPrivate) # qtx11extras_p.h
0089     endif()
0090 endif ()
0091
0092 ecm_generate_headers(KJobWidgets_HEADERS
0093   HEADER_NAMES
0094   KAbstractWidgetJobTracker
0095   KDialogJobUiDelegate
0096   KUiServerJobTracker
0097   KUiServerV2JobTracker
0098   KJobWidgets
0099   KStatusBarJobTracker
0100   KWidgetJobTracker
0101
0102   REQUIRED_HEADERS KJobWidgets_HEADERS
0103 )
0104
0105 install(TARGETS KF5JobWidgets EXPORT KF5JobWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0106
0107 install(FILES
0108   org.kde.JobViewServer.xml
0109   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0110   RENAME kf5_org.kde.JobViewServer.xml)
0111
0112 install(FILES
0113   org.kde.JobView.xml
0114   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0115   RENAME kf5_org.kde.JobView.xml)
0116
0117 install(FILES
0118   org.kde.JobViewV2.xml
0119   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0120   RENAME kf5_org.kde.JobViewV2.xml)
0121
0122 install(FILES
0123   ${CMAKE_CURRENT_BINARY_DIR}/kjobwidgets_export.h
0124   ${KJobWidgets_HEADERS}
0125   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets COMPONENT Devel
0126 )
0127
0128 ecm_qt_install_logging_categories(
0129     EXPORT KJOBWIDGETS
0130     FILE kjobwidgets.categories
0131     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0132 )
0133
0134 if(BUILD_QCH)
0135     ecm_add_qch(
0136         KF5JobWidgets_QCH
0137         NAME KJobWidgets
0138         BASE_NAME KF5JobWidgets
0139         VERSION ${KF_VERSION}
0140         ORG_DOMAIN org.kde
0141         SOURCES # using only public headers, to cover only public API
0142             ${KJobWidgets_HEADERS}
0143         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0144         LINK_QCHS
0145             KF5CoreAddons_QCH
0146             Qt5Widgets_QCH
0147             Qt5Gui_QCH
0148             Qt5Core_QCH
0149         INCLUDE_DIRS
0150             ${CMAKE_CURRENT_BINARY_DIR}
0151         BLANK_MACROS
0152             KJOBWIDGETS_EXPORT
0153         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0154         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0155         COMPONENT Devel
0156     )
0157 endif()
0158
0159 include(ECMGeneratePriFile)
0160 ecm_generate_pri_file(BASE_NAME KJobWidgets LIB_NAME KF5JobWidgets DEPS "widgets KCoreAddons" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets)
0161 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})