src/core/CMakeLists.txt

0001 add_library(KF5ItemModels)
0002 add_library(KF5::ItemModels ALIAS KF5ItemModels)
0003
0004 set_target_properties(KF5ItemModels PROPERTIES
0005     VERSION     ${KITEMMODELS_VERSION}
0006     SOVERSION   ${KITEMMODELS_SOVERSION}
0007     EXPORT_NAME ItemModels
0008 )
0009
0010 target_sources(KF5ItemModels PRIVATE
0011     kbihash_p.h
0012     kbreadcrumbselectionmodel.cpp
0013     kbreadcrumbselectionmodel.h
0014     kcheckableproxymodel.cpp
0015     kcheckableproxymodel.h
0016     kcolumnheadersmodel.cpp
0017     kcolumnheadersmodel.h
0018     kdescendantsproxymodel.cpp
0019     kdescendantsproxymodel.h
0020     kextracolumnsproxymodel.cpp
0021     kextracolumnsproxymodel.h
0022     klinkitemselectionmodel.cpp
0023     klinkitemselectionmodel.h
0024     kmodelindexproxymapper.cpp
0025     kmodelindexproxymapper.h
0026     knumbermodel.cpp
0027     knumbermodel.h
0028     krearrangecolumnsproxymodel.cpp
0029     krearrangecolumnsproxymodel.h
0030     kselectionproxymodel.cpp
0031     kselectionproxymodel.h
0032     kvoidpointerfactory_p.h
0033 )
0034 if (QT_MAJOR_VERSION EQUAL "5")
0035     target_sources(KF5ItemModels PRIVATE
0036         kconcatenaterowsproxymodel.cpp
0037         kconcatenaterowsproxymodel.h
0038         krecursivefilterproxymodel.cpp
0039         krecursivefilterproxymodel.h
0040     )
0041 endif()
0042
0043 ecm_qt_declare_logging_category(KF5ItemModels
0044     HEADER kitemmodels_debug.h
0045     IDENTIFIER KITEMMODELS_LOG
0046     CATEGORY_NAME kf.itemmodels.core
0047     OLD_CATEGORY_NAMES kf5.kitemmodels
0048     DESCRIPTION "KItemModels (Core)"
0049     EXPORT KITEMMODELS
0050 )
0051
0052 ecm_generate_export_header(KF5ItemModels
0053     BASE_NAME KItemModels
0054     GROUP_BASE_NAME KF
0055     VERSION ${KF_VERSION}
0056     DEPRECATED_BASE_VERSION 0
0057     DEPRECATION_VERSIONS 4.8 5.65 5.80
0058     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0059 )
0060
0061 target_include_directories(KF5ItemModels INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels>")
0062
0063 target_link_libraries(KF5ItemModels PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0064
0065 ecm_generate_headers(KItemModels_HEADERS
0066   HEADER_NAMES
0067   KBreadcrumbSelectionModel
0068   KCheckableProxyModel
0069   KExtraColumnsProxyModel
0070   KLinkItemSelectionModel
0071   KRearrangeColumnsProxyModel
0072   KDescendantsProxyModel
0073   KModelIndexProxyMapper
0074   KSelectionProxyModel
0075   KNumberModel
0076   KColumnHeadersModel
0077   REQUIRED_HEADERS KItemModels_HEADERS
0078 )
0079 if (QT_MAJOR_VERSION EQUAL "5")
0080     ecm_generate_headers(KItemModels_Legacy_HEADERS
0081         HEADER_NAMES
0082         KConcatenateRowsProxyModel
0083         KRecursiveFilterProxyModel
0084         REQUIRED_HEADERS KItemModels_Legacy_HEADERS
0085     )
0086 endif()
0087
0088 install(TARGETS KF5ItemModels EXPORT KF5ItemModelsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0089
0090 install(FILES
0091   ${CMAKE_CURRENT_BINARY_DIR}/kitemmodels_export.h
0092   ${KItemModels_HEADERS} ${KItemModels_Legacy_HEADERS}
0093   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels COMPONENT Devel
0094 )
0095
0096 if(BUILD_QCH)
0097     ecm_add_qch(
0098         KF5ItemModels_QCH
0099         NAME KItemModels
0100         BASE_NAME KF5ItemModels
0101         VERSION ${KF_VERSION}
0102         ORG_DOMAIN org.kde
0103         SOURCES # using only public headers, to cover only public API
0104             ${KItemModels_HEADERS}
0105         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0106         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0107         LINK_QCHS
0108             Qt5Core_QCH
0109         INCLUDE_DIRS
0110             ${CMAKE_CURRENT_BINARY_DIR}
0111         BLANK_MACROS
0112             KITEMMODELS_EXPORT
0113             "KITEMMODELS_DEPRECATED_VERSION(x, y, t)"
0114         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0115         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0116         COMPONENT Devel
0117     )
0118 endif()
0119
0120 include(ECMGeneratePriFile)
0121 ecm_generate_pri_file(BASE_NAME KItemModels LIB_NAME KF5ItemModels DEPS "core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels)
0122 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})