src/i18n/CMakeLists.txt

0001 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in" "${CMAKE_CURRENT_BINARY_DIR}/config.h")
0002
0003 add_library(KF5I18n)
0004 add_library(KF5::I18n ALIAS KF5I18n)
0005
0006 target_sources(KF5I18n PRIVATE
0007     klocalizedstring.cpp
0008     klocalizedtranslator.cpp
0009     kcatalog.cpp
0010     kuitsetup.cpp
0011     common_helpers.cpp
0012     klocalizedcontext.cpp
0013     main.cpp
0014 )
0015
0016 ecm_qt_declare_logging_category(KF5I18n
0017     HEADER ki18n_logging.h
0018     IDENTIFIER KI18N
0019     CATEGORY_NAME kf.i18n
0020     OLD_CATEGORY_NAMES kf5.ki18n
0021     DESCRIPTION "KI18n"
0022     EXPORT KI18N
0023 )
0024
0025 ecm_qt_declare_logging_category(KF5I18n
0026     HEADER ki18n_logging_kuit.h
0027     IDENTIFIER KI18N_KUIT
0028     CATEGORY_NAME kf.i18n.kuit
0029     OLD_CATEGORY_NAMES kf5.ki18n.kuit
0030     DESCRIPTION "KI18n KUIT"
0031     EXPORT KI18N
0032 )
0033
0034 ecm_generate_export_header(KF5I18n
0035     BASE_NAME KI18n
0036     GROUP_BASE_NAME KF
0037     VERSION ${KF_VERSION}
0038     DEPRECATED_BASE_VERSION 0
0039     DEPRECATION_VERSIONS 5.0
0040     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0041 )
0042
0043 target_include_directories(KF5I18n INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KI18n>")
0044 target_include_directories(KF5I18n PRIVATE ${LibIntl_INCLUDE_DIRS})
0045
0046 target_link_libraries(KF5I18n PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0047 # This is only required for platforms which don't use glibc (with glibc LibIntl_LIBRARIES will be empty)
0048 target_link_libraries(KF5I18n PRIVATE ${LibIntl_LIBRARIES})
0049 if (ANDROID)
0050     if (QT_MAJOR_VERSION EQUAL "5")
0051         target_link_libraries(KF5I18n PRIVATE Qt5::AndroidExtras)
0052     endif()
0053     target_link_libraries(KF5I18n PRIVATE android)
0054 endif()
0055 target_compile_options(KF5I18n PRIVATE -DTRANSLATION_DOMAIN=\"ki18n5\")
0056
0057 set_target_properties(KF5I18n PROPERTIES VERSION   ${KI18N_VERSION}
0058                                          SOVERSION ${KI18N_SOVERSION}
0059                                          EXPORT_NAME I18n
0060 )
0061
0062 install(TARGETS KF5I18n EXPORT KF5I18nTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0063
0064 ecm_generate_headers(KI18n_HEADERS
0065   HEADER_NAMES
0066     KLazyLocalizedString
0067     KLocalizedContext
0068     KLocalizedString
0069     KLocalizedTranslator
0070     KuitSetup
0071     REQUIRED_HEADERS KI18n_HEADERS
0072 )
0073
0074 # provide compat headers for old includes
0075 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0076    EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.105.0)
0077     list(APPEND KI18n_HEADERS
0078         compatheaders/KuitMarkup
0079         compatheaders/kuitmarkup.h
0080     )
0081 endif()
0082
0083 install(FILES
0084     ${KI18n_HEADERS}
0085     ${CMAKE_CURRENT_BINARY_DIR}/ki18n_export.h
0086     DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KI18n" COMPONENT Devel
0087 )
0088
0089 ### ktranscript plugin
0090 if (BUILD_WITH_QML)
0091
0092 add_library(ktranscript MODULE)
0093
0094 target_sources(ktranscript PRIVATE
0095     ktranscript.cpp
0096     common_helpers.cpp
0097 )
0098 generate_export_header(ktranscript BASE_NAME KTranscript)
0099 target_link_libraries(ktranscript PRIVATE Qt${QT_MAJOR_VERSION}::Qml Qt${QT_MAJOR_VERSION}::Core)
0100
0101 install(TARGETS ktranscript DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION})
0102
0103 endif()
0104
0105 if (BUILD_QCH)
0106     ecm_add_qch(
0107         KF5I18n_QCH
0108         NAME KI18n
0109         BASE_NAME KF5I18n
0110         VERSION ${KF_VERSION}
0111         ORG_DOMAIN org.kde
0112         SOURCES # using only public headers, to cover only public API
0113             ${KI18n_HEADERS}
0114             "${CMAKE_SOURCE_DIR}/docs/programmers-guide.md"
0115             "${CMAKE_SOURCE_DIR}/docs/translators-guide.md"
0116         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0117         LINK_QCHS
0118             Qt5Core_QCH
0119         INCLUDE_DIRS
0120             ${CMAKE_CURRENT_BINARY_DIR}
0121         BLANK_MACROS
0122             KI18N_EXPORT
0123             KI18N_DEPRECATED_EXPORT
0124             KI18N_DEPRECATED
0125             "KI18N_DEPRECATED_VERSION(x, y, t)"
0126         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0127         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0128         COMPONENT Devel
0129     )
0130 endif()
0131
0132 include(ECMGeneratePriFile)
0133 ecm_generate_pri_file(BASE_NAME KI18n LIB_NAME KF5I18n DEPS "core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KI18n)
0134 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})