kitemviews/src/CMakeLists.txt

0001 add_library(KF5ItemViews)
0002 add_library(KF5::ItemViews ALIAS KF5ItemViews)
0003
0004 set_target_properties(KF5ItemViews PROPERTIES
0005     VERSION     ${KITEMVIEWS_VERSION}
0006     SOVERSION   ${KITEMVIEWS_SOVERSION}
0007     EXPORT_NAME ItemViews
0008 )
0009
0010 ecm_create_qm_loader(KF5ItemViews kitemviews5_qt)
0011
0012 target_sources(KF5ItemViews PRIVATE
0013     kcategorizedsortfilterproxymodel.cpp
0014     kcategorizedsortfilterproxymodel.h
0015     kcategorizedsortfilterproxymodel_p.h
0016     kcategorizedview.cpp
0017     kcategorizedview.h
0018     kcategorizedview_p.h
0019     kcategorydrawer.cpp
0020     kcategorydrawer.h
0021     kextendableitemdelegate.cpp
0022     kextendableitemdelegate.h
0023     kfilterproxysearchline.cpp
0024     kfilterproxysearchline.h
0025     klistwidgetsearchline.cpp
0026     klistwidgetsearchline.h
0027     ktreewidgetsearchline.cpp
0028     ktreewidgetsearchline.h
0029     ktreewidgetsearchlinewidget.cpp
0030     ktreewidgetsearchlinewidget.h
0031     kwidgetitemdelegate.cpp
0032     kwidgetitemdelegate.h
0033     kwidgetitemdelegate_p.h
0034     kwidgetitemdelegatepool.cpp
0035     kwidgetitemdelegatepool_p.h
0036
0037 )
0038
0039 ecm_qt_declare_logging_category(KF5ItemViews
0040     HEADER kitemviews_debug.h
0041     IDENTIFIER KITEMVIEWS_LOG
0042     CATEGORY_NAME kf.itemviews
0043     DESCRIPTION "KItemViews"
0044     EXPORT KITEMVIEWS
0045 )
0046
0047 ecm_generate_export_header(KF5ItemViews
0048     BASE_NAME KItemViews
0049     GROUP_BASE_NAME KF
0050     VERSION ${KF_VERSION}
0051     DEPRECATED_BASE_VERSION 0
0052     DEPRECATION_VERSIONS 4.2 4.4 5.0 5.50
0053     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0054 )
0055
0056
0057 target_include_directories(KF5ItemViews INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews>")
0058
0059 target_link_libraries(KF5ItemViews PUBLIC Qt${QT_MAJOR_VERSION}::Widgets)
0060
0061 ecm_generate_headers(KItemViews_HEADERS
0062   HEADER_NAMES
0063   KCategorizedSortFilterProxyModel
0064   KCategorizedView
0065   KCategoryDrawer
0066   KExtendableItemDelegate
0067   KFilterProxySearchLine
0068   KListWidgetSearchLine
0069   KTreeWidgetSearchLine
0070   KTreeWidgetSearchLineWidget
0071   KWidgetItemDelegate
0072
0073   REQUIRED_HEADERS KItemViews_HEADERS
0074 )
0075
0076 install(TARGETS KF5ItemViews EXPORT KF5ItemViewsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0077
0078 install(FILES
0079   ${CMAKE_CURRENT_BINARY_DIR}/kitemviews_export.h
0080   ${KItemViews_HEADERS}
0081   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews COMPONENT Devel
0082 )
0083
0084 if(BUILD_DESIGNERPLUGIN)
0085     add_subdirectory(designer)
0086 endif()
0087
0088 if(BUILD_QCH)
0089     ecm_add_qch(
0090         KF5ItemViews_QCH
0091         NAME KItemViews
0092         BASE_NAME KF5ItemViews
0093         VERSION ${KF_VERSION}
0094         ORG_DOMAIN org.kde
0095         SOURCES # using only public headers, to cover only public API
0096             ${KItemViews_HEADERS}
0097         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0098         LINK_QCHS
0099             Qt5Widgets_QCH
0100             Qt5Gui_QCH
0101             Qt5Core_QCH
0102         INCLUDE_DIRS
0103             ${CMAKE_CURRENT_BINARY_DIR}
0104         BLANK_MACROS
0105             KITEMVIEWS_EXPORT
0106             KITEMVIEWS_DEPRECATED
0107             KITEMVIEWS_DEPRECATED_EXPORT
0108             "KITEMVIEWS_DEPRECATED_VERSION(x, y, t)"
0109         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0111         COMPONENT Devel
0112     )
0113 endif()
0114
0115 include(ECMGeneratePriFile)
0116 ecm_generate_pri_file(BASE_NAME KItemViews LIB_NAME KF5ItemViews DEPS "widgets" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews)
0117 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0118
0119 ecm_qt_install_logging_categories(
0120     EXPORT KITEMVIEWS
0121     FILE kitemviews.categories
0122     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0123 )