kitemviews/src/CMakeLists.txt

0001 add_library(KF6ItemViews)
0002 add_library(KF6::ItemViews ALIAS KF6ItemViews)
0003
0004 set_target_properties(KF6ItemViews PROPERTIES
0005     VERSION     ${KITEMVIEWS_VERSION}
0006     SOVERSION   ${KITEMVIEWS_SOVERSION}
0007     EXPORT_NAME ItemViews
0008 )
0009
0010 ecm_create_qm_loader(KF6ItemViews kitemviews6_qt)
0011
0012 target_sources(KF6ItemViews PRIVATE
0013     kcategorizedsortfilterproxymodel.cpp
0014     kcategorizedsortfilterproxymodel.h
0015     kcategorizedsortfilterproxymodel_p.h
0016     kcategorizedview.cpp
0017     kcategorizedview.h
0018     kcategorizedview_p.h
0019     kcategorydrawer.cpp
0020     kcategorydrawer.h
0021     kextendableitemdelegate.cpp
0022     kextendableitemdelegate.h
0023     klistwidgetsearchline.cpp
0024     klistwidgetsearchline.h
0025     ktreewidgetsearchline.cpp
0026     ktreewidgetsearchline.h
0027     ktreewidgetsearchlinewidget.cpp
0028     ktreewidgetsearchlinewidget.h
0029     kwidgetitemdelegate.cpp
0030     kwidgetitemdelegate.h
0031     kwidgetitemdelegate_p.h
0032     kwidgetitemdelegatepool.cpp
0033     kwidgetitemdelegatepool_p.h
0034
0035 )
0036
0037 ecm_qt_declare_logging_category(KF6ItemViews
0038     HEADER kitemviews_debug.h
0039     IDENTIFIER KITEMVIEWS_LOG
0040     CATEGORY_NAME kf.itemviews
0041     DESCRIPTION "KItemViews"
0042     EXPORT KITEMVIEWS
0043 )
0044
0045 ecm_generate_export_header(KF6ItemViews
0046     BASE_NAME KItemViews
0047     GROUP_BASE_NAME KF
0048     VERSION ${KF_VERSION}
0049     USE_VERSION_HEADER
0050     DEPRECATED_BASE_VERSION 0
0051     DEPRECATION_VERSIONS
0052     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0053 )
0054
0055
0056 target_include_directories(KF6ItemViews INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews>")
0057
0058 target_link_libraries(KF6ItemViews PUBLIC Qt6::Widgets)
0059
0060 ecm_generate_headers(KItemViews_HEADERS
0061   HEADER_NAMES
0062   KCategorizedSortFilterProxyModel
0063   KCategorizedView
0064   KCategoryDrawer
0065   KExtendableItemDelegate
0066   KListWidgetSearchLine
0067   KTreeWidgetSearchLine
0068   KTreeWidgetSearchLineWidget
0069   KWidgetItemDelegate
0070
0071   REQUIRED_HEADERS KItemViews_HEADERS
0072 )
0073
0074 install(TARGETS KF6ItemViews EXPORT KF6ItemViewsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0075
0076 install(FILES
0077   ${CMAKE_CURRENT_BINARY_DIR}/kitemviews_export.h
0078   ${KItemViews_HEADERS}
0079   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews COMPONENT Devel
0080 )
0081
0082 if(BUILD_DESIGNERPLUGIN)
0083     add_subdirectory(designer)
0084 endif()
0085
0086 if(BUILD_QCH)
0087     ecm_add_qch(
0088         KF6ItemViews_QCH
0089         NAME KItemViews
0090         BASE_NAME KF6ItemViews
0091         VERSION ${KF_VERSION}
0092         ORG_DOMAIN org.kde
0093         SOURCES # using only public headers, to cover only public API
0094             ${KItemViews_HEADERS}
0095         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0096         LINK_QCHS
0097             Qt6Widgets_QCH
0098             Qt6Gui_QCH
0099             Qt6Core_QCH
0100         INCLUDE_DIRS
0101             ${CMAKE_CURRENT_BINARY_DIR}
0102         BLANK_MACROS
0103             KITEMVIEWS_EXPORT
0104             KITEMVIEWS_DEPRECATED
0105             KITEMVIEWS_DEPRECATED_EXPORT
0106             "KITEMVIEWS_DEPRECATED_VERSION(x, y, t)"
0107         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0108         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0109         COMPONENT Devel
0110     )
0111 endif()
0112
0113 ecm_qt_install_logging_categories(
0114     EXPORT KITEMVIEWS
0115     FILE kitemviews.categories
0116     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0117 )