kidletime/src/CMakeLists.txt

0001 configure_file(config-kidletime.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kidletime.h )
0002
0003 add_library(KF5IdleTime)
0004 add_library(KF5::IdleTime ALIAS KF5IdleTime)
0005
0006 target_sources(KF5IdleTime PRIVATE
0007     kidletime.cpp
0008     abstractsystempoller.cpp
0009     widgetbasedpoller.cpp # TODO it doesn't actually use widgets, just GUI. Rename?
0010 )
0011
0012 ecm_qt_declare_logging_category(KF5IdleTime
0013     HEADER logging.h
0014     IDENTIFIER KIDLETIME
0015     CATEGORY_NAME kf.idletime
0016     OLD_CATEGORY_NAMES org.kde.kf5.idletime
0017     DESCRIPTION "kidletime (lib)"
0018     EXPORT KIDLETIME
0019 )
0020
0021 ecm_generate_export_header(KF5IdleTime
0022     BASE_NAME KIdleTime
0023     GROUP_BASE_NAME KF
0024     VERSION ${KF_VERSION}
0025     DEPRECATED_BASE_VERSION 0
0026     DEPRECATION_VERSIONS 5.76
0027     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0028 )
0029 target_include_directories(KF5IdleTime INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime>")
0030
0031 target_link_libraries(KF5IdleTime PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0032 target_link_libraries(KF5IdleTime PRIVATE Qt${QT_MAJOR_VERSION}::Gui)
0033
0034 set_target_properties(KF5IdleTime PROPERTIES  VERSION ${KIDLETIME_VERSION}
0035                                               SOVERSION ${KIDLETIME_SOVERSION}
0036                                               EXPORT_NAME IdleTime
0037 )
0038
0039 add_subdirectory(plugins)
0040
0041 ecm_generate_headers(KIdleTime_HEADERS
0042   HEADER_NAMES
0043   KIdleTime
0044
0045   REQUIRED_HEADERS KIdleTime_HEADERS
0046 )
0047
0048
0049 install(FILES
0050   ${CMAKE_CURRENT_BINARY_DIR}/kidletime_export.h
0051   ${KIdleTime_HEADERS}
0052   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime COMPONENT Devel
0053 )
0054
0055 install(
0056     FILES
0057         abstractsystempoller.h
0058     DESTINATION
0059         ${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime/private
0060     COMPONENT
0061         Devel
0062 )
0063
0064 install(TARGETS KF5IdleTime EXPORT KF5IdleTimeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0065
0066
0067 ecm_qt_install_logging_categories(
0068     EXPORT KIDLETIME
0069     FILE kidletime.categories
0070     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0071 )
0072
0073 if(BUILD_QCH)
0074     ecm_add_qch(
0075         KF5IdleTime_QCH
0076         NAME KIdleTime
0077         BASE_NAME KF5IdleTime
0078         VERSION ${KF_VERSION}
0079         ORG_DOMAIN org.kde
0080         SOURCES # using only public headers, to cover only public API
0081             ${KIdleTime_HEADERS}
0082         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0083         LINK_QCHS
0084             Qt5Core_QCH
0085         INCLUDE_DIRS
0086             ${CMAKE_CURRENT_BINARY_DIR}
0087         BLANK_MACROS
0088             KIDLETIME_EXPORT
0089             "KIDLETIME_DEPRECATED_VERSION(x, y, t)"
0090         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0091         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0092         COMPONENT Devel
0093     )
0094 endif()
0095
0096 include(ECMGeneratePriFile)
0097 ecm_generate_pri_file(BASE_NAME KIdleTime LIB_NAME KF5IdleTime DEPS "core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime)
0098 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})