kjobwidgets/src/CMakeLists.txt

0001 configure_file(config-kjobwidgets.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kjobwidgets.h )
0002
0003 add_library(KF6JobWidgets)
0004 add_library(KF6::JobWidgets ALIAS KF6JobWidgets)
0005
0006 set_target_properties(KF6JobWidgets PROPERTIES
0007     VERSION     ${KJOBWIDGETS_VERSION}
0008     SOVERSION   ${KJOBWIDGETS_SOVERSION}
0009     EXPORT_NAME JobWidgets
0010 )
0011
0012 ecm_create_qm_loader(KF6JobWidgets kjobwidgets6_qt)
0013
0014 set(kjobwidgets_dbus_SRCS)
0015 if (TARGET Qt6::DBus)
0016     qt_add_dbus_interfaces(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewServer.xml )
0017     qt_add_dbus_interface(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobView.xml jobviewiface )
0018
0019     qt_add_dbus_interfaces(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewServerV2.xml )
0020     qt_add_dbus_interface(kjobwidgets_dbus_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/org.kde.JobViewV3.xml jobviewv3iface )
0021 endif()
0022
0023 target_sources(KF6JobWidgets PRIVATE
0024     kabstractwidgetjobtracker.cpp
0025     kabstractwidgetjobtracker.h
0026     kabstractwidgetjobtracker_p.h
0027     kdialogjobuidelegate.cpp
0028     kdialogjobuidelegate.h
0029     kjobtrackerformatters.cpp
0030     kjobtrackerformatters_p.h
0031     kstatusbarjobtracker.cpp
0032     kstatusbarjobtracker.h
0033     kstatusbarjobtracker_p.h
0034     kwidgetjobtracker.cpp
0035     kwidgetjobtracker.h
0036     kwidgetjobtracker_p.h
0037     knotificationjobuidelegate.cpp
0038     knotificationjobuidelegate.h
0039
0040     ${kjobwidgets_dbus_SRCS}
0041 )
0042 if (TARGET Qt6::DBus)
0043     target_sources(KF6JobWidgets PRIVATE
0044         kuiserverjobtracker.cpp
0045         kuiserverjobtracker.h
0046         kuiserverjobtracker_p.h
0047         kuiserverv2jobtracker.cpp
0048         kuiserverv2jobtracker.h
0049         kuiserverv2jobtracker_p.h
0050     )
0051 endif()
0052
0053 ecm_qt_declare_logging_category(KF6JobWidgets
0054     HEADER debug.h
0055     IDENTIFIER KJOBWIDGETS
0056     CATEGORY_NAME kf.jobwidgets
0057     OLD_CATEGORY_NAMES kf5.kjobwidgets
0058     DESCRIPTION "KJobWidgets"
0059     EXPORT KJOBWIDGETS
0060 )
0061
0062 ecm_generate_export_header(KF6JobWidgets
0063     BASE_NAME KJobWidgets
0064     GROUP_BASE_NAME KF
0065     VERSION ${KF_VERSION}
0066     USE_VERSION_HEADER
0067     DEPRECATED_BASE_VERSION 0
0068     DEPRECATION_VERSIONS
0069     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0070 )
0071
0072 target_include_directories(KF6JobWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets>")
0073
0074 target_link_libraries(KF6JobWidgets
0075    PUBLIC
0076       Qt6::Widgets
0077       KF6::CoreAddons    # KJob
0078    PRIVATE
0079       KF6::WidgetsAddons # KSqueezedTextLabel
0080       KF6::Notifications
0081 )
0082 if (TARGET Qt6::DBus)
0083     target_link_libraries(KF6JobWidgets PRIVATE Qt6::DBus)
0084 endif()
0085
0086 if (HAVE_X11)
0087     target_link_libraries(KF6JobWidgets PRIVATE Qt6::GuiPrivate) # qtx11extras_p.h
0088 endif ()
0089
0090 ecm_generate_headers(KJobWidgets_HEADERS
0091   HEADER_NAMES
0092   KAbstractWidgetJobTracker
0093   KDialogJobUiDelegate
0094   KUiServerJobTracker
0095   KUiServerV2JobTracker
0096   KStatusBarJobTracker
0097   KWidgetJobTracker
0098   KNotificationJobUiDelegate
0099
0100   REQUIRED_HEADERS KJobWidgets_HEADERS
0101 )
0102
0103 install(TARGETS KF6JobWidgets EXPORT KF6JobWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0104
0105 install(FILES
0106   org.kde.JobViewServer.xml
0107   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0108   RENAME kf6_org.kde.JobViewServer.xml)
0109
0110 install(FILES
0111   org.kde.JobView.xml
0112   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0113   RENAME kf6_org.kde.JobView.xml)
0114
0115 install(FILES
0116   org.kde.JobViewV2.xml
0117   DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0118   RENAME kf6_org.kde.JobViewV2.xml)
0119
0120 install(FILES
0121   ${CMAKE_CURRENT_BINARY_DIR}/kjobwidgets_export.h
0122   ${KJobWidgets_HEADERS}
0123   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KJobWidgets COMPONENT Devel
0124 )
0125
0126 ecm_qt_install_logging_categories(
0127     EXPORT KJOBWIDGETS
0128     FILE kjobwidgets.categories
0129     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0130 )
0131
0132 if(BUILD_QCH)
0133     ecm_add_qch(
0134         KF6JobWidgets_QCH
0135         NAME KJobWidgets
0136         BASE_NAME KF6JobWidgets
0137         VERSION ${KF_VERSION}
0138         ORG_DOMAIN org.kde
0139         SOURCES # using only public headers, to cover only public API
0140             ${KJobWidgets_HEADERS}
0141         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0142         LINK_QCHS
0143             KF6CoreAddons_QCH
0144             Qt6Widgets_QCH
0145             Qt6Gui_QCH
0146             Qt6Core_QCH
0147         INCLUDE_DIRS
0148             ${CMAKE_CURRENT_BINARY_DIR}
0149         BLANK_MACROS
0150             KJOBWIDGETS_EXPORT
0151         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0152         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0153         COMPONENT Devel
0154     )
0155 endif()
0156