kidletime/src/CMakeLists.txt

0001 configure_file(config-kidletime.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kidletime.h )
0002
0003 add_library(KF6IdleTime)
0004 add_library(KF6::IdleTime ALIAS KF6IdleTime)
0005
0006 set_target_properties(KF6IdleTime PROPERTIES
0007     VERSION     ${KIDLETIME_VERSION}
0008     SOVERSION   ${KIDLETIME_SOVERSION}
0009     EXPORT_NAME IdleTime
0010 )
0011
0012 target_sources(KF6IdleTime PRIVATE
0013     kidletime.cpp
0014     kabstractidletimepoller.cpp
0015     kwindowbasedidletimepoller.cpp
0016 )
0017
0018 ecm_qt_declare_logging_category(KF6IdleTime
0019     HEADER logging.h
0020     IDENTIFIER KIDLETIME
0021     CATEGORY_NAME kf.idletime
0022     OLD_CATEGORY_NAMES org.kde.kf5.idletime
0023     DESCRIPTION "kidletime (lib)"
0024     EXPORT KIDLETIME
0025 )
0026
0027 ecm_generate_export_header(KF6IdleTime
0028     BASE_NAME KIdleTime
0029     GROUP_BASE_NAME KF
0030     VERSION ${KF_VERSION}
0031     USE_VERSION_HEADER
0032     DEPRECATED_BASE_VERSION 0
0033     DEPRECATION_VERSIONS
0034     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0035 )
0036
0037 target_include_directories(KF6IdleTime INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime>")
0038
0039 target_link_libraries(KF6IdleTime PUBLIC Qt6::Core)
0040 target_link_libraries(KF6IdleTime PRIVATE Qt6::Gui)
0041
0042 add_subdirectory(plugins)
0043
0044 ecm_generate_headers(KIdleTime_HEADERS
0045   HEADER_NAMES
0046   KIdleTime
0047
0048   REQUIRED_HEADERS KIdleTime_HEADERS
0049 )
0050
0051
0052 install(FILES
0053   ${CMAKE_CURRENT_BINARY_DIR}/kidletime_export.h
0054   ${KIdleTime_HEADERS}
0055   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime COMPONENT Devel
0056 )
0057
0058 install(
0059     FILES
0060         kabstractidletimepoller_p.h
0061     DESTINATION
0062         ${KDE_INSTALL_INCLUDEDIR_KF}/KIdleTime/private
0063     COMPONENT
0064         Devel
0065 )
0066
0067 install(TARGETS KF6IdleTime EXPORT KF6IdleTimeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0068
0069
0070 ecm_qt_install_logging_categories(
0071     EXPORT KIDLETIME
0072     FILE kidletime.categories
0073     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0074 )
0075
0076 if(BUILD_QCH)
0077     ecm_add_qch(
0078         KF6IdleTime_QCH
0079         NAME KIdleTime
0080         BASE_NAME KF6IdleTime
0081         VERSION ${KF_VERSION}
0082         ORG_DOMAIN org.kde
0083         SOURCES # using only public headers, to cover only public API
0084             ${KIdleTime_HEADERS}
0085         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0086         LINK_QCHS
0087             Qt6Core_QCH
0088         INCLUDE_DIRS
0089             ${CMAKE_CURRENT_BINARY_DIR}
0090         BLANK_MACROS
0091             KIDLETIME_EXPORT
0092             "KIDLETIME_DEPRECATED_VERSION(x, y, t)"
0093         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0094         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0095         COMPONENT Devel
0096     )
0097 endif()
0098