src/core/CMakeLists.txt

0001 add_library(KF6ItemModels)
0002 add_library(KF6::ItemModels ALIAS KF6ItemModels)
0003
0004 set_target_properties(KF6ItemModels PROPERTIES
0005     VERSION     ${KITEMMODELS_VERSION}
0006     SOVERSION   ${KITEMMODELS_SOVERSION}
0007     EXPORT_NAME ItemModels
0008 )
0009
0010 target_sources(KF6ItemModels PRIVATE
0011     kbihash_p.h
0012     kbreadcrumbselectionmodel.cpp
0013     kbreadcrumbselectionmodel.h
0014     kcheckableproxymodel.cpp
0015     kcheckableproxymodel.h
0016     kcolumnheadersmodel.cpp
0017     kcolumnheadersmodel.h
0018     kdescendantsproxymodel.cpp
0019     kdescendantsproxymodel.h
0020     kextracolumnsproxymodel.cpp
0021     kextracolumnsproxymodel.h
0022     klinkitemselectionmodel.cpp
0023     klinkitemselectionmodel.h
0024     kmodelindexproxymapper.cpp
0025     kmodelindexproxymapper.h
0026     knumbermodel.cpp
0027     knumbermodel.h
0028     krearrangecolumnsproxymodel.cpp
0029     krearrangecolumnsproxymodel.h
0030     kselectionproxymodel.cpp
0031     kselectionproxymodel.h
0032     kvoidpointerfactory_p.h
0033 )
0034
0035 ecm_qt_declare_logging_category(KF6ItemModels
0036     HEADER kitemmodels_debug.h
0037     IDENTIFIER KITEMMODELS_LOG
0038     CATEGORY_NAME kf.itemmodels.core
0039     OLD_CATEGORY_NAMES kf5.kitemmodels
0040     DESCRIPTION "KItemModels (Core)"
0041     EXPORT KITEMMODELS
0042 )
0043
0044 ecm_generate_export_header(KF6ItemModels
0045     BASE_NAME KItemModels
0046     GROUP_BASE_NAME KF
0047     VERSION ${KF_VERSION}
0048     USE_VERSION_HEADER
0049     DEPRECATED_BASE_VERSION 0
0050     DEPRECATION_VERSIONS
0051     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0052 )
0053
0054 target_include_directories(KF6ItemModels INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels>")
0055
0056 target_link_libraries(KF6ItemModels PUBLIC Qt6::Core)
0057
0058 ecm_generate_headers(KItemModels_HEADERS
0059     HEADER_NAMES
0060         KBreadcrumbSelectionModel
0061         KCheckableProxyModel
0062         KColumnHeadersModel
0063         KDescendantsProxyModel
0064         KExtraColumnsProxyModel
0065         KLinkItemSelectionModel
0066         KModelIndexProxyMapper
0067         KNumberModel
0068         KRearrangeColumnsProxyModel
0069         KSelectionProxyModel
0070     REQUIRED_HEADERS KItemModels_HEADERS
0071 )
0072
0073 install(TARGETS KF6ItemModels EXPORT KF6ItemModelsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0074
0075 install(FILES
0076     ${CMAKE_CURRENT_BINARY_DIR}/kitemmodels_export.h
0077     ${KItemModels_HEADERS}
0078     ${KItemModels_Legacy_HEADERS}
0079     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemModels
0080     COMPONENT Devel
0081 )
0082
0083 if (BUILD_QCH)
0084     ecm_add_qch(
0085         KF6ItemModels_QCH
0086         NAME KItemModels
0087         BASE_NAME KF6ItemModels
0088         VERSION ${KF_VERSION}
0089         ORG_DOMAIN org.kde
0090         SOURCES # using only public headers, to cover only public API
0091             ${KItemModels_HEADERS}
0092         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0093         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0094         LINK_QCHS
0095             Qt6Core_QCH
0096         INCLUDE_DIRS
0097             ${CMAKE_CURRENT_BINARY_DIR}
0098         BLANK_MACROS
0099             KITEMMODELS_EXPORT
0100             "KITEMMODELS_DEPRECATED_VERSION(x, y, t)"
0101         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0102         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0103         COMPONENT Devel
0104     )
0105 endif()