Warning, /frameworks/ki18n/src/i18n/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in" "${CMAKE_CURRENT_BINARY_DIR}/config.h")
0002 
0003 add_library(KF6I18n)
0004 add_library(KF6::I18n ALIAS KF6I18n)
0005 
0006 set_target_properties(KF6I18n PROPERTIES
0007     VERSION     ${KI18N_VERSION}
0008     SOVERSION   ${KI18N_SOVERSION}
0009     EXPORT_NAME I18n
0010 )
0011 
0012 target_sources(KF6I18n PRIVATE
0013     klocalizedstring.cpp
0014     klocalizedtranslator.cpp
0015     kcatalog.cpp
0016     kuitsetup.cpp
0017     common_helpers.cpp
0018     klocalizedcontext.cpp
0019     main.cpp
0020 )
0021 
0022 ecm_qt_declare_logging_category(KF6I18n
0023     HEADER ki18n_logging.h
0024     IDENTIFIER KI18N
0025     CATEGORY_NAME kf.i18n
0026     OLD_CATEGORY_NAMES kf5.ki18n
0027     DESCRIPTION "KI18n"
0028     EXPORT KI18N
0029 )
0030 
0031 ecm_qt_declare_logging_category(KF6I18n
0032     HEADER ki18n_logging_kuit.h
0033     IDENTIFIER KI18N_KUIT
0034     CATEGORY_NAME kf.i18n.kuit
0035     OLD_CATEGORY_NAMES kf5.ki18n.kuit
0036     DESCRIPTION "KI18n KUIT"
0037     EXPORT KI18N
0038 )
0039 
0040 ecm_generate_export_header(KF6I18n
0041     BASE_NAME KI18n
0042     GROUP_BASE_NAME KF
0043     VERSION ${KF_VERSION}
0044     USE_VERSION_HEADER
0045     DEPRECATED_BASE_VERSION 0
0046     DEPRECATION_VERSIONS
0047     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0048 )
0049 
0050 target_include_directories(KF6I18n
0051     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KI18n>"
0052     PUBLIC "$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}>" # for version header
0053     PRIVATE ${LibIntl_INCLUDE_DIRS}
0054 )
0055 
0056 target_link_libraries(KF6I18n PUBLIC Qt6::Core)
0057 # This is only required for platforms which don't use glibc (with glibc LibIntl_LIBRARIES will be empty)
0058 target_link_libraries(KF6I18n PRIVATE ${LibIntl_LIBRARIES})
0059 if (ANDROID)
0060     target_link_libraries(KF6I18n PRIVATE android)
0061 endif()
0062 target_compile_options(KF6I18n PRIVATE -DTRANSLATION_DOMAIN=\"ki18n6\")
0063 
0064 install(TARGETS KF6I18n EXPORT KF6I18nTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0065 
0066 ecm_generate_headers(KI18n_HEADERS
0067   HEADER_NAMES
0068     KLazyLocalizedString
0069     KLocalizedContext
0070     KLocalizedString
0071     KLocalizedTranslator
0072     KuitSetup
0073     REQUIRED_HEADERS KI18n_HEADERS
0074 )
0075 
0076 install(FILES
0077     ${KI18n_HEADERS}
0078     ${CMAKE_CURRENT_BINARY_DIR}/ki18n_export.h
0079     DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KI18n" COMPONENT Devel
0080 )
0081 
0082 
0083 ### ktranscript plugin
0084 if (BUILD_WITH_QML)
0085 
0086 add_library(ktranscript MODULE)
0087 
0088 target_sources(ktranscript PRIVATE
0089     ktranscript.cpp
0090     common_helpers.cpp
0091 )
0092 generate_export_header(ktranscript BASE_NAME KTranscript)
0093 target_link_libraries(ktranscript PRIVATE Qt6::Qml Qt6::Core)
0094 
0095 install(TARGETS ktranscript DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6)
0096 
0097 endif()
0098 
0099 if (BUILD_QCH)
0100     ecm_add_qch(
0101         KF6I18n_QCH
0102         NAME KI18n
0103         BASE_NAME KF6I18n
0104         VERSION ${KF_VERSION}
0105         ORG_DOMAIN org.kde
0106         SOURCES # using only public headers, to cover only public API
0107             ${KI18n_HEADERS}
0108             "${CMAKE_SOURCE_DIR}/docs/programmers-guide.md"
0109             "${CMAKE_SOURCE_DIR}/docs/translators-guide.md"
0110         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0111         LINK_QCHS
0112             Qt6Core_QCH
0113         INCLUDE_DIRS
0114             ${CMAKE_CURRENT_BINARY_DIR}
0115         BLANK_MACROS
0116             KI18N_EXPORT
0117             KI18N_DEPRECATED_EXPORT
0118             KI18N_DEPRECATED
0119             "KI18N_DEPRECATED_VERSION(x, y, t)"
0120         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0121         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0122         COMPONENT Devel
0123     )
0124 endif()