src/gui/CMakeLists.txt

0001 configure_file(config-kiogui.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kiogui.h)
0002
0003 add_library(KF5KIOGui)
0004 add_library(KF5::KIOGui ALIAS KF5KIOGui)
0005
0006 set_target_properties(KF5KIOGui PROPERTIES
0007     VERSION     ${KIO_VERSION}
0008     SOVERSION   ${KIO_SOVERSION}
0009     EXPORT_NAME KIOGui
0010 )
0011
0012 target_sources(KF5KIOGui PRIVATE
0013    applicationlauncherjob.cpp
0014    commandlauncherjob.cpp
0015    faviconrequestjob.cpp
0016    kcoreurlnavigator.cpp
0017    openurljob.cpp
0018    openwithhandlerinterface.cpp
0019    openorexecutefileinterface.cpp
0020    kprocessrunner.cpp
0021    kterminallauncherjob.cpp
0022    kemailclientlauncherjob.cpp
0023    dbusactivationrunner.cpp
0024    thumbnailcreator.cpp
0025    gpudetection.cpp
0026 )
0027
0028 if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
0029     set(SYSTEMD_DBUS_XMLS
0030         systemd/org.freedesktop.systemd1.Manager.xml
0031         systemd/org.freedesktop.systemd1.Unit.xml
0032         systemd/org.freedesktop.DBus.Properties.xml)
0033
0034     set_source_files_properties(${SYSTEMD_DBUS_XMLS} PROPERTIES INCLUDE systemd/dbustypes.h)
0035
0036     set(kiogui_dbus_SRCS)
0037     qt_add_dbus_interfaces(kiogui_dbus_SRCS ${SYSTEMD_DBUS_XMLS})
0038
0039     target_sources(KF5KIOGui PRIVATE
0040         ${kiogui_dbus_SRCS}
0041         systemd/systemdprocessrunner.cpp
0042         systemd/scopedprocessrunner.cpp
0043     )
0044 endif ()
0045
0046 ecm_qt_declare_logging_category(KF5KIOGui
0047     HEADER kiogui_debug.h
0048     IDENTIFIER KIO_GUI
0049     CATEGORY_NAME kf.kio.gui
0050     OLD_CATEGORY_NAMES kf5.kio.gui
0051     DESCRIPTION "KIOGui (KIO)"
0052     EXPORT KIO
0053 )
0054
0055 ecm_qt_declare_logging_category(KF5KIOGui
0056     HEADER favicons_debug.h
0057     IDENTIFIER FAVICONS_LOG
0058     CATEGORY_NAME kf.kio.gui.favicons
0059     OLD_CATEGORY_NAMES kf5.kio.favicons
0060     DESCRIPTION "FavIcons (KIO)"
0061     EXPORT KIO
0062 )
0063
0064 ecm_generate_export_header(KF5KIOGui
0065     BASE_NAME KIOGui
0066     GROUP_BASE_NAME KF
0067     VERSION ${KF_VERSION}
0068     DEPRECATED_BASE_VERSION 0
0069     DEPRECATION_VERSIONS 5.101 5.103
0070     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0071 )
0072
0073 target_include_directories(KF5KIOGui INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui>")
0074
0075 target_link_libraries(KF5KIOGui
0076   PUBLIC
0077     KF5::KIOCore
0078     KF5::ConfigCore
0079     KF5::Service
0080     Qt${QT_MAJOR_VERSION}::Gui
0081   PRIVATE
0082     KF5::I18n
0083 )
0084
0085 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0086    EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.102.0)
0087   target_link_libraries(KF5KIOGui PUBLIC KF5::WindowSystem)
0088 else()
0089   target_link_libraries(KF5KIOGui PRIVATE KF5::WindowSystem)
0090 endif()
0091
0092 # Headers prefixed with KIO/
0093 ecm_generate_headers(KIOGui_CamelCase_HEADERS
0094   HEADER_NAMES
0095   ApplicationLauncherJob
0096   CommandLauncherJob
0097   FavIconRequestJob
0098   OpenUrlJob
0099   OpenWithHandlerInterface
0100   ThumbnailCreator
0101
0102   PREFIX KIO
0103   REQUIRED_HEADERS KIO_namespaced_gui_HEADERS
0104 )
0105
0106 # Headers not prefixed with KIO/
0107 ecm_generate_headers(KIOGui_HEADERS
0108   HEADER_NAMES
0109   KCoreUrlNavigator
0110   KEMailClientLauncherJob
0111   KTerminalLauncherJob
0112
0113   REQUIRED_HEADERS KIOGui_HEADERS
0114 )
0115
0116 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0117    EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.101.0)
0118     list(APPEND KIOGui_CamelCase_HEADERS compatheaders/KCoreUrlNavigator)
0119     list(APPEND KIO_namespaced_gui_HEADERS compatheaders/kcoreurlnavigator.h)
0120 endif()
0121
0122 install(FILES ${KIOGui_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui/KIO COMPONENT Devel)
0123
0124 install(TARGETS KF5KIOGui EXPORT KF5KIOTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0125
0126 install(FILES
0127   ${KIO_namespaced_gui_HEADERS}
0128   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui/kio COMPONENT Devel)
0129
0130 install(FILES
0131   ${KIOGui_HEADERS}
0132   ${CMAKE_CURRENT_BINARY_DIR}/kiogui_export.h
0133   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui COMPONENT Devel)
0134
0135 # make available to ecm_add_qch in parent folder
0136 set(KIOGui_QCH_SOURCES ${KIOGui_HEADERS} ${KIO_namespaced_gui_HEADERS} PARENT_SCOPE)
0137
0138 include(ECMGeneratePriFile)
0139 ecm_generate_pri_file(BASE_NAME KIOGui LIB_NAME KF5KIOGui DEPS "KIOCore" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui)
0140 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})