src/gui/CMakeLists.txt

0001 configure_file(config-kiogui.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kiogui.h)
0002
0003 add_library(KF6KIOGui)
0004 add_library(KF6::KIOGui ALIAS KF6KIOGui)
0005
0006 set_target_properties(KF6KIOGui PROPERTIES
0007     VERSION     ${KIO_VERSION}
0008     SOVERSION   ${KIO_SOVERSION}
0009     EXPORT_NAME KIOGui
0010 )
0011
0012 target_sources(KF6KIOGui PRIVATE
0013    applicationlauncherjob.cpp
0014    commandlauncherjob.cpp
0015    dndpopupmenuplugin.cpp
0016    faviconrequestjob.cpp
0017    kcoreurlnavigator.cpp
0018    openurljob.cpp
0019    openwithhandlerinterface.cpp
0020    openorexecutefileinterface.cpp
0021    kprocessrunner.cpp
0022    kterminallauncherjob.cpp
0023    kemailclientlauncherjob.cpp
0024    dbusactivationrunner.cpp
0025    previewjob.cpp
0026    thumbnailcreator.cpp
0027    gpudetection.cpp
0028    kurifilter.cpp
0029    kurifilterplugin.cpp
0030 )
0031
0032 if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
0033     set(SYSTEMD_DBUS_XMLS
0034         systemd/org.freedesktop.systemd1.Manager.xml
0035         systemd/org.freedesktop.systemd1.Unit.xml
0036         systemd/org.freedesktop.DBus.Properties.xml)
0037
0038     set_source_files_properties(${SYSTEMD_DBUS_XMLS} PROPERTIES INCLUDE systemd/dbustypes.h)
0039
0040     set(kiogui_dbus_SRCS)
0041     qt_add_dbus_interfaces(kiogui_dbus_SRCS ${SYSTEMD_DBUS_XMLS})
0042
0043     target_sources(KF6KIOGui PRIVATE
0044         ${kiogui_dbus_SRCS}
0045         systemd/systemdprocessrunner.cpp
0046         systemd/scopedprocessrunner.cpp
0047     )
0048 endif ()
0049
0050 if (NOT ANDROID)
0051   target_sources(KF6KIOGui PRIVATE openfilemanagerwindowjob.cpp)
0052 endif()
0053
0054 ecm_qt_declare_logging_category(KF6KIOGui
0055     HEADER kiogui_debug.h
0056     IDENTIFIER KIO_GUI
0057     CATEGORY_NAME kf.kio.gui
0058     OLD_CATEGORY_NAMES kf5.kio.gui
0059     DESCRIPTION "KIOGui (KIO)"
0060     EXPORT KIO
0061 )
0062
0063 ecm_qt_declare_logging_category(KF6KIOGui
0064     HEADER favicons_debug.h
0065     IDENTIFIER FAVICONS_LOG
0066     CATEGORY_NAME kf.kio.gui.favicons
0067     OLD_CATEGORY_NAMES kf5.kio.favicons
0068     DESCRIPTION "FavIcons (KIO)"
0069     EXPORT KIO
0070 )
0071
0072 ecm_generate_export_header(KF6KIOGui
0073     BASE_NAME KIOGui
0074     GROUP_BASE_NAME KF
0075     VERSION ${KF_VERSION}
0076     USE_VERSION_HEADER
0077     VERSION_BASE_NAME KIO
0078     DEPRECATED_BASE_VERSION 0
0079     DEPRECATION_VERSIONS
0080     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0081 )
0082
0083 target_include_directories(KF6KIOGui INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui>")
0084
0085 target_link_libraries(KF6KIOGui
0086   PUBLIC
0087     KF6::KIOCore
0088     KF6::ConfigCore
0089     KF6::Service
0090     Qt6::Gui
0091   PRIVATE
0092     KF6::Solid
0093     KF6::I18n
0094 )
0095
0096 target_link_libraries(KF6KIOGui PRIVATE KF6::WindowSystem)
0097
0098 # Headers prefixed with KIO/
0099 ecm_generate_headers(KIOGui_CamelCase_HEADERS
0100   HEADER_NAMES
0101   ApplicationLauncherJob
0102   CommandLauncherJob
0103   DndPopupMenuPlugin
0104   FavIconRequestJob
0105   OpenFileManagerWindowJob
0106   OpenUrlJob
0107   OpenWithHandlerInterface
0108   PreviewJob
0109   ThumbnailCreator
0110
0111   PREFIX KIO
0112   REQUIRED_HEADERS KIO_namespaced_gui_HEADERS
0113 )
0114
0115 # Headers not prefixed with KIO/
0116 ecm_generate_headers(KIOGui_HEADERS
0117   HEADER_NAMES
0118   KCoreUrlNavigator
0119   KEMailClientLauncherJob
0120   KTerminalLauncherJob
0121   KUriFilter
0122
0123   REQUIRED_HEADERS KIOGui_HEADERS
0124 )
0125
0126 install(FILES ${KIOGui_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui/KIO COMPONENT Devel)
0127
0128 install(TARGETS KF6KIOGui EXPORT KF6KIOTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0129
0130 install(FILES
0131   ${KIO_namespaced_gui_HEADERS}
0132   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui/kio COMPONENT Devel)
0133
0134 install(FILES
0135   ${KIOGui_HEADERS}
0136   ${CMAKE_CURRENT_BINARY_DIR}/kiogui_export.h
0137   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIOGui COMPONENT Devel)
0138
0139 # make available to ecm_add_qch in parent folder
0140 set(KIOGui_QCH_SOURCES ${KIOGui_HEADERS} ${KIO_namespaced_gui_HEADERS} PARENT_SCOPE)
0141